DataMuseum.dk

Presents historical artifacts from the history of:

Philips Data Systems

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about Philips Data Systems

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - metrics - download

⟦2195a20f2⟧ 

    Length: 4664 (0x1238)
    Notes: pts_type(SC)
    Names: »DJUACT.SC«

Derivation

└─⟦35fda6e03⟧ Bits:30009701 Philips computer tape "BARCLAY"
    └─⟦this⟧ »DEMO6800/DJUACT.SC« 
    └─⟦this⟧ »DEMO6800/DJUACT.SC« 
└─⟦e276fd206⟧ Bits:30009696 Philips computer tape "600413"
    └─⟦this⟧ »DEMO6800/DJUACT.SC« 
└─⟦f350e1b7a⟧ Bits:30009678 Philips computer tape "600219"
    └─⟦this⟧ »PTSDEMO/DJUACT.SC«

PTS(SC)

         IDENT  DJUACT                    UPDATE ACCOUNT
	DDUM	DEMODD
	PDIV 
	EXPROC	PAJRN 
	EXPROC	QENTRS
	EXPROC	XBFMT 
	EXPROC	ZDRWRD
	EXPROC	ZHWRID
	ENTRY	DJUACT 
	ENTRY	SPAP30 
************************************************************************
* 
*   UPDATE ACCOUNT
* 
************************************************************************
DJUACT	PROC 
DJ000 
	SET	SBUACT 
	TBT	SBKEY2,DJ500 
	MOVE	TDTRSCDE,=D'88' 
	PERF	PAJRN,=W'1'	JOURNAL LINE 1
	PERF	PAJRN,=W'2'	JOURNAL LINE 2
	PERF	XBFMT,=W'52'	UPDATE ACCOUNT SCREEN 1
	TBT	SBCANCEL,DJ999 
	B	DJ520
DJ500 
	MOVE	TDTRSCDE,=D'89' 
	PERF	PAJRN,=W'1'	JOURNAL LINE 1
	PERF	PAJRN,=W'2'	JOURNAL LINE 2
	MOVE	TDNEWBAL,ADBAL	TO DISPLAY CURRENT BALANCE 
	PERF	XBFMT,=W'53'
	TBT	SBCANCEL,DJ999 
* 
* UPDATE LAST TRANSACTION SEQUENCE NUMBER 
* 
DJ520 
	ADD	YDLASSEQ,=D'1' 
	MOVE	ADLASSEQ,YDLASSEQ 
	MOVE	TDTRSSEQ,YDLASSEQ 
* 
* TO GET ZERO REPRESENTED AS  +0
* TDNEWBAL IS MULTIPLIED BY 1 
* 
	MUL	TDNEWBAL,=D'1' 
* 
* MAKE A TRANSACTION RECORD 
* IF KEY 2 IS ON AND THE BALANCE HAS BEEN CHANGED BY THE OPERATOR 
* 
	TBF	SBKEY2,DJ550	KEY 2 IS OFF
	CBNE	ADBAL,TDNEWBAL,DJ570	BALANCE CHANGED
* 
* KEY 1 ON OR BALANCE UNCHANGED,
* REWRITE ACCOUNT RECORD
* 
DJ550 
	PERF	ZDRWRD,ADACTRNR,NDLRN1
	B	DJ999
* 
*  BALANCE IS UPDATED, MAKE A TRANSACTION RECORD
* 
DJ570 
	PERF	QENTRS,ADLASTRS 
	MOVE	TDTRSRNR,ADACTRNR	COMPUTE TDTRSRNR
	ADD	TDTRSRNR,ADLASTRS
* 
*   ACTION ASSUMED TO BE A WITHDRAWAL OR A DEPOSIT ?
* 
	CBG	ADBAL,TDNEWBAL,DJ600	WITHDRAWAL
* 
*  DEPOSIT
* 
	MOVE	TDTRSCDE,=D'7'
* 
*  COMPUTE TDAMOUNT FOR INCREASED BALANCE 
* 
	MOVE	TDAMOUNT,TDNEWBAL 
	SUB	TDAMOUNT,ADBAL 
	ADD	ADDEPCUM,TDAMOUNT
	B	DJ800
DJ600 
* 
*  WITHDRAWAL 
* 
	MOVE	TDTRSCDE,=D'2'
* 
*  COMPUTE TDAMOUNT FOR REDUCED BALANCE 
* 
	MOVE	TDAMOUNT,ADBAL
	SUB	TDAMOUNT,TDNEWBAL
	ADD	ADWDRCUM,TDAMOUNT
* 
*  WRITE TRANSACTIONRECORD TO DATABASE
* 
DJ800 
	PERF	ZHWRID,TDTRSRNR,NDLRN2
	TBT	SBCANCEL,DJ999 
* 
*  REWRITE ACCOUNTRECORD
* 
	MOVE	ADBAL,TDNEWBAL
	PERF	ZDRWRD,ADACTRNR,NDLRN1
	TBT	SBCANCEL,DJ999 
* 
* 
*  UPDATE OPERATOR BALANCES 
* 
	CBE	TDTRSCDE,=D'2',DJ850	WITHDRAWAL TRANSACTION
* DEPOSIT 
	ADD	ODCASH(KW1,KW4),TDAMOUNT	BALANCE,CASH
	ADD	ODCASH(KW2,KW3),TDAMOUNT	ACCUMULATED DEPOSITS
	B	DJ999
* WITHDRAWAL
DJ850 
	SUB	ODCASH(KW1,KW4),TDAMOUNT	BALANCE CASH
	ADD	ODCASH(KW2,KW4),TDAMOUNT	ACCUMULTED WITHDRAWALS
DJ999 
	CLEAR	SBUACT 
	RET	 
	PEND 
********************************************************************
SPAP30	PROC	XWRET 
	PBIN	XWRET 
S30000
	CBE	ADBAL,TDNEWBAL,S30990
* 
*   SPACE AVAILABLE FOR TRANSACTIONRECORDS ?
* 

	MOVE	WDEC1,ADLASTRS
	PERF	QENTRS,WDEC1
	CBNE	ADSTMTRS,WDEC1,S30990	TRANSACTIONS POSSIBLE 
	MOVE	XWRET,=W'1' 
	MOVE	SPBINW4,=W'56'	'NO TRANSACTIONS POSSIBLE' 
	B	S30999 
S30990
	MOVE	XWRET,=W'0' 
S30999
	RET
	PEND 
******************************************************************* 
	END

Full view