DataMuseum.dk

top - metrics - download

    Length: 3056 (0xbf0)
    Notes: OS65UFile, OSU65U-BASIC
    Names: »BEXEC*«

└─⟦2f57871a3⟧ Bits:30009355 Ohio Scientific OS-OMS Nucleus, delvist oversat til dansk
    └─⟦this⟧ »BEXEC*« 

BASIC

00010 REM *** BASIC EXECUTIVE ***
00020 REM
00030 REM SETUP CONSOLE INPUT DEVICE
00040 I% = PEEK (11664)
00041 REM  
00042 REM  LOCKUP SYSTEM
00043 FLAG 21: REM  INPUT ESCAPE
00044 POKE 2073,96: POKE 14639,0: REM  CTRL C,O
00050 POKE 11668, 2^(I%-1)
00060 REM
00070 REM SETUP CONSOLE OUTPUT DEVICE
00080 J% = PEEK (11665)
00090 POKE 11686, 2^(J%-1)
00140 REM SETUP FOR MASTER 3300 SYSTEM
00150 POKE 61438,0: POKE 61439,0
00170 REM  GET USER FUNCTION
00190 FU$="XYZ"
00210 IF FU$ <> "UNLOCK" GOTO 280
00220 REM  
00230 REM  UNLOCK SYSTEM
00240 REM  
00250 FLAG 22: REM  INPUT ESCAPE
00270 POKE 14639,255: POKE 2073,76: REM  CTRL C,O
00280 REM
00290 REM FOR BACK SPACE THIS LINE SHOULD SAY GOSUB 5000
00305 POKE 2888,27
00307 GOSUB 9000
00308 DEV"A"
00310 RUN"DBMSYS","PASS":REM COMMON EXIT FROM BEXEC*
00320 REM
01000 FOR X=1 TO 35:PRINT:NEXT: REM    SET UP PRINTERS
01005 POKE 2888,0
01006 PRINTTAB(20);"<<  PRINTER INITIALIZATION  >>":PRINT:PRINT:PRINT
01010 PRINT"SELECT TYPE OF PRINTER":PRINT
01020 PRINT TAB(4);"(1)  CENTRONICS 700 SERIES"
01030 PRINT TAB(4);"(2)  OKIDATA 22"
01035 PRINT TAB(4);"(3)  NO PRINTER"
01040 PRINT
01050 INPUT "   ";A
01055 IF (A=1 OR A=2 OR A=3) AND A=INT(A) GOTO 1060
01056 GOTO 1050
01060 ON A GOTO 1070,1200,1520
01065 REM
01070 PRINT:PRINT"PLEASE WAIT":REM   CENTRONICS SET UP
01075 FOR X=1 TO PEEK(15908):PRINT#5:NEXT
01080 FOR X=1 TO 35:PRINT:NEXT:PRINT TAB(7);
01090 PRINT"<<  SET THE PAPER ON THE PRINTER TO THE TOP OF FORM.  >>"
01095 FOR X=1 TO 8:PRINT:NEXT
01100 PRINT:INPUT"ENTER A  C  TO CONTINUE";X$:RETURN
01101 REM
01200 FOR X=1 TO 35:PRINT:NEXT:REM   OKIDATA SET UP
01210 PRINT"SELECT THE TYPE OF PAPER TO BE USED"
01220 PRINT
01230 PRINT TAB(4);"(1)  8 1/2 INCH LONG PAPER"
01240 PRINT TAB(4);"(2)  11 INCH LONG PAPER"
01250 PRINT TAB(4);"(3)  SPECIAL PAPER"
01260 PRINT
01270 INPUT"   ";A:IF A=1 OR A=2 OR A=3 GOTO 1280
01275 GOTO 1270
01280 ON A GOTO 1290,1300,1310
01290 POKE 14387,68:GOTO 1400
01300 POKE 14387,66:GOTO 1400
01310 POKE 14457,66:PRINT:PRINT:PRINT
01320 PRINTTAB(7);
01325 PRINT"<<  PRINTER PAGING IS NOW ON MANUAL  >>"
01330 PRINT:PRINT:PRINT:FOR X=1TO 1000:NEXT:RETURN
01400 FOR X=1 TO 35:PRINT:NEXT
01410 PRINTTAB(7);
01415 PRINT"<<  SET PAPER ON PRINTER TO THE TOP OF FORM  >>"
01420 PRINT
01421 PRINTTAB(7);
01422 PRINT"<<  PUSH THE TOP OF FORM SWITCH ON THE PRINTER  >>"
01423 PRINT
01425 PRINTTAB(7);
01430 PRINT"<<  TURN OFF THE AUTO-SKIP ON THE PRINTER  >>"
01431 PRINT
01432 PRINTTAB(7);
01433 PRINT"<<  SET THE PRINTER TO  ";
01434 IF A=1 THEN PRINT"8 LINES PER INCH  >>":GOTO 1440
01435 IF A=2 THEN PRINT"6 LINES PER INCH  >>":GOTO 1440
01440 PRINT
01445 PRINT TAB(7);
01450 PRINT"<<  SET THE PAPER LENGTH DIAL TO  ";
01455 IF A=1 THEN PRINT"8 1/2  INCHES  >>":GOTO 1500
01456 IF A=2 THEN PRINT"11  INCHES  >>":GOTO 1500
01458 PRINT"THE SIZE OF YOUR SPECIAL PAPER  >>"
01500 FOR X=1 TO 6:PRINT:NEXT
01510 INPUT"ENTER A  C  TO CONTINUE ";X$
01520 RETURN
04999 REM
05000 REM POKE OUTPUT TO ALLOW PRINTING OF BACKSPACE
05010 POKE 21340,8: REM BACSPC=8
05020 REM  POKE PATCH INTO INPUT ROUTINE
05030 POKE 1373,76:POKE 1374,0:POKE 1375,92
05040 REM POKE PATCH INTO $5C00
05050 FOR PTR=23552 TO 23571
05060 READ MAC: POKE PTR,MAC
05070 NEXT PTR:RETURN
05080 DATA 201,8,208,13,32,8,40,72
05090 DATA 169,32,32,8,40,104,76,76,5,76,97,5
09000 REM
09010 D=PEEK(55921)
09015 M=PEEK(55922)
09020 A=PEEK(55923)
09050 GOSUB 9900
09060 PRINT"     DAGS DATO: ";D;"/";M;"-";A
09070 PRINT:PRINT:PRINT:PRINT:PRINT:PRINT
09080 INPUT"     \NSKES DET [NDRET (J/N) ";R$
09090 IF R$<>"J" THEN RETURN
09100 PRINT:PRINT:PRINT
09110 INPUT"     INDTAST DEN NYE DATO (D,M,]) ";D,M,A
09111 IF D<0 OR D>31 THEN PRINT"** FORKERT DATO":GOTO 9110
09112 IF M<0 OR M>12 THEN PRINT"** FORKERT DATO":GOTO 9110
09113 IF A<0 OR A>99 THEN PRINT"** FORKERT DATO":GOTO 9110
09115 POKE 55921,D
09120 POKE 55922,M
09150 POKE 55923,A
09200 RETURN
09900 FOR I=1 TO 35 :PRINT:NEXT I
09999 RETURN