DataMuseum.dk

top - metrics - download

    Length: 7584 (0x1da0)
    Notes: Mikados TextFile, Mikados_K
    Names: »RUMFANG4«

└─⟦92e6f589c⟧ Bits:30003895/4xCOMAL3b.imd 4 * COMAL - SPC/1 - Disketter til bogen
    └─⟦this⟧ »RUMFANG4« 
└─⟦faca42ef2⟧ Bits:30003895/4xCOMAL1.imd 4 * COMAL - SPC/1 - Disketter til bogen
    └─⟦this⟧ »RUMFANG4« 

Text

0010 // ------------------------ rumfang4 ---------------------------
0020 // Udregner forskellige rumfang ved benyttelse af CASE - ENDCASE
0030 // samt procedure-sætninger.
0040 DIM SV$ OF 3
0050 REPEAT 
0060 CLEAR 
0070 CURSOR 10,3
0080 PRINT "Dette program udskriver rumfanget af:"
0090 CURSOR 10,4
0100 PRINT "-------------------------------------"
0110 PRINT 
0120 CURSOR 10,6
0130 PRINT "Kasse.....................................Tast 1"
0140 CURSOR 10,8
0150 PRINT "Pyramide..................................Tast 2"
0160 CURSOR 10,10
0170 PRINT "Pyramidestub..............................Tast 3"
0180 CURSOR 10,12
0190 PRINT "Cylinder..................................Tast 4"
0200 CURSOR 10,14
0210 PRINT "Kegle.....................................Tast 5"
0220 CURSOR 10,16
0230 PRINT "Keglestub.................................Tast 6"
0240 CURSOR 10,18
0250 PRINT "Kugle.....................................Tast 7"
0260 CURSOR 10,20
0270 PRINT "Stop......................................Tast 8"
0280 CURSOR 10,16
0290 PRINT 
0300 PRINT 
0310 CURSOR 10,22
0320 PRINT "Indtast det ønskede nummer for rumfang:";
0330 INPUT ØNSKE
0340 // ---------------------------------------------------------------
0350 PRINT 
0360 CASE ØNSKE OF 
0370 WHEN 1
0380 EXEC KASSE
0390 WHEN 2
0400 EXEC PYRAMIDE
0410 WHEN 3
0420 EXEC PYRAMIDESTUB
0430 WHEN 4
0440 EXEC CYLINDER
0450 WHEN 5
0460 EXEC KEGLE
0470 WHEN 6
0480 EXEC KEGLESTUB
0490 WHEN 7
0500 EXEC KUGLE
0510 CURSOR 70,22
0520 WHEN 8
0530 EXEC SLUT
0540 OTHERWISE 
0550 CLEAR 
0560 CURSOR 20,12
0570 PRINT "Du har tastet forkert. Prøv igen."
0580 ENDCASE 
0590 CURSOR 68,23
0600 PRINT "Return!";
0610 INPUT SV$
0620 UNTIL ØNSKE=8
0630 // --------------------------------------------------------------------
0640 PROC KASSE
0650 CLEAR 
0660 CURSOR 1,6
0670 PRINT "                          K A S S E . "
0680 PRINT "________________________________________________________________"
0690 CURSOR 1,10
0700 INPUT "Indtast længde:                            ":LÆNGDE
0710 PRINT 
0720 INPUT "Indtast bredde:                            ":BREDDE
0730 PRINT 
0740 INPUT "Indtast højde:                             ":HØJDE
0750 PRINT 
0760 PRINT 
0770 RUMFANG:=LÆNGDE*BREDDE*HØJDE
0780 PRINT "Rumfanget af kassen:                       ";RUMFANG
0790 ENDPROC KASSE
0800 // ------------------------------------------------------------------
0810 PROC PYRAMIDE
0820 CLEAR 
0830 CURSOR 1,5
0840 PRINT "                           P Y R A M I D E ."
0850 PRINT "________________________________________________________________"
0860 CURSOR 1,10
0870 INPUT "Indtast længde:                                  ":LÆNGDE
0880 PRINT 
0890 INPUT "Indtast bredde:                                  ":BREDDE
0900 PRINT 
0910 INPUT "Indtast højde:                                   ":HØJDE
0920 RUMFANG:=INT(1/3*HØJDE*BREDDE*LÆNGDE*100)/100
0930 PRINT 
0940 PRINT "Rumfanget af en pyramide med de ønskede mål:     ";RUMFANG
0950 ENDPROC PYRAMIDE
0960 // ------------------------------------------------------------------
0970 PROC PYRAMIDESTUB
0980 CLEAR 
0990 CURSOR 1,5
1000 PRINT "                       P Y R A M I D E S T U B .    "
1010 PRINT "________________________________________________________________"
1020 CURSOR 1,10
1030 INPUT "Indtast længden i bundfladen:              ":L1
1040 PRINT 
1050 INPUT "Indtast bredden i bundfladen:              ":B1
1060 PRINT 
1070 INPUT "Indtast længden i den øverste flade:       ":L2
1080 PRINT 
1090 INPUT "Indtast bredden i den øverste flade:       ":B2
1100 PRINT 
1110 INPUT "Indtast pyramidestubbens højde:            ":HØJDE
1120 RUMFANG:=(HØJDE/3)*(L1*B1+L2*B2+SQR(L1*B1*L2*B2))
1130 PRINT 
1140 PRINT 
1150 PRINT "Rumfanget af en pyramidestub med de ønskede mål:         ";RUMFAN
1160 ENDPROC PYRAMIDESTUB
1170 // ------------------------------------------------------------------
1180 PROC CYLINDER
1190 CLEAR 
1200 CURSOR 1,5
1210 PRINT "                      C Y L I N D E R .  "
1220 PRINT "________________________________________________________________"
1230 CURSOR 1,10
1240 INPUT "Indtast cylinderens radius:               ":RADIUS
1250 PRINT 
1260 INPUT "Indtast cylinderens højde:                ":HØJDE
1270 RUMFANG:=INT(3.14159*HØJDE*RADIUS**2*100)/100
1280 PRINT 
1290 PRINT 
1300 PRINT "Cylinderens rumfang med de ønskede mål:       ";RUMFANG
1310 ENDPROC CYLINDER
1320 // ------------------------------------------------------------------
1330 PROC KEGLE
1340 CLEAR 
1350 CURSOR 1,5
1360 PRINT "                            K E G L E . "
1370 PRINT "________________________________________________________________"
1380 CURSOR 1,10
1390 INPUT "Indtast keglens radius:                   ":RADIUS
1400 PRINT 
1410 INPUT "Indtast keglens højde:                    ":HØJDE
1420 RUMFANG:=1/3*HØJDE*RADIUS**2
1430 PRINT 
1440 PRINT 
1450 PRINT "Keglens rumfang med de ønskede mål:       ";RUMFANG
1460 ENDPROC KEGLE
1470 // ------------------------------------------------------------------
1480 PROC KEGLESTUB
1490 CLEAR 
1500 CURSOR 1,5
1510 PRINT "                       K E G L E S T U B .     "
1520 PRINT "________________________________________________________________"
1530 PRINT 
1540 CURSOR 1,10
1550 INPUT "Indtast keglestubbens nederste radius:      ":R1
1560 PRINT 
1570 INPUT "Indtast keglestubbens øverste radius:       ":R2
1580 PRINT 
1590 INPUT "Indtast keglestubbens højde:                ":HØJDE
1600 PRINT 
1610 RUMFANG:=1/3*3.14159*HØJDE*(R1**2+R2**2+R1*R2)
1620 PRINT 
1630 PRINT "Rumfanget af en keglestub med de ønskede mål:      ";RUMFANG
1640 ENDPROC KEGLESTUB
1650 // -----------------------------------------------------------------
1660 PROC KUGLE
1670 CLEAR 
1680 CURSOR 1,5
1690 PRINT "                          K U G L E .     "
1700 PRINT "________________________________________________________________"
1710 CURSOR 1,10
1720 INPUT "Indtast kuglens radius:                    ":RADIUS
1730 RUMFANG:=4/3*3.14159*RADIUS**3
1740 CURSOR 1,16
1750 PRINT "Rumfanget af en kugle, hvor radius er: ";
1755 PRINT RADIUS;" = ";INT(RUMFANG*100)/100
1760 ENDPROC KUGLE
1770 // ------------------------------------------------------------------
1780 PROC SLUT
1790 CLEAR 
1800 CURSOR 15,12
1810 PRINT "Det var så en del nye rumfang. Tak for nu. "
1820 CURSOR 1,21
1830 END 
1840 ENDPROC SLUT