DataMuseum.dk

top - metrics - download

    Length: 2032 (0x7f0)
    Notes: OS65UFile, OSU65U-BASIC
    Names: »KDUMP«

└─⟦2f57871a3⟧ Bits:30009355 Ohio Scientific OS-OMS Nucleus, delvist oversat til dansk
    └─⟦this⟧ »KDUMP« 

BASIC

00002 REM KEY FILE DUMP UTILITY (OSI 1978)
00010 PRINT"           ***KEY FILE DUMP UTILITY***"
00020 PRINT
00030 INPUT"KEY FILE NAME (COMPLETE OS-65U FILE NAME) ";A$
00040 IF LEN(A$)<>6 GOTO 30
00050 PRINT:INPUT"KEY FILE PASSWORD";PW$
00060 IF PW$="." THEN PW$="ANAN"
00070 IF LEN(PW$)<>4 THEN GOTO 50
00080 DV(2)=PEEK(9832):IF DV(2)>127 THEN DV(2)=DV(2)-128+4
00090 DV$(2)=CHR$(DV(2)+65)
00100 PRINT:INPUT"DEVICE KEY FILE STORED ON";DV$(1)
00110 IF DV$(1)<>"A" AND DV$(1)<>"B" AND DV$(1)<>"E" THEN GOTO 100
00160 DEV DV$(1)
00166 PRINT
00170 INPUT"CONSOLE(C) OR PRINTER(P) ";V$
00180 IF LEFT$(V$,1)="P" THEN VD=5:GOTO  190
00185 IF LEFT$(V$,1)="C" THEN VD=PEEK(11665):GOTO 190
00188 IF LEFT$(V$,1)<>"P" AND LEFT$(V$,1)<>"C" THEN GOTO 170
00190 REM
00250 OPEN A$,PW$,2
00260 INDEX<2>=42:INPUT %2,LN$
00270 INDEX<2>=43+LEN(LN$)
00275 FORZ=1 TO 40:PRINT #VD:NEXT Z
00278 S$="-"
00280 PRINT #VD
00290 PRINT #VD,"         ***KEY FILE DUMP OF ";A$;:PRINT #VD," ***"
00300 PRINT #VD
00310 PRINT #VD,"            *KEY FILE LABEL IS ";LN$;:PRINT #VD,"*"
00320 FORZ=1 TO LEN(LN$):PRINT #VD,TAB(31);S$;:NEXT Z
00330 PRINT #VD
00370 PRINT #VD,"          KEY                    INDEX"
00375 PRINT #VD,"          ***                    *****"
00380 PRINT #VD
00385 FLAG1:FLAG5
00395 INPUT%2,L$:INPUT%2,I
00398 IF INDEX(2)>1E8 THEN GOTO 500
00400 PRINT #VD,TAB(10);L$;TAB(32);I
00410 GOTO 395
00500 FLAG2:FLAG6:CLOSE2
00510 DEV DV$(2):CLOSE
00520 END