DataMuseum.dk

Presents historical artifacts from the history of:

DKUUG/EUUG Conference tapes

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about DKUUG/EUUG Conference tapes

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - metrics - download
Index: T b

⟦cbc2fd4c7⟧ TextFile

    Length: 2163 (0x873)
    Types: TextFile
    Names: »bnf.bnf«

Derivation

└─⟦3d0c2be1b⟧ Bits:30001254 ISODE-5.0 Tape
    └─⟦eba4602b1⟧ »./isode-5.0.tar.Z« 
        └─⟦d3ac74d73⟧ 
            └─⟦this⟧ »isode-5.0/doc/interim/bnf.bnf« 
└─⟦2d1937cfd⟧ Bits:30007241 EUUGD22: P.P 5.0
    └─⟦35176feda⟧ »EurOpenD22/isode/isode-6.tar.Z« 
        └─⟦de7628f85⟧ 
            └─⟦this⟧ »isode-6.0/doc/interim/bnf.bnf«

TextFile


<digit> ::= [0-9]
<other> ::= [0-9a-zA-Z+-.]
<hexdigit> ::= [0-9a-f]

<digitstring> ::= <digit> <digitstring>
                        | <digit>
<otherstring> ::= <other> <otherstring>
                        | <other>
<hexstring> ::= <hexdigit> <hexstring> | <hexdigit>


                        

<presentation-address> ::= 
                [[[ <psel> "/" ] <ssel> "/" ] <tsel> "/" ] 
                <network-address-list>

<network-address-list> ::= <network-address> "|" <network-address-list> 
                           | <network-address>

<psel> ::= <selector>
<ssel> ::= <selector>
<tsel> ::= <selector>

<selector>  ::= '"' <otherstring> '"'        -- IA5
                                             -- For chars not in this
                                             -- string use hex
                | "#" <digitstring>          -- US GOSIP
                | "'" <hexstring> "'H"       -- Hex
                | ""                         -- Empty but present

<network-address> ::=   "NS" "+" <hexstring>
                                 -- Concrete Binary Representation
                                 -- This is the compact encoding
        | <afi> "+" <idi> [ "+" <dsp> ]


<dsp>  ::=
        | "d" <digitstring>          -- Abstract Decimal
        | "x" <hexstring>            -- Abstract Binary
        | "l" <otherstring>             -- IA5: local form only
        | "RFC-1006" "+" <prefix> "+" <ip> 
           [ "+" <port> [ "+" <tset> ]]
        | "X.25(80)" "+" <prefix> "+" <dte> 
           [ "+" <cudf-or-pid> "+" <hexstring> ]
        | "ECMA-117-Binary" "+" <hexstring> "+" <hexstring> 
           "+" <hexstring>
        | "ECMA-117-Decimal" "+" <digitstring> "+" 
           <digitstring> "+" <digitstring>
                
<idi> ::= <digitstring>
<afi> ::= "X121" | "DCC" | "TELEX" | "PSTN" | "ISDN" 
                | "ICD" | "LOCAL" 

<prefix> ::= <digit> <digit>         

<ip> ::= <otherstring>
                        -- dotted decimal form (e.g., 10.0.0.6)
                        -- or domain (e.g., twg.com)
<port> ::= <digitstring>
<tset> ::= <digitstring>

<dte> ::= <digitstring>
<cudf-or-pid> ::= "CUDF" | "PID"