DataMuseum.dk

Presents historical artifacts from the history of:

Philips Data Systems

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about Philips Data Systems

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - metrics - download

⟦1c45d362d⟧ 

    Length: 2800 (0xaf0)
    Notes: pts_type(SC)
    Names: »COPY4.SC«

Derivation

└─⟦cd4bbebb4⟧ Bits:30009680 Philips computer tape "600221"
    └─⟦this⟧ »ATM/COPY4.SC« 
    └─⟦this⟧ »ATM6601/COPY4.SC« 
    └─⟦this⟧ »BEBATM/COPY4.SC«

PTS(SC)

	IDENT COPY4 	COPY HALF BYTES REL 1.1 
* 
* 
************************************************************************
* 
*          THIS ROUTINE IS TO COPY HALF-BYTES BETWEEN CREDIT
* 
*          DATA ITEMS.
* 
*          SUPPORTING CREDIT REL 3.2
* 
************************************************************************
* 
*          THE CALL TO THIS ROUTINE HAS THE FORMAT:-
* 
*          CALL    COPY4,<BUF1>,<PNTR1>,<SIZE>,<BUF2>,<PNTR2> 
* 
*          WHERE: 
* 
*               <BUF1>      IS THE DATA ITEM TO WHICH THE DATA IS TO BE 
* 
*               <PNTR1>     IS A BINARY DATA ITEM CONTAINING AN OFFSET F
*                           THE START OF THE ITEM, AT WHICH POINT THE CO
*                           DATA IS TO START. 
* 
*               <SIZE>      IS A BINARY DATA ITEM CONTAINING THE NUMBER 
*                           OF HALF-BYTES TO BE COPIED. 
* 
*               <BUF2>      IS A DATA ITEM CONTAINING THE DATA TO BE COP
* 
*               <PNTR2>     IS A BINARY DATA ITEM CONTAINING AN OFFSET
*                           FROM THE START OF THE ITEM, FROM WHICH POINT
*                           THE DATA IS TO BE COPIED. 
* 
*          THE CREDIT CONDITION REGISTER IS NOT AFFECTED. 
* 
************************************************************************
* 
* 
	EJECT
* 
	ENTRY	COPY4
* 
* 
	EXTRN	I:EVA0,I:RT1 
* 
* 
COPY4	EQU	* 
	CF	A14,I:EVA0
	LDR	A4,A9	START ADDRESS OF TARGET
	CF	A14,I:EVA0
	LDR*	A7,A9	POINTER 1 
	CF	A14,I:EVA0
	LDR*	A8,A9	LENGTH
	CF	A14,I:EVA0
	LDR	A6,A9	START ADDRESS OF SOURCE
	CF	A14,I:EVA0
	LDR*	A5,A9	POINTER 2 
* 
	LDR	A1,A7
	SRL	A1,1	DIVIDE BY 2 
	ADR	A4,A1
	LDR	A1,A5
	SRL	A1,1	DIVIDE BY 2 
	ADR	A6,A1
* 
	SRC	A7,1 
	SRC	A5,1 
	RF	ML090 
MAINLOOP	EQU	*
	LCR	A1,A6
	LDR	A5,A5
	RF(N)	ML020
	SRL	A1,4 
	RF	ML040 
ML020	EQU	* 
	ADK	A6,1 
ML040	EQU	* 
	ANK	A1,/F
	C1R	A5,A5
	LCR	A2,A4
	LDR	A7,A7
	RF(N)	ML060
	SLL	A1,4 
	ANK	A2,/F
	ORR	A2,A1
	SCR	A2,A4
	RF	ML080 
ML060	EQU	* 
	ANK	A2,/F0 
	ORR	A2,A1
	SCR	A2,A4
	ADK	A4,1 
ML080	EQU	* 
	C1R	A7,A7
ML090	EQU	* 
	SUKL	A8,1
	RB(NN)	MAINLOOP
* 
	ABL	I:RT1
* 
	END

Full view