DataMuseum.dk

Presents historical artifacts from the history of:

Philips Data Systems

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about Philips Data Systems

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - metrics - download

⟦83932b2b2⟧ 

    Length: 17360 (0x43d0)
    Notes: pts_type(SC)
    Names: »DDTP71.SC«

Derivation

└─⟦35fda6e03⟧ Bits:30009701 Philips computer tape "BARCLAY"
    └─⟦this⟧ »DEMO6800/DDTP71.SC« 
└─⟦e276fd206⟧ Bits:30009696 Philips computer tape "600413"
    └─⟦this⟧ »DEMO6800/DDTP71.SC« 
└─⟦f350e1b7a⟧ Bits:30009678 Philips computer tape "600219"
    └─⟦this⟧ »PTSDEMO/DDTP71.SC«

PTS(SC)

	IDENT	DDTP71	DEMONSTRATE 6371-PRINTER
	DDUM	DEMODD			
	PDIV				
	EXPROC	PVATTP			 
	EXPROC	PWDETP			 
	EXPROC	XCLAMP			 
	EXPROC	XEERR			 
	EXPROC	ZMRDF			 
	EXPROC	DEFDOC			 
	EXPROC	FMOVE 
	ENTRY	DDTP71			
************************************************************************
* *
* DEMONSTRATE THE 6371-PRINTER*
* *
************************************************************************
DDTP71	PROC				
DD000					
	PERF	PVATTP,DSVCHPRT	ATTACH PRINTER		 
* *
* DISPLAY MESSAGE TO MOUNT A4-SHEET IN PRINTER*
* *
	PERF	XCLAMP,KW4,KW1	LAMP 4 ON		
	PERF	XEERR,=W'64',KW3			
	PERF	XCLAMP,KW4,KW0	LAMP 4 OFF		
	TBT	SBCANCEL,DD999			
* *
* DEFINE THE DOCUMENT*
* *
	MOVE	WW1,=W'18'
	MOVE	VCDOCPAR,=C'1012561475710058000000'	SET PARAMETERS
	DSC2	DSVCHPRT,X'11',KW0,VCDOCPAR,WW1 
	DSC1	DSVCHPRT,X'00',KW0
	MOVE	WW1,=X'8066'
	DSC1	DSVCHPRT,X'0D',WW1
**
* WRITE TITLE LINES*
**
	MOVE	WW1,=W'65'	FORMAT NUMBER
	PERF 	ZMRDF,WW1,KW0	READ INTO FCFORMAT		 
	MOVE	ICSTRG1,=X'19'	START WITH DOUBLE COLUMN		
	PERF	PTITLE,=W'10',=D'7',=D'1'			
	PERF	PTITLE,=W'13',=D'10',=D'2'			 
	PERF	PTITLE,=W'15',=D'12',=D'4'			 
	MOVE	ICSTRG1,=C' '	STOP DOUBLE COLUMN 		
	PERF	PTITLE,=W'10',=D'17',=D'3'			 
	PERF	PTITLE,=W'13',=D'18',=D'5'			 
	PERF	PTITLE,=W'14',=D'19',=D'6'			 
* *
* PRINT AVAILABLE CHARACTER SET*
* *
	PERF	PUPOSA,=D'26'			
	MOVE	WW1,=W'66'	FORMAT NUMBER
	PERF	ZMRDF,WW1,KW0	READ INTO FCFORMAT		 
	PERF	PSWFMT,=W'10'			
	PERF	PUPOSA,=D'28'			
	CALL	FMOVE,FCFORMAT,FMTCSET			
	PERF	PSWFMT,=W'19'			
* *
* PRINT NATIONAL CHARACTER SETS*
* *
	PERF	PUPOSA,=D'30'			
	CALL	FMOVE,FCFORMAT,FMTNCV			
	MOVE	ICTEXT2,=C'D,A,L,CH'			
	PERF	PSWFMT,=W'11'			
	MOVE	ICTEXT2,=C'GB,NL,B '			
	PERF	PSWFMT,=W'1'			
	MOVE	ICTEXT2,=C'F,CH,B,L'			
	PERF	PSWFMT,=W'2'			
	MOVE	ICTEXT2,=C'E       '			
	PERF	PSWFMT,=W'3'			
	MOVE	ICTEXT2,=C'I,CH    '			
	PERF	PSWFMT,=W'4'			
	MOVE	ICTEXT2,=C'S,SF    '			
	PERF	PSWFMT,=W'5'			
	MOVE	ICTEXT2,=C'DK,N    '			
	PERF	PSWFMT,=W'6'			
	MOVE	ICTEXT2,=C'P       '			
	PERF	PSWFMT,=W'7'			
	MOVE	ICTEXT2,=C'US      '			
	PERF	PSWFMT,=W'8'			
	MOVE	ICTEXT2,=C'YU      '			
	PERF	PSWFMT,=W'9'			
	MOVE	ICTEXT2,=C'DK,N (2)'
	PERF	PSWFMT,=W'21' 
*  *
* PRINT SPECIAL CHARACTERS*
* *
	MOVE	WW1,=W'67'	FORMAT NUMBER
	PERF	ZMRDF,WW1,KW0	READ INTO FCFORMAT		
	PERF	PSWFMT,=W'10'			
* *
* WRITE TITLE LINES AGAIN*
* *
	MOVE	WW1,=W'65'	FORMAT NUMBER
	PERF	ZMRDF,WW1,KW0	READ INTO FCFORMAT		
	PERF	PTITLE,=W'16',=D'44',=D'6'			
	PERF	PTITLE,=W'17',=D'45',=D'5'			
	PERF	PTITLE,=W'19',=D'46',=D'3'			
	MOVE	ICSTRG1,=X'19'	START DOUBLE COLUMN AGAIN		
	PERF	PTITLE,=W'20',=D'50',=D'4'			
	PERF	PTITLE,=W'18',=D'53',=D'2'			
* *
* RELEASE A4-SHEET AND DETACH PRINTER*
* *
	DSC0	DSVCHPRT,01	RELEASE DOCUMENT		 
	PERF	PWDETP,DSVCHPRT	DETACH PRINTER		 
DD999					
	RET				
	PEND				
************************************************************************
* *
*   PROCEDURE:   PTITLE*
*   PARAMETERS:*
*      PWPRT:  INDEX IN THE PRINTER PARAMETERS-ARRAY*
*      PDPOS:  LINE NUMBER WHERE THE LINE MUST BE PRINTED*
*      PDFILL: LENGTH OF THE FILLER PRECEDING THE TEXT *
*   FUNCTIONAL DESCRIPTION:*
*      THE FORMAT CONTAINED IN FCFORMAT IS PRINTED IN THE LINE GIVEN*
*      BY PDPOS USING THE PRINTER PARAMETERS POINTED TO BY PWPRT AND*
*      AND PRECEDED BY THE NUMBER OF SPACES GIVEN BY PDFILL.*
* *
************************************************************************
PTITLE	PROC	PWPRT,PDPOS,PDFILL
	PLIT	PWPRT 
	PLIT	PDPOS 
	PLIT	PDFILL
PT000					
* *
* GET THE PRINTER PARAMETERS*
* *
	MOVE	WW2,PWPRT 
	MOVE	WW1,KCPRTPAR(WW2) 
	DSC1	DSVCHPRT,5,WW1	SEND PRINTER PARAMTERS		 
* *
* POSITION DOCUMENT*
* *
	PERF	PUPOSA,PDPOS			
* *
* WRITE THE LINE*
* *
	MOVE	WW1,PDFILL			
	IB	WW1,PT001,PT002,PT003,PT004,PT005,PT006 
PT001 
	SET	SBFIL1 
PT002 
	SET	SBFIL2 
PT003 
	SET	SBFIL3 
PT004 
	SET	SBFIL4 
PT005 
	SET	SBFIL5 
PT006 
	EDWRT	DSVCHPRT,FCFORMAT			 
	CLEAR	SBFIL1 
	CLEAR	SBFIL2 
	CLEAR	SBFIL3 
	CLEAR	SBFIL4 
	CLEAR	SBFIL5 
PT999					
	RET				
	PEND				
************************************************************************
* *
*   PROCEDURE:    PSWFMT*
*   FUNCTIONAL DESCRIPTION:*
*      WRITE THE FORMAT CONTAINED IN FCFORMAT USING THE PRINTER-*
*      PARAMETERS POINTED TO BY PWPRT.*
* *
************************************************************************
PSWFMT	PROC	PWPRT			
	PLIT	PWPRT 
PS000					
	MOVE	WW2,PWPRT 
	MOVE	WW1,KCPRTPAR(WW2) 
	DSC1	DSVCHPRT,5,WW1	SEND PRINTER PARAMETERS		 
	EDWRT	DSVCHPRT,FCFORMAT			 
PS999					
	RET				
	PEND				
************************************************************************
* *
*   PROCEDURE:   PUPOSA*
*   FUNCTIONAL DESCRIPTION:*
*      POSITION A4-SHEET ON THE LINE NUMBER GIVEN BY PDLINE*
* *
************************************************************************
PUPOSA	PROC	PDLINE			
	PLIT	PDLINE
PU000					
	MOVE	WDEC1,PDLINE
	DSC1	DSVCHPRT,6,WDEC1
PU999					
	RET				
	PEND				
************************************************************************
************************************************************************
* *
* DEMO TP71: AVAILABLE CHARACTER SET*
* *
************************************************************************
FMTCSET	FRMT				
	FTEXT	'  '			
	FILLR  	' ',15			
	FTEXT	=X'202122232425262728292A2B2C2D2E2F'			
	FTEXT	=X'303132333435363738393A3B3C3D3E3F'			
	FTEXT	=X'404142434445464748494A4B4C4D4E4F'			
	FEOR				
	FTEXT	'  '			
	FILLR  	' ',15			
	FTEXT	=X'505152535455565758595A5B5C5D5E5F'			
	FTEXT	=X'606162636465666768696A6B6C6D6E6F'			
	FTEXT	=X'707172737475767778797A7B7C7D7E7F'			
	FMEND				
************************************************************************
* *
* DEMO TP71: NATIONAL CHARACTER VERSION*
* *
************************************************************************
FMTNCV	FRMT				
	FTEXT	'  '			
	FILLR	' ',6			
	FCOPY	ICTEXT2			
	FTAB	17			
	FTEXT 	': '			
	FTEXT	=X'23405B5C5D607B7C7D7E'			
	FMEND				
************************************************************************
	END

Full view