DataMuseum.dk

Presents historical artifacts from the history of:

MIKADOS

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about MIKADOS

Excavated with: AutoArchaeologist - Free & Open Source Software.


top - metrics - download

⟦0566c93d0⟧

    Length: 5056 (0x13c0)
    Notes: Mikados TextFile, Mikados_K
    Names: »DEMOSEKV«

Derivation

└─⟦bcf7b34c7⟧ Bits:30003895/4xCOMAL2.imd 4 * COMAL - SPC/1 - Disketter til bogen
    └─⟦this⟧ »DEMOSEKV« 

Text

0100 // ------------------------- demosekvent -------------------------------
0110 // Programmet indlæser v/indtastning elevliste og udskriver
0120 // den. APPEND findes ikke for denne Comal-version.
0130 DIM NAVN$ OF 22,ADR$ OF 22,POSTBY$ OF 20,FIL$ OF 16,KLASSE$ OF 5,S$ OF 1
0140 INTEGER NUMMER,ØNSKE
0150 // 
0160 REPEAT 
0170 EXEC VALG
0180 UNTIL ØNSKE=4
0190 // 
0200 PROC VALG
0210 CLEAR 
0220 CURSOR 1,3
0230 PRINT "     E L E V K A R T O T E K ."
0240 PRINT "     --------------------------------------------------------"
0250 PRINT "     Du har følgende muligheder for at vælge:"
0260 PRINT "     --------------------------------------------------------"
0270 PRINT 
0280 PRINT "     Oprettelse af kartotek............Tast 1"
0290 PRINT 
0300 PRINT "     Tilføjelse i kartotek.............Tast 2"
0310 PRINT 
0320 PRINT "     Udlæsningen af kartotek...........Tast 3"
0330 PRINT 
0340 PRINT "     Ønsker du at slutte...............Tast 4"
0350 CURSOR 5,20
0360 INPUT "Indtast ønske: ":ØNSKE
0370 CASE ØNSKE OF 
0380 WHEN 1
0390 EXEC OPRET
0400 WHEN 2
0410 EXEC TILFØJ
0420 WHEN 3
0430 EXEC UDSKRIFT
0440 OTHERWISE 
0450 CURSOR 5,22
0460 PRINT "Så slutter vi for idag."
0470 ENDCASE 
0480 ENDPROC VALG
0490 // 
0500 PROC OPRET
0510 CLEAR 
0520 CURSOR 1,6
0530 INPUT "Navn på filen :               ":FIL$
0540 NUMMER:=0;FIL$:="SYSTIME:"+FIL$
0550 CREATE FIL$
0560 OPEN FIL$,W
0570 REPEAT 
0580 CLEAR 
0590 CURSOR 1,4
0600 PRINT "Oprettelse af nyt kartotek"
0610 PRINT "--------------------------------------------------------------"
0620 NUMMER:=NUMMER+1
0630 CURSOR 1,8
0640 PRINT "Nummer:         ";NUMMER
0650 PRINT 
0660 INPUT "Indtast klasse:                  ":KLASSE$
0670 INPUT "indtast navn:                    ":NAVN$
0680 INPUT "indtast adresse:                 ":ADR$
0690 INPUT "indtast postnummer & by:         ":POSTBY$
0700 PUT FIL$:NUMMER,KLASSE$,NAVN$,ADR$,POSTBY$
0710 CURSOR 1,22
0720 INPUT "Ønsker du at fortsætte?  j/n ":S$
0730 UNTIL S$="N" OR S$="n"
0740 ENDFILE FIL$
0750 CLOSE FIL$
0760 ENDPROC OPRET
0770 // 
0780 // 
0790 PROC UDSKRIFT
0800 CLEAR 
0810 INPUT "Filens navn:                  ":FIL$
0820 FIL$:="SYSTIME:"+FIL$
0830 PRINT 
0840 OPEN FIL$,R
0850 PRINT "Nr:  Klasse:    Navn:                 Adresse:               ";
0860 PRINT "Postnummer & By"
0870 PRINT "_______________________________________________________________";
0880 PRINT "_____________"
0890 PRINT 
0900 GET FIL$:NUMMER,KLASSE$,NAVN$,ADR$,POSTBY$
0910 WHILE NOT EOF(FIL$) DO 
0920 PRINT NUMMER;TAB(6);KLASSE$;TAB(17);NAVN$;TAB(39);ADR$;TAB(62);POSTBY$
0930 GET FIL$:NUMMER,KLASSE$,NAVN$,ADR$,POSTBY$
0940 ENDWHILE 
0950 CLOSE FIL$
0960 CURSOR 65,22
0970 INPUT "Tast return ":S$
0980 ENDPROC UDSKRIFT
0990 // 
1000 PROC TILFØJ
1010 CLEAR 
1020 CURSOR 25,12
1030 PRINT "APPEND findes ikke på denne Comal-version."
1040 CURSOR 70,23
1050 INPUT "Return!":S$
1060 ENDPROC TILFØJ
1070 // 
1080 PROC EOF(FNAVN$)
1090 EOF:=(STATUS(FNAVN$)=19) // 19 = DDE-comal End-Of-File status nr.
1100 ENDPROC EOF