DataMuseum.dk

Presents historical artifacts from the history of:

Philips Data Systems

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about Philips Data Systems

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - metrics - download

⟦5f0af97e5⟧ 

    Length: 7868 (0x1ebc)
    Notes: pts_type(SC)
    Names: »DGCACT.SC«

Derivation

└─⟦f350e1b7a⟧ Bits:30009678 Philips computer tape "600219"
    └─⟦this⟧ »PTSDEMO/DGCACT.SC«

PTS(SC)

         IDENT     DGCACT              CLOSE ACCOUNT
*********************************************************************** 
*        PROCEDURE NAME :                                              *
*                  DGCACT      CLOSE ACCOUNT                           *
*        FUNCTIONAL DESCRIPTION :                                     * 
*                  - PRINT JOURNAL-ROLL                               * 
*                  - DISPLAY FORMAT 40 ON SCREEN                      * 
*                  - UPDATE ACCOUNTRECORD                             * 
*                  - SAVINGS ACCOUNT: PRINT BOOK IF TERMINAL PRINTER  * 
*                                     IS PRESENT                      * 
*                                     RECORDSTATUS BECOMES 2          * 
*                  - CHEQUE ACCOUNT : IF LAST-TRANSACTION = LAST-TRANS* 
*                                     ACTION-STATEMENTED: RECORDSTATUS* 
*                                     BECOMES 3 , ELSE RECORDSTATUS   * 
*                                     BECOMES 2 AND PRINT BOOK IS PER * 
*                                     FORMED IF TERMINALPRINTER IS    * 
*                                     PRESENT                         * 
*                  - REWRITE ACCOUNTRECORD                            * 
*        PROCEDURES USED :                                             *
*                  PAJRN       WRITE JOURNAL                           *
*                  PBBOOK      PRINT BOOK                              *
*                  ZZDRWRD     WRITE DATABASE-RECORD                  * 
*                  XBFMT      SCREEN-CONTROL                          * 
*********************************************************************** 
         DDUM      DEMODD 
         PDIV 
         ENTRY     DGCACT 
	EXPROC	DKDSTM
         EXT       PAJRN
         EXT       PBBOOK 
	EXPROC	XBFMT 
	EXPROC	ZCRDD 
	EXPROC	ZDRWRD

DGCACT   PROC 
DG000 
*        PRINT JOURNAL-ROLL 
         SET       SBCACT 
         PERF      PAJRN,=W'1'
         MOVE      TDTRSCDE,=D'081' 
         PERF      PAJRN,=W'2'
DG100 
*        DISPLAY FORMAT ON SCREEN 
         PERF      XBFMT,=W'40' 
         TBT       SBCANCEL,DG999 
*        UPDATE ACCOUNT- AND TRANSACTION-RECORD 
         ADD       YDLASSEQ,=D'1' 
         MOVE      ADLASSEQ,YDLASSEQ
         MOVE      TDTRSSEQ,ADLASSEQ
	CLEAR	SBCACT	CLEAR IDENTIFICATION SWITCH		
* *
* SET ACCOUNT STATUS*
* *
	MOVE	ADSTATUS,=D'2'	CLOSED W/O STATEMENTING		
	TBF	SBCHQACT,DG600			
* CHEQUE ACCOUNT*
	CBNE	ADLASTRS,ADSTMTRS,DG600	TRANS. TO BE STATEMENTED		
	MOVE	ADSTATUS,=D'3'	CLOSED WITH STATEMENTING		
**
* REWRITE THE ACCOUNT RECORD*
* *
DG600					
	PERF	ZDRWRD,ADACTRNR,NDLRN1			
	TBT	SBCANCEL,DG999			
* *
* PRINT UNSTATEMENTED TRANSACTIONS*
* *
	CBE	ADSTATUS,=D'3',DG999	NO STATEMENTING NECESSARY		
	CBE	RDPRTTYP,=D'3',DG650 
	CBG	RDPRTTYP,=D'1',DG999	NO TTP/TEP		
* *
* READ THE ACCOUNT RECORD FOR PBBOOK OR DKDSTM*
* *
DG650 
	PERF	ZCRDD,ADACTRNR,NDLRN1,KW1			
	TBT	SBCANCEL,DG999			
	TBT	SBCHQACT,DG700			
* SAVINGS ACCOUNT, PRINT BOOK*
	PERF	PBBOOK			
	B	DG999			
* CHEQUE ACCOUNT, PRINT DAILY-STATEMENTS*
DG700					
	PERF	DKDSTM			
DG999					
         RET
         PEND 
         END

Full view