DataMuseum.dk

top - metrics - download

    Length: 7584 (0x1da0)
    Notes: Mikados TextFile, Mikados_K
    Names: »SLUTSK1«

└─⟦92e6f589c⟧ Bits:30003895/4xCOMAL3b.imd 4 * COMAL - SPC/1 - Disketter til bogen
    └─⟦this⟧ »SLUTSK1« 
└─⟦faca42ef2⟧ Bits:30003895/4xCOMAL1.imd 4 * COMAL - SPC/1 - Disketter til bogen
    └─⟦this⟧ »SLUTSK1« 

Text

0100 // ------------------------ slutskat ------------------------------
0110 // 
0120 // 
0130 EXEC MENU
0140 // -----------------------------------------------------------------
0150 PROC MENU
0160 DIM ØNSKE$ OF 10
0170 CLEAR 
0180 CURSOR 1,3
0190 PRINT " B E R E G N I N G   A F   R E S T S K A T   1 9 8 2 ."
0200 PRINT "------------------------------------------------------"
0210 CURSOR 1,9
0220 PRINT " f o r :"
0230 CURSOR 1,11
0240 PRINT "Hans Hansen."
0250 CURSOR 1,12
0260 PRINT "Vestervej 9,"
0270 CURSOR 1,13
0280 PRINT "9876 Østerby."
0290 CURSOR 1,16
0300 INPUT "Indtast skattepligtig indkomst:                     ":SKINDKOMST
0310 CURSOR 1,18
0320 INPUT "Indtast skattepligtig formue:                       ":SKFORMUE
0330 CURSOR 1,20
0340 INPUT "Indtast pct. for amtskommuneskat:                   ":AMT
0350 CURSOR 1,22
0360 INPUT "Indtast pct. for kommuneskatten:                    ":KOMMUNE
0370 CURSOR 1,24
0380 INPUT "Indtast pct. for kirkeskat:                         ":KIRKE
0390 EXEC PRSTATSSKAT
0400 EXEC KOMMUNESKAT
0410 EXEC PERSONFRADRAG
0420 EXEC PRFORMUESKAT
0430 EXEC UDSKRIFT
0431 SELECT OUTPUT "T"
0440 CURSOR 70,24
0450 INPUT "Return!":ØNSKE$
0460 EXEC FORSKEL
0470 ENDPROC MENU
0480 // ---------------------------------------------------------------
0490 PROC PRSTATSSKAT
0500 IF SKINDKOMST<=95500.0 THEN 
0510 STATSSKAT:=SKINDKOMST*18.9/100
0520 ELSE 
0530 IF SKINDKOMST<=164100.0 THEN 
0540 STATSSKAT:=18049.5+(SKINDKOMST-95500.0)*33.3/100
0550 ELSE 
0560 STATSSKAT:=40893.3+(SKINDKOMST-164100.0)*44.1/100
0570 ENDIF 
0580 ENDIF 
0590 ENDPROC PRSTATSSKAT
0600 // ---------------------------------------------------------------
0610 PROC KOMMUNESKAT
0620 SAMLETPCT:=AMT+KOMMUNE+KIRKE
0630 KOMMUNESKATMV:=SKINDKOMST*SAMLETPCT/100
0640 ENDPROC KOMMUNESKAT
0650 // ----------------------------------------------------------------
0660 PROC PERSONFRADRAG
0670 CLEAR 
0680 CURSOR 1,6
0690 PRINT "            P E R S O N F R A D R A G                        "
0700 CURSOR 1,8
0710 PRINT "------------------------------------------------------------"
0720 CURSOR 1,12
0730 INPUT "Indtast eget personfradrag:                        ":EGETFRADRAG
0740 CURSOR 1,14
0750 INPUT "Indtast overført personfradrag for ægtefælle:      ":ÆGTEFFRADRAG
0760 CURSOR 1,16
0770 PRINT "Personfradrag udregnes.                               "
0780 SAMLETFRADRAG:=EGETFRADRAG+ÆGTEFFRADRAG
0790 SKATAFFRADRAG:=SAMLETFRADRAG*(18.9+(AMT+KOMMUNE+KIRKE))/100
0800 ENDPROC PERSONFRADRAG
0810 // --------------------------------------------------------------------
0820 PROC PRFORMUESKAT
0830 IF SKFORMUE>1083000.0 THEN 
0840 FORMUESKAT:=(SKFORMUE-1083000.0)*22/1000
0850 ELSE 
0860 FORMUESKAT:=0
0870 ENDIF 
0880 ENDPROC PRFORMUESKAT
0890 // -----------------------------------------------------------------
0900 PROC UDSKRIFT
0910 CLEAR 
0920 CURSOR 5,12
0930 INPUT "Ønsker du udskrift på skærm eller printer?   s/p      ":ØNSKE$
0940 IF ØNSKE$ IN "pprinterj" THEN 
0950 EXEC PRINTERRES
0960 ENDIF 
0970 CLEAR 
0980 PRINT "              S L U T S K A T  F O R   1 9 8 2 ."
0990 PRINT "________________________________________________________________"
1000 CURSOR 1,3
1010 PRINT "Hans Hansen,"
1020 PRINT "Vestervej 6,"
1030 PRINT "9876 Østerby."
1040 PRINT "----------------------------------------------------------------"
1050 CURSOR 1,9
1060 PRINT "Skattepligtig indkomst:     ";
1070 PRINT USING " #######.## kr. ":SKINDKOMST
1080 PRINT "Skattepligtig formue:      ";
1090 PRINT USING " ########.## kr. ":SKFORMUE
1100 PRINT "----------------------------------------------------------------"
1110 PRINT 
1120 PRINT "Statsskat:                 ";
1130 PRINT USING " ########.## kr. ":STATSSKAT
1140 PRINT "Amts-,kommune- & kirkeskat:";
1150 PRINT USING " ########.## kr. ":KOMMUNESKATMV
1160 PRINT "Formueskat:                ";
1170 PRINT USING " ########.## kr. ":FORMUESKAT
1180 IALT:=STATSSKAT+KOMMUNESKATMV+FORMUESKAT
1190 PRINT "----------------------------------------------------------------"
1200 PRINT "Skat ialt:                 ";
1210 PRINT USING " ########.## kr. ":IALT
1220 PRINT "Skat af personfradrag:     ";
1230 PRINT USING " ########.## kr. ":SKATAFFRADRAG
1240 ENDELIGSKAT:=IALT-SKATAFFRADRAG
1250 PRINT "----------------------------------------------------------------"
1260 PRINT "Slutskat for 1982:         ";
1270 PRINT USING " ########.## kr. ":ENDELIGSKAT
1280 PRINT "================================================================"
1290 ENDPROC UDSKRIFT
1300 // ---------------------------------------------------------------------
1310 PROC FORSKEL
1315 SELECT OUTPUT "T"
1320 CLEAR 
1340 CURSOR 1,3
1350 PRINT " S k a l   d u   h a v e   p e n g e   t i l b a g e   e l l e r"
1360 PRINT " s k a l   d u   b e t a l e ?                                  "
1370 PRINT "----------------------------------------------------------------"
1380 CURSOR 1,8
1390 INPUT "Indtast den samlede betalte skat for 1982:                ":SKAT
1410 CURSOR 1,10
1420 INPUT "Ønsker du udskrift på skærm eller printer?   s/p         ":ØNSKE$
1430 IF ØNSKE$ IN "pprinter" THEN 
1440 EXEC PRINTERRES
1450 ELSE 
1460 CLEAR 
1470 ENDIF 
1480 DIFFERENCE:=SKAT-ENDELIGSKAT
1490 CURSOR 1,5
1500 PRINT "Samlede betalte personlige skatter:";
1510 PRINT USING " ########.## kr. ":SKAT
1520 PRINT "Slutskat:                          ";
1530 PRINT USING " ########.## kr. ":ENDELIGSKAT
1540 PRINT "================================================================"
1550 CURSOR 1,9
1560 IF DIFFERENCE=>0 THEN 
1570 PRINT "Du skal have                ";
1580 PRINT USING "         #######.## kr. tilbage. ":DIFFERENCE
1590 PRINT "================================================================"
1600 ELSE 
1610 PRINT "Du skal efterbetale         ";
1620 PRINT USING "         #######.## kr.          ":-DIFFERENCE
1630 PRINT "================================================================"
1640 CURSOR 1,12
1650 PRINT "Du skal ikke tage det for højtideligt, vi er mange i samme båd."
1660 ENDIF 
1670 ENDPROC FORSKEL
1680 // 
1690 PROC PRINTERRES
1700 SELECT OUTPUT "P"
1710 IF STATUS("P")=1 THEN 
1720 CURSOR 12,15
1730 PRINT "Printeren er reserveret af en anden bruger, skal "
1740 CURSOR 12,16
1750 INPUT "der ventes på at den bliver ledig ? (j/n) ":ØNSKE$
1760 CURSOR 1,15
1770 PRINT "<Z>"
1780 PRINT "<Z>"
1790 IF ØNSKE$="j" OR ØNSKE$="J" THEN 
1800 CURSOR 12,15
1810 PRINT "Der ventes på at printeren bliver ledig........"
1820 WHILE STATUS("P")=1 DO SELECT OUTPUT "P"
1830 ENDIF 
1840 ENDIF 
1850 ENDPROC PRINTERRES