DataMuseum.dk

top - metrics - download

    Length: 4080 (0xff0)
    Notes: OS65UFile, OSU65U-BASIC
    Names: »LDKFMF«

└─⟦2f57871a3⟧ Bits:30009355 Ohio Scientific OS-OMS Nucleus, delvist oversat til dansk
    └─⟦this⟧ »LDKFMF« 

BASIC

00001 PRINT"** PROGRAM NOT EXECUTABLE FROM CONSOLE **":RUN"DBMSYS","PASS"
00002 CLOSE:CLEAR:REM 1/79  LOAD KEY FILE FROM MASTER FILE  (LDKFMF)
00003 REM                  (LDKFMF)
00005 REM     OS-65U DATA BASE MANAGEMENT SYSTEM
00006 REM         7/78 LOAD KEY FILE FROM MASTER FILE
00010 FLAG11:FLAG9:REM FLG11-SPACE SUPPRESSION  FLG9-ON ERROR GOTO 50000
00049 REM     GET CURRENT DEVICE NUMBER (DV$(2))
00050 DV(2)=PEEK(9832): IF DV(2)>127 THEN DV(2)=DV(2)-128+4
00060 DV$(2)=CHR$(DV(2)+65)
00090 FOR I=1 TO 27:PRINT:NEXTI
00092 PRINT"   DB-2   L[S N\GLE FIL FRA MASTER FIL"
00094 PRINT"   ===================================":PRINT:PRINT:PRINT
00095 PRINT
00100 REM  LINES 100-200 AVAIABLE FOR PROGRAM INSTRUCTIONS
00198 REM
00199 REM     INPUT & CHECK KEY FILE NAME & PASSWORD
00200 INPUT"HVILKEN STATION LIGGER N\GLE FILEN P] ";DV$(1)
00201 IFDV$(1)=""ORLEN(DV$(1))>1THENPRINT:PRINT"*** FORKERT !!":GOTO200  
00202 IF DV$(1)<"A"ORDV$(1)>"E"THENPRINT:PRINT"*** FORKERT !!":GOTO200
00203 INPUT"INDTAST N\GLE FIL, KODEORD ";F$(1),PW$(1)
00204 IFF$(1)=""ORPW$(1)=""THENPRINT:PRINT"*** FORKERT !!":GOTO203
00205 IFLEN(F$(1))<5THENF$(1)=F$(1)+" ":GOTO205
00207 IFLEN(F$(1))>6THENPRINT:PRINT"*** UGYLDIGT FILNAVN":GOTO203
00208 F$(1)=LEFT$(F$(1),5)
00209 IFPW$(1)="."ORPW$(1)="."THENPW$(1)="ANAN"
00210 IFLEN(PW$(1))<>4THENPRINT:PRINT"*** UGYLDIGT KODEORD":GOTO203
00211 INPUT"FIL NR. (1-7) ";Y:IFY>0ANDY<8 GOTO 219
00212 PRINT"*** FORKERT FIL NUMMMER (FRA 1 TIL 7) ***":GOTO 208
00218 PRINT:PRINT:PRINT
00219 INPUT"HVILKEN STATION ER MASTER FILEN P]";DV$(3):IFDV$(3)=""GOTO219
00220 IFDV$(3)<"A"ORDV$(3)>"E"THENPRINT:PRINT"*** FORKERT !!":GOTO 219
00221 INPUT"INDTAST MASTER FILENS KODEORD ";PW$(2)
00222 IF LEN(PW$(2))>4 THEN PW$(2)=LEFT$(PW$(2),4)
00224 IF PW$(2)="." THEN PW$(2)="ANAN"
00225 IFLEN(PW$(2))<4 THEN PRINT"*** FORKERT KODEORD":GOTO 221
00226 FORX=1TO32:PRINT:NEXT:PRINT:PRINT" VENT !!!"
00227 POKE2972,13:POKE2976,13:REM ACCEPT :,;& IN FIELDS
00249 REM     OPEN AND CHECK KEY FILE
00250 DEVDV$(1):F$(1)=LEFT$(F$(1),5)+RIGHT$(STR$(Y),1)
00260 OPEN F$(1),PW$(1),1
00265 F$(1)=LEFT$(F$(1),5)
00270 INPUT%1,T$
00280 INDEX<1>=6: INPUT%1,TY
00290 IF T$=F$(1) GOTO 310
00300 PRINT"*** FORKERTE FIL NAVNE ****": GOTO 330
00310 IF TY>10 AND T<18 GOTO 400
00320 PRINT"*** FIL NUMMMER FINDES IKKE ***"
00330 CLOSE 1: DEV DV$(2):GOTO 200
00398 REM
00399 REM     CHECK FOR KEY FILE ALREADY LOADED
00400 REM
00499 REM     GET MASTER FILE HEADER
00500 F$(2)=LEFT$(F$(1),5)+"0": REM CONSTRUCT MASTER NAME
00505 DEV DV$(3)
00510 OPEN F$(2),PW$(2),2
00514 INDEX<2>=9: INPUT%2,E
00515 INDEX<2>=20: INPUT%2,BODF
00517 INDEX<2>=31: INPUT%2,RL
00518 INDEX<2>=42: INPUT%2,RN
00520 INDEX<2>=53: N=1
00530 INPUT%2,K$: INPUT%2,L
00540 IF INDEX(2)<BODF THEN N=N+1: GOTO 530
00550 INDEX<2>=53: DIM FDLB$(N),FL(N)
00560 FOR I=1 TO N: INPUT%2,FDLB$(I): INPUT %2,FL(I): NEXT I
00598 REM
00600 INDEX<1>=42:DEV DV$(1):INPUT %1,KN$
00610 FORI=1 TO N:IF KN$=FDLB$(I) GOTO 630
00615 NEXT I
00620 PRINT"FELT ";KN$;" EJ FUNDET I FILEN ";F$(2): GOTO 980
00630 EF=I:REM EF=FIELD #
00698 REM
00699 REM     LOAD KEY FILE FROM MASTER 
00700 RPTR=1:ML=0
00705 IF EF=N THEN ML=0:GOTO710
00706 FOR I=(EF+1) TO N: ML=ML+FL(I):NEXT I
00710 BDF=43+LEN(KN$):INDEX<1>=BDF
00730 IF EF=1 THEN FOS=0: GOTO 750
00739 FOS=0
00740 FOR K=1 TO (EF-1):FOS=FOS+(FL(K)):NEXT K
00750 INDEX<2>=((RPTR-1)*RL)+FOS+BODF
00751 IPTR=BODF+((RPTR-1)*RL)
00755 O$="^":DEV DV$(3):
00760 INPUT %2,T$:DEV DV$(1):PRINT %1,O$+T$:PRINT %1,IPTR
00765 IF INDEX(2)>=(E-ML) GOTO 800
00770 RPTR=RPTR+1
00780 IF RPTR<=RN GOTO 730
00800 EODF=INDEX(1):INDEX<1>=9:PRINT%1,EODF
00900 REM
00950 PRINT:PRINT"N\GLE FIL: ";F$(1)+RIGHT$(STR$(Y),1)
00960 PRINT"NAVN ";FDLB$(EF)
00965 PRINT
00970 PRINT"                N\GLE FILEN ER F[RDIG "
00980 CLOSE 1: CLOSE 2: DEV DV$(2)
00990 FLAG12:POKE2888,27
00992 POKE 2976,44:POKE 2972,58
01000 RUN"DBMSYS","PASS"
50000 DE=PEEK(10226):DL=PEEK(11774)+PEEK(11775)*256
50010 XC=XC+1:IFXC<2GOTO50030
50020 PRINT"*** KONTROLER AT DISKETTERNE ER PLACERET RIGTIGT ***"
50030 PRINT:PRINT"*** FEJL ";DE;" I LINIE ";DL;" ***"
50040 POKE2972,58:POKE2976,44:FLAG12
50045 PRINT:INPUT"TAST RETURN, HVIS FORS[TTELSE ";QA$
50047 FORX=1TO32:PRINT:NEXT
50050 CLOSE:DEVDV$(2):RUN"DBMSYS","PASS