DataMuseum.dk

top - metrics - download

    Length: 4772 (0x12a4)
    Notes: pts_type(SC)
    Names: »DRCP01.SC«

└─⟦efe3a1cfc⟧ Bits:30009667 Philips computer tape "600113"
    └─⟦this⟧ »TOSSWORK/DRCP01.SC« 

PTS(SC)

	IDENT DRCP01 	REL 8.2 78-09-15  870105040820 

* 
**********************************************: 
* 
*   PHILIPS TERMINAL SYSTEM PTS 
* 
*   DRCP01 = DRIVER COT PRINTER 
* 
* 
* 
* 
* 
* 
*********************************************** 
* 
*    THIS DRIVER HANDLES OUTPUT TO COT PRINTER. 
* 
*    THE COT MUST BE CONNECTED TO CPU VIA CHLT OR CHRT. 
* 
* 
*    THE DRIVER CONSISTS OF THE FOLLOWING PARTS:
* 
*    A C C P :    ACTIVATION PART 
*    I H C P :    INTERRUPT HANDLER 
* 
*    R C C P :     RECOVERY ROUTINE 
* 
* 
*    THE FOLLOWING ORDERS ARE TREATED:
* 
*    ORDER 06:   WRITE
*    ORDER 22: CUT RECEIPT
	EJECT
* 
* 
*    NORMAL REGISTER USAGE: 
* 
*    REGISTER A1: RETURN CODE 
*             A2: OUTPUT CHARACTER
*             A3: WORK REGISTER 
*             A4: WORK REGISTER 
*             A5: WORK REGISTER 
*             A6: DWT-ADDRESS 
*             A7: ORDER 
*             A8: ECB-ADDRESS 
* 
	EJECT
* 
* 
*********************** 
*    ENTRIES          * 
*********************** 
* 
	ENTRY	CPAD 
* 
************************************* 
*    EXTERNALS                    * 
************************************* 
	EXTRN	SAVE8	SAVE REGS
	EXTRN	TENDIO	END I/O 
	EXTRN	DISEND	PERFORM END I/O AND DISPATCH
	EXTRN	TDISP	DISPATCHER ENTRY 
	EXTRN	OUTPUT	OUTPUT CHAR.
	EXTRN	LDREG	LOAD REGISTERS AND RETURN
	EXTRN	STREG	STORE REGISTERS AND DISPATCH 
	EXTRN	GETCHR	GET CHARACTER 
	EXTRN	DISIOE	I/O REQUEST ERROR 
	EXTRN	DWTST	STATUS 
	EXTRN	DWTOR	ORDER
	EXTRN	ECHRTN	RETURN FROM ECHO ROUTINE
	EJECT
* 
* 
******************************* 
*    CONSTANTS                * 
******************************* 
* 
DWTBC	EQU	/3
* 
************************* 
*      TABLES           * 
************************* 
* 
CPAD	EQU	*
	DATA	ACCP	ACTIVATION DRIVER
	DATA	IHCP	INTERRUPT HANDLER
	DATA	RCCP	RECOVERY ROUTINE 
* 
* 
* 
	EJECT
* 
* 
******************************************* 
*    CONDITIONAL ASSEMBLY               * 
******************************************* 
* 
* 
* 
* 
********************************************
*    DWT-DISPLACEMENTS                     *
********************************************
* 
	EJECT
* 
*    A C C P
* 
*    ACTIVATION PART: CHECH VALIDITY OF ORDERS
*                     AND STARTS THE PROCESSING 
* 
ACCP	EQU	*
	LDKL	A4,/4000
	ORRS	A4,A6 
	LC	A3,DWTOR,A6 
	ANK	A3,1	JOURNAL PRINTER?
	RF(NE)	ACP05	YES 
	XRRS	A4,A6	NO, SET DEV. ADR. TO RECEIPT PRINTER
ACP05	EQU	* 
	SUK	A7,/22	CUT ? 
	RF(E)	ACCP30 
	ADK	A7,/1C	WRITE ? 
	ABL(NE)	DISIOE	REQUEST ERROR 
	LDK	A3,0	START BUFFER INDEX
	LDK	A4,0 
ACCP10	EQU	*
	CF	A15,GETCHR	GET ONE CHARACTER
	LDR	A1,A1	LAST CHARACTER 
	RF(E)	ACCP20	YES 
	CF	A5,OUTPUT 
	RB	ACCP10
ACCP20	EQU	*
	LDK	A2,/03 
ACCP25	CF	A5,OUTPUT 
ACCP27	CF	A5,STREG
	ANK	A2,/7F 
	SUK	A2,2 
	RF(Z)	ACCP65	END OF PAPER
	SUK	A7,6 
	RF(NE)	ACCP70
	SUK	A2,2 
	RF(NZ)	ENDIO	
	LDK	A2,/20 
	ORS	A2,8,A8
	RB	ACCP27
ACCP30	LDK	A2,/60 
	LDK	A3,0 
ACCP35	CF	A5,OUTPUT 
	LDR	A3,A3
	RF(NE)	ACCP50
	LDK	A2,/20 
	ADK	A3,1 
	RB	ACCP35
ACCP50	LDK	A2,/13 
	ST	A3,6,A8 
	RB	ACCP25
ACCP65	LDKL	A1,/4000	RECEIPT STUCK
	RF	ENDIO 
ACCP70	SUK	A2,4 
	RB(E)	ACCP27 
ENDIO	ABL	DISEND
	EJECT
* 
*   I H C P 
* 
*    INTERRUPT HANDLER: PROCESS OF INTERRUPT
* 
IHCP	EQU	*
	LD	A4,DWTST,A6	STATUS
	RF(N)	EXIT 
	LDR	A1,A1	RETURN CODE
	RB(NE)	ENDIO	YES END I/O 
	ABL	LDREG
EXIT	ABL	TDISP
	EJECT
* 
*    R C C P
* 
* 
RCCP	EQU	*
	CF	A15,SAVE8 
	LD	A7,DWTST,A6 
	RB(N)	EXIT 
	LDK	A1,2 
	RB	ENDIO 
* 
* 
	END