DataMuseum.dk

top - metrics - download

    Length: 5056 (0x13c0)
    Notes: Mikados TextFile, Mikados_K
    Names: »REJSEB2«

└─⟦4cd80c18f⟧ Bits:30003895/4xCOMAL3a.imd 4 * COMAL - SPC/1 - Disketter til bogen
    └─⟦this⟧ »REJSEB2« 
└─⟦bcf7b34c7⟧ Bits:30003895/4xCOMAL2.imd 4 * COMAL - SPC/1 - Disketter til bogen
    └─⟦this⟧ »REJSEB2« 

Text

0100 // ----------------------- Rejsebureau-2 ---------------------
0110 // Programmet udskriver pris og restantal for destinationer i
0120 // Europa.
0130 // 
0140 INTEGER TRUE,FALSE,ANTALREJSEMÅL,I,ANTAL
0150 FALSE:=0;TRUE:=1
0160 DIM REJSEMÅL$ OF 30,DESTINATION$ OF 30,ØNSKE$ OF 3,S$ OF 1
0170 EXEC MENU
0180 // 
0190 PROC MENU
0200 RESTORE 
0210 CLEAR 
0220 CURSOR 1,3
0230 PRINT "  R E J S E B U R E A U     'Den gyldne sol'     "
0240 CURSOR 1,4
0250 PRINT "-------------------------------------------------"
0260 CURSOR 1,10
0270 PRINT "Vi har følgende destinationer:     "
0280 CURSOR 1,11
0290 PRINT "------------------------------     "
0300 CURSOR 1,13
0310 PRINT "London - Paris - Oslo - Stockholm - Madrid - Helsingfors"
0320 PRINT "Rom - Moskva - Bern - Amsterdam - Bruxelles - Lissabon "
0330 CURSOR 1,18
0340 INPUT "Hvorhen ønsker De at rejse?   ":REJSEMÅL$
0350 // 
0360 FUNDET:=FALSE
0370 OPEN "systime:rejsefil",W
0380 GET "systime:rejsefil":DESTINATION$,PRIS,ANTAL
0390 WHILE NOT EOF("systime:rejsefil") DO 
0400 IF DESTINATION$=REJSEMÅL$ THEN 
0410 CLEAR 
0420 EXEC UDSKRIFT
0430 EXEC PRINTER
0440 FUNDET:=TRUE
0450 ENDIF 
0460 GET "systime:rejsefil":DESTINATION$,PRIS,ANTAL
0470 ENDWHILE 
0480 CLOSE 
0490 IF NOT FUNDET THEN EXEC FEJLSKRIFT
0500 ENDPROC MENU
0510 // 
0520 PROC FEJLSKRIFT
0530 CLEAR 
0540 CURSOR 1,10
0550 PRINT "Vi har desværre ingen rejser til:  ";REJSEMÅL$
0560 CURSOR 1,20
0570 INPUT "Har De ikke lyst til at rejse et andet sted hen? ":ØNSKE$
0580 IF ØNSKE$ IN "JA,ja" THEN 
0590 EXEC MENU
0600 ELSE 
0610 END 
0620 ENDIF 
0630 ENDPROC FEJLSKRIFT
0640 // 
0650 PROC UDSKRIFT
0660 CURSOR 1,6
0670 PRINT "  R e j d e b u r e a u    'Den gyldne sol'    "
0680 CURSOR 1,7
0690 PRINT "-----------------------------------------------"
0700 CURSOR 1,10
0710 PRINT "Vi kan tilbyde Dem en rejse til:               "
0720 CURSOR 1,12
0730 PRINT "Rejsemål:                        ";DESTINATION$
0740 CURSOR 1,13
0750 PRINT USING "Pris:                        ########.## kr.":PRIS
0760 CURSOR 1,14
0770 PRINT "Restpladser:                     ";ANTAL
0780 ENDPROC UDSKRIFT
0790 // 
0800 PROC PRINTER
0810 SELECT OUTPUT "T"
0830 CURSOR 1,22
0840 INPUT "Ønskes udskrift på printer?   (j/n)   ":S$
0850 IF S$="J" OR S$="j" THEN 
0860 SELECT OUTPUT "P"
0870 IF STATUS("P")=1 THEN 
0880 CURSOR 1,22
0890 PRINT "<Z>Printer er reserveret af anden bruger,"
0900 INPUT " Skal der ventes på at den bliver ledig?  (j/n)  ":S$
0910 IF S$="J" OR S$="j" THEN 
0920 CURSOR 1,23
0930 PRINT "<Z>Der ventes på at printeren bliver ledig"
0940 WHILE STATUS("P")=1 DO SELECT OUTPUT "P"
0950 ELSE 
0960 SELECT OUTPUT "T"
0970 ENDIF 
0980 ENDIF 
0990 EXEC UDSKRIFT
1000 ENDIF 
1010 SELECT OUTPUT "T"
1020 CURSOR 1,21
1030 PRINT "                                       "
1040 PRINT "Så slutter vi for i dag .                      "
1050 END 
1080 ENDPROC PRINTER
1090 // 
1100 PROC EOF(FNAVN$)
1110 EOF:=(STATUS(FNAVN$)=19)
1120 ENDPROC EOF