DataMuseum.dk

top - metrics - download

    Length: 5056 (0x13c0)
    Notes: Mikados TextFile, Mikados_K
    Names: »DEMO_2«

└─⟦92e6f589c⟧ Bits:30003895/4xCOMAL3b.imd 4 * COMAL - SPC/1 - Disketter til bogen
    └─⟦this⟧ »DEMO_2« 
└─⟦faca42ef2⟧ Bits:30003895/4xCOMAL1.imd 4 * COMAL - SPC/1 - Disketter til bogen
    └─⟦this⟧ »DEMO_2« 

Text

0100 // ------------------------- demosekvent -------------------------------
0110 // Programmet indlæser v/indtastning elevliste og udskriver
0120 // den. APPEND findes ikke for denne Comal-version.
0130 DIM NAVN$ OF 22,ADR$ OF 22,POSTBY$ OF 20,FIL$ OF 16,KLASSE$ OF 5,S$ OF 1
0135 INTEGER NUMMER,ØNSKE
0140 // 
0150 REPEAT 
0160 EXEC VALG
0170 UNTIL ØNSKE=4
0180 // 
0190 PROC VALG
0200 CLEAR 
0210 CURSOR 1,3
0220 PRINT "     E L E V K A R T O T E K ."
0230 PRINT "     --------------------------------------------------------"
0240 PRINT "     Du har følgende muligheder for at vælge:"
0250 PRINT "     --------------------------------------------------------"
0260 PRINT 
0270 PRINT "     Oprettelse af kartotek............Tast 1"
0280 PRINT 
0290 PRINT "     Tilføjelse i kartotek.............Tast 2"
0300 PRINT 
0310 PRINT "     Udlæsningen af kartotek...........Tast 3"
0320 PRINT 
0330 PRINT "     Ønsker du at slutte...............Tast 4"
0340 CURSOR 5,20
0350 INPUT "Indtast ønske: ":ØNSKE
0360 CASE ØNSKE OF 
0370 WHEN 1
0380 EXEC OPRET
0390 WHEN 2
0400 EXEC TILFØJ
0410 WHEN 3
0420 EXEC UDSKRIFT
0430 OTHERWISE 
0440 CURSOR 5,22
0450 PRINT "Så slutter vi for idag."
0460 ENDCASE 
0470 ENDPROC VALG
0480 // 
0490 PROC OPRET
0500 CLEAR 
0510 CURSOR 1,6
0520 INPUT "Navn på filen :               ":FIL$
0530 NUMMER:=0;FIL$:="SYSTIME:"+FIL$
0540 CREATE FIL$
0550 OPEN FIL$,W
0560 REPEAT 
0570 CLEAR 
0580 CURSOR 1,4
0590 PRINT "Oprettelse af nyt kartotek"
0600 PRINT "--------------------------------------------------------------"
0610 NUMMER:=NUMMER+1
0620 CURSOR 1,8
0630 PRINT "Nummer:         ";NUMMER
0640 PRINT 
0650 INPUT "Indtast klasse:                  ":KLASSE$
0660 INPUT "indtast navn:                    ":NAVN$
0670 INPUT "indtast adresse:                 ":ADR$
0680 INPUT "indtast postnummer & by:         ":POSTBY$
0690 PUT FIL$:NUMMER,KLASSE$,NAVN$,ADR$,POSTBY$
0700 CURSOR 1,22
0710 INPUT "Ønsker du at fortsætte?  j/n ":S$
0720 UNTIL S$="N" OR S$="n"
0730 ENDFILE FIL$
0740 CLOSE FIL$
0750 ENDPROC OPRET
0760 // 
0770 // 
0780 PROC UDSKRIFT
0790 CLEAR 
0800 INPUT "Filens navn:                  ":FIL$
0810 FIL$:="SYSTIME:"+FIL$
0820 PRINT 
0830 EXEC PRINTER
0840 OPEN FIL$,R
0850 PRINT "Nr:  Klasse:    Navn:                 Adresse:               ";
0860 PRINT "Postnummer & By"
0870 PRINT "_______________________________________________________________";
0880 PRINT "_____________"
0890 PRINT 
0900 GET FIL$:NUMMER,KLASSE$,NAVN$,ADR$,POSTBY$
0910 WHILE NOT EOF(FIL$) DO 
0920 PRINT NUMMER;TAB(6);KLASSE$;TAB(17);NAVN$;TAB(39);ADR$;TAB(62);POSTBY$
0930 GET FIL$:NUMMER,KLASSE$,NAVN$,ADR$,POSTBY$
0940 ENDWHILE 
0950 CLOSE FIL$
0960 SELECT OUTPUT "T"
0970 CURSOR 65,22
0980 INPUT "Tast return ":S$
0990 ENDPROC UDSKRIFT
1000 // 
1010 PROC TILFØJ
1020 CLEAR 
1030 CURSOR 25,12
1040 PRINT "APPEND findes ikke på denne Comal-version."
1050 CURSOR 70,23
1060 INPUT "Return!":S$
1070 ENDPROC TILFØJ
1080 // 
1090 PROC PRINTER
1100 CURSOR 1,5
1110 INPUT "Ønsker du udskrift på printer?   (p/s): ":S$
1120 IF S$="P" OR S$="p" THEN 
1130 SELECT OUTPUT "P"
1140 IF STATUS("P")=1 THEN 
1150 CURSOR 1,5
1160 PRINT "Printeren er reserveret af anden bruger."
1170 INPUT "Skal der ventes på at den bliver ledig (j/n) ? ":S$
1180 CURSOR 1,5
1190 PRINT "                                                    "
1200 PRINT "                                                    "
1210 IF S$="J" OR S$="j" THEN 
1220 CURSOR 1,5
1230 PRINT "Der ventes på at printeren bliver ledig"
1240 WHILE STATUS("P")<>0 DO SELECT OUTPUT "P"
1250 ELSE 
1260 SELECT OUTPUT "T"
1270 ENDIF 
1280 ENDIF 
1290 ENDIF 
1300 ENDPROC PRINTER
1310 
1320 PROC EOF(FNAVN$)
1330 EOF:=(STATUS(FNAVN$)=19) // 19 = DDE-comal End-Of-File status nr.
1340 ENDPROC EOF