DataMuseum.dk

top - metrics - download

    Length: 3580 (0xdfc)
    Types: TextFile
    Names: »name.bnf«

└─⟦3d0c2be1b⟧ Bits:30001254 ISODE-5.0 Tape
    └─⟦eba4602b1⟧ »./isode-5.0.tar.Z« 
        └─⟦d3ac74d73⟧ 
            └─⟦this⟧ »isode-5.0/doc/manual/name.bnf« 

TextFile

<attribute-value> ::= <numericvalue>
				-- NumericString
			| <printablestring>
				-- PrintableString
				-- and related ones
			| <asnvalue>
				-- general value
			| <psapvalue>
				-- PSAP Address
			| <namevalue>
				-- DistinguishedName
			| <aclvalue>
				-- ACL
			| <schemavalue>
				-- TreeStructure
			| <updateinfovalue>
				-- UpdateInfoSyntax
			| <objectIdentifiervalue>
				-- Object Class attribute

<numericvalue>	::= ["{N}"] <numericstring>

<asnvalue>	::= ["{ASN}"] <printablestring>
                                -- interpreted as HEX pairs

<psapvalue>	::= ["{PSAP}"] <PSPAaddr>

-- We also need a string format for addresses:-
<PSAPaddr>      ::= [[[ <psel> "/" ] <ssel> "/" ] <tsel> "/" ] 
                <network-address-list>

<network-address-list> ::= <network-address> "|" <network-address-list> 
                           | <network-address>

<psel> ::= <selector>
<ssel> ::= <selector>
<tsel> ::= <selector>

<selector>  ::= '"' <otherstring> '"'        -- IA5
                                             -- For chars not in this
                                             -- string use hex
                | "#" <digitstring>          -- US GOSIP
                | "'" <hexstring> "'H"       -- Hex
                | ""                         -- Empty but present

<network-address> ::=   "NS" "+" <hexstring>
                                 -- Concrete Binary Representation
                                 -- This is the compact encoding
        | <afi> "+" <idi> [ "+" <dsp> ]


<dsp>  ::=
        | "d" <digitstring>          -- Abstract Decimal
        | "x" <hexstring>            -- Abstract Binary
        | "l" <otherstring>             -- IA5: local form only
        | "RFC-1006" "+" <prefix> "+" <ip> 
           [ "+" <port> [ "+" <tset> ]]
        | "X.25(80)" "+" <prefix> "+" <dte> 
           [ "+" <cudf-or-pid> "+" <hexstring> ]
        | "ECMA-117-Binary" "+" <hexstring> "+" <hexstring> 
           "+" <hexstring>
        | "ECMA-117-Decimal" "+" <digitstring> "+" 
           <digitstring> "+" <digitstring>
                
<idi> ::= <digitstring>
<afi> ::= "X121" | "DCC" | "TELEX" | "PSTN" | "ISDN" 
                | "ICD" | "LOCAL" 

<prefix> ::= <digit> <digit>         

<ip> ::= <otherstring>
                        -- dotted decimal form (e.g., 10.0.0.6)
                        -- or domain (e.g., twg.com)
<port> ::= <digitstring>
<tset> ::= <digitstring>

<dte> ::= <digitstring>
<cudf-or-pid> ::= "CUDF" | "PID"
                

<aclvalue>	::= ["{ACL}"] <aclwho> "#" <aclwhat> "#" <acltype> ["#"]
<aclwho>	::= "self" | "others" | "group #" <namelist> | 
			"prefix #" <namelist>
<aclwhat>	::= "none" | "detect" | "compare" | "read" | "add" | "write"
<acltype>	::= "child" | "entry" | "default" | "attributes #" <oidlist>
<oidlist>	::= <oid> | <oidlist> "$" <oid>

<schemavalue>	::= ["{SCHEMA}"] <oid>

<updateinfovalue> ::= ["{UPDATE}"] <name> "#" <name> "#" <namelist> ["#"]
 --                                edb     # from     # allowed to send to 

<objectIdentifiervalue>  ::= ["{OID}"] <oid>

<namevalue>	::= ["{DN}"]  <namelist> ["#"]
<namelist>	::= <name> | <namelist> "$" <name>

<attribute>	::= <oid> "=" <avlist>
<avlist>	::= <attribute-value> | <avlist> "&" <attribute-value>
<rdn>		::= <attribute> | <attribute> "%" <rdn>
<name>		::= <rdn> | <rdn> "@" <name>
				- most significant first

-- An example name might be:
--        ``c=GB @ o=UCL % locality=London @ ou=CS
-- Finally, this can be assembled together to give a format for a textual
-- representation of an Entry Data Block.