DataMuseum.dk

Presents historical artifacts from the history of:

Philips Data Systems

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about Philips Data Systems

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - metrics - download

⟦355518da4⟧ 

    Length: 4712 (0x1268)
    Notes: pts_type(SC)
    Names: »TSWBLK.SC«

Derivation

└─⟦13e5fd45a⟧ Bits:30009699 Philips computer tape "600507"
    └─⟦this⟧ »TOSSWORK/TSWBLK.SC« 
└─⟦bc20f3abf⟧ Bits:30009670 Philips computer tape "600126"
    └─⟦this⟧ »TOSSWORK/TSWBLK.SC«

PTS(SC)

	IDENT TSWBLK 	REL 11.0 81-01-26 870105041100 

* 
* 
**************************************************
* 
*   PHILIPS TERMINAL SYSTEM  PTS
* 
*   TSWBLK = LOAD/STORE SWAPPABLE WORK BLOCK
* 
* 
* 
* 
**************************************************
* 
* 
*   THIS MODULE CONTAINS THE LOAD/STORE SWAPPABLE WORK BLOCK
*   LKM PROCESSOR, USED IN TOSS MEMORY MANAGEMENT SYSTEMS.
* 
* 
	EJECT			TSWBLK 
* 
* 
*********** 
* ENTRIES * 
*********** 
* 
* 
	ENTRY	TSWBLK	LOAD/STORE SWAPPABLE WORK BLOCK 



* 
* 
************* 
* EXTERNALS * 
************* 
* 
* 
	EXTRN	TDISP	DISPATCHER 
	EXTRN	LKMRQE	LKM REQUEST ERROR 
	EXTRN	ACBSWB	SWBTAB ADDRESS
	EXTRN	TTB:AP	ACB ADDRESS 
	EXTRN	QLTSWB	ACTIVATE LDTASK AT ENTRY LT:SWB 
	EJECT			TSWBLK 
* 
* 
**********
* TSWBLK *
**********
* 
* 
*   THIS IS THE LOAD/STORE SWAPPABLE WORK BLOCK LKM PROCESSOR.
* 
*   IT IS ENTERED FROM THE LKM HANDLER
*   WITH THE FOLLOWING PARAMETERS:
* 
*   A5 = TTAB ADDRESS 
*   A6 = LKM DATA DIRECTIVE: 19 IF LOAD SWB 
*      =                     20 IF STORE SWB
*   A7 = LEFT BYTE : SWB TYPE (NUMBER)
*      = RIGHT BYTE: INDEX WITHIN TYPE
*   A8 = MEMORY ADDRESS OF WHERE TO LOAD THE SWB (A6 = 19)
*       =  "       "    "  THE SWB TO STORE      (A6 = 20)
* 
*   TSWBLK WILL ACTIVATE LDTASK (THE LOAD TASK) AT LABEL LT:SWB 
*   AND LDTASK WILL LOAD/STORE REQUESTED WORK BLOCK.
* 
*   IT RETURNS TO CALLING TASK WITH 
*   THE FOLLOWING PARAMETERS: 
* 
*   A7 = UNCHANGED IF LOADING/STORING IS SUCCESSFUL, ELSE 
*   A7 = -1 IF REQUEST ERROR, ELSE
*   A7 = -2 IF DISC I/O ERROR, ELSE 
*   A7 = -3 IF DISC NOT OPERABLE
* 
	EJECT			TSWBLK 
* 
*	CHECK VALIDITY OF SWPBLK PARAMETERS 
* 
TSWBLK	EQU	*	SWB HANDLING ENTRY 
	LD	A1,TTB:AP,A5	ACB ADDRESS
	LD	A1,ACBSWB,A1	GET SWBTAB ADDRESS 
	RF(NZ)	TSW:10	SWBTAB PRESENT 
* 
SWBERR	EQU	*	COMMON REQUEST ERROR EXIT
	ABL	LKMRQE	LKM REQUEST ERROR 
* 
TSW:10	EQU	*
	ECR	A4,A7
	ANK	A4,/FF	GET TYPE NUMBER 
	CWR*	A4,A1	CHECK IF LEGAL
	RB(G)	SWBERR	SWB TYPE NUMBER TOO BIG 
	ADR	A4,A4
	ADR	A1,A4	GET ADDRESS TO SWB TYPE POINTER
	LDR*	A1,A1	GET ADDRESS TO SWB TYPE 
	CCR	A7,A1	CHECK IF LEGAL 
	RB(G)	SWBERR	SWB COPY NUMBER TOO BIG 
* 
*	ACTIVATE LOAD TASK
* 
	LDR	A3,A5	GET TTAB ADDRESS OF CALLING TASK 
	LDR	A4,A6	LKM DATA DIRECTIVE 
	CF	A15,QLTSWB	ACTIVATE LDTASK AT ENTRY LT:SWB
	ABL	TDISP	GO TO DISPATCHER 
* 
* 
* 
	END

Full view