DataMuseum.dk

top - metrics - download

    Length: 4080 (0xff0)
    Notes: OS65UFile, OSU65U-BASIC
    Names: »KYEDIT«

└─⟦2f57871a3⟧ Bits:30009355 Ohio Scientific OS-OMS Nucleus, delvist oversat til dansk
    └─⟦this⟧ »KYEDIT« 

BASIC

00001 PRINT"** PROGRAM NOT EXECUTABLE FROM CONSOLE **":RUN"DBMSYS","PASS"
00002 CLOSE:CLEAR:REM 1/79  KEY FILE EDIT  (KYEDIT)
00010 FLAG9:REM DISC ERROR CHECK GOTO 50,000
00015 POKE 2888,0
00020 FLAG11:REM CLEARS SPACES
00025 EE$="/":NC$="":NE$="*"
00030 DV(2)=PEEK (9832):IF DV(2)>127 THEN DV(2)=DV(2)-128+4
00040 DV$(2)=CHR$(DV(2)+65)
00045 FOR I=1 TO 26:PRINT:NEXT I
00046 PRINT"DB-2 [NDRE I N\GLE FIL"
00047 PRINT"======================":PRINT:PRINT:PRINT
00050 INPUT"HVILKEN STATION LIGGER N\GLE FILEN P] ";DV$(1)
00060 IF DV$(1)>="A" AND DV$(1)<="E" GOTO 64
00061 PRINT"*** FORKERT STATION ***":GOTO 50
00064 IFLEN(DV$(1))>1ORLEN(DV$(1))=0 THENPRINT"*** FORKERT STATION":GOTO50
00065 DEV DV$(1)
00069 INPUT"INDTAST NAVNET P] N\GLE FILEN, KODEORD ";N$,PW$
00070 IF LEN(N$)<1 ORLEN(N$)>6 THENPRINT:PRINT"FORKERT !!":PRINT:GOTO 69  
00071 IF LEN(N$)<5 THEN FORX=0 TO (4-LEN(N$)):N$=N$+" ":NEXTX
00072 N$=LEFT$(N$,5)
00073 IF PW$="." THEN PW$="ANAN"
00075 IF LEN(PW$)<>4 GOTO 73
00076 INPUT"INDTAST N\GLE FIL NR. (1-7) ";U
00077 IF U<1 OR U>7 THENPRINT:PRINT"*** FORKERT !!!"PRINT:PRINT:GOTO 76
00080 U$=STR$(U):U$=RIGHT$(U$,1)
00090 N$=N$+U$
00120 OPEN N$,PW$,1
00130 INPUT %1,KN$:INDEX<1>=6
00140 INPUT %1,T:INDEX<1>=9
00150 INPUT %1,EODF:INDEX<1>=20
00155 INPUT %1,RL:INDEX<1>=31
00160 INPUT %1,BDF:INDEX<1>=42
00170 INPUT %1,KF$
00175 POKE 2976,13:POKE 2972,13
00180 CNT=INDEX(1)
00220 FOR I=1 TO 27:PRINT:NEXT
00221 PRINT"KONTROL KARAKTERER:"
00222 PRINT"   /      RETUR TIL SIDSTE SP\RGSM]L"
00223 PRINT:PRINT:PRINT:PRINT:PRINT
00224 INPUT"TAST RETURN, HVIS FORS[TTELSE ";Z$:FORI=1 TO 27:PRINT:NEXT
00225 O$="^":INPUT"SLET (S) ELLER TILF\J (T) ";QU$
00226 IFLEN(QU$)<>1THENPRINT"*** INDTAST S ELLER T ***":GOTO 225
00227 IF QU$=NC$ THEN CLOSE:GOTO 2
00228 IF QU$="T" GOTO 263
00230 IF QU$=EE$ GOTO 1000
00235 IF QU$<>"S" THENPRINT"*** INDTAST S ELLER T ***":GOTO 225
00240 INPUT"INDTAST N\GLE ";F$:F=VAL(F$)
00241 IF F$=NC$ THEN CLOSE :GOTO 2
00242 IF F$=EE$ GOTO 225
00243 INDEX<1>=CNT
00244 PRINT
00245 FIND O$+F$,1
00246 IFINDEX(1)>=1E9THENPRINT"N\GLE EJ FUNDET":GOTO240
00247 CTR=INDEX(1):INPUT %1,T$:T=VAL(T$)
00248 PTR=INDEX(1):INPUT %1,I$:I=VAL(I$)
00249 IF MID$(T$,2)<>F$ THEN GOTO 245
00250 GOTO 336
00255 PRINT
00260 REM
00263 PRINT
00265 INPUT"TILF\J VED HJ[LP AF RECORD NR. (R) ELLER INDEX NR. (I) ";Z$  
00268 IF Z$=EE$ GOTO 225
00269 IF Z$=NC$ THEN CLOSE:GOTO 2
00270 IF Z$="R" GOTO 330
00275 IF Z$<>"R"ANDZ$<>"I"THENPRINT"*** TAST R ELLER I ":GOTO 265
00280 PRINT:INPUT"INDEX NR. ";I$:I=VAL(I$)
00282 PRINT
00283 IF I$=EE$ GOTO 265
00284 IF I$=NC$ THEN CLOSE :GOTO 2
00285 GOTO 352
00329 PRINT
00330 INPUT"RECORD NR. ";RN$
00331 RN=VAL(RN$):IF RN$=EE$ GOTO 265
00332 PRINT:IF RN$=NC$ THEN CLOSE :GOTO 2
00333 REM
00334 IF RN<>INT(RN) OR RN<1 THENPRINT"*** FORKERT NR. ***": GOTO 330
00336 PRINT"NAVN                N\GLE                              INDEX"
00337 PRINT"******************************************************************
00340 PRINT KF$;TAB(20);F$;TAB(55);I$
00341 PRINT
00342 IF QU$="T" GOTO 350
00343 PRINT"                    TAST *, HVIS SLETNING"
00344 PRINT
00350 REM
00351 PRINT
00352 INPUT"INDTAST N\GLE ";ED$
00353 PRINT:ED=VAL(ED$)
00355 IF ED$=NC$ GOTO 500
00360 IF ED$=EE$ GOTO 225
00370 IF ED$=NE$ GOTO 400
00372 IF LEN(ED$)>72 THENPRINT"MAX FELT L[NGDE ER 72 KARAKTERER":GOTO 352
00374 IF QU$="T" GOTO 410
00400 INDEX<1>=CTR:A$="*"
00405 FORY=1 TO LEN(F$)+1:PRINT %1,A$;:NEXTY
00408 IF ED$=NE$ GOTO 500
00410 INDEX<1>=EODF:PRINT %1,O$+ED$
00420 IF Z$="I" GOTO 422
00421 I=((RN-1)*RL)+BDF:REM BDF=BODF OF MASTER FILE
00422 INDEX<1>=EODF+LEN(ED$)+2:PRINT %1,I
00424 EODF=EODF+LEN(ED$)+LEN(STR$(I))+2
00430 INDEX<1>=9:PRINT %1,EODF
00500 REM
00502 IF QU$="T" AND Z$="R" AND INDEX(1)<EODF THEN GOTO 330
00503 IF QU$="T" AND Z$="I" AND INDEX(1)<EODF THEN GOTO 280
00505 IF INDEX(1)<EODF THENPRINT"*** N[STE N\GLE":GOTO 260
01000 CLOSE:DEV DV$(2)
01020 FLAG12:POKE2888,27
01030 CLOSE
01035 POKE 2976,44:POKE 2972,58
01040 RUN"DBMSYS","PASS"
50000 XC=XC+1:IFXC<2GOTO50030
50010 IF CHK=1 THEN PRINT"END OF FILE":
50020 PRINT"*** KONTROLER AT DISKETTERNE ER PLACERET RIGTIGT ***"
50030 DE=PEEK(10226):DL=PEEK(1774)+PEEK(11775)*256:PRINT
50040 PRINT"*** FEJL ";DE;" I LINIE ";DL;" ***":PRINT
50050 INPUT"TAST RETURN, HVIS FORS[TTELSE ";QS$:PRINT
50060 GOTO1000