DataMuseum.dk

Presents historical artifacts from the history of:

Philips Data Systems

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about Philips Data Systems

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - metrics - download

⟦a207233f5⟧ 

    Length: 17422 (0x440e)
    Notes: pts_type(SC)
    Names: »BESELF.SC«

Derivation

└─⟦35fda6e03⟧ Bits:30009701 Philips computer tape "BARCLAY"
    └─⟦this⟧ »DEMO6800/BESELF.SC« 
└─⟦e276fd206⟧ Bits:30009696 Philips computer tape "600413"
    └─⟦this⟧ »DEMO6800/BESELF.SC«

PTS(SC)

         IDENT    BESELF                SELECT FUNCTION 
	DDUM	DEMODD			
	PDIV 
	EXPROC	XAKBIN
	EXPROC	XDMSG 
	EXPROC	XEERR 
	EXPROC	CDCHKY
	EXPROC	CEGACT
	EXPROC	CFCHKH
         EXPROC   DAUCCY
	EXPROC	DQCOPR			 
	EXPROC	DOQCCY			 
	EXPROC	DPECCY			 
	EXPROC	DCVDU			 
	EXPROC	DDTP71			 
	EXPROC	DELACT			 
	EXPROC	DFOACT			 
	EXPROC	DGCACT			 
	EXPROC	DHBACT			 
	EXPROC	DJUACT			 
	EXPROC	DIQACT			 
	EXPROC	DKDSTM			 
	EXPROC	DLDEP			 
	EXPROC	DMWDR			 
	EXPROC	DNTRF			 
	EXPROC	EZIBUF
	EXPROC	ECICCY
	EXPROC	PAJRN 
	EXPROC	ZCRDD 
	EXPROC	ZGREA 
	ENTRY	BESELF 
* 
* 
* 
BESELF	PROC				
BE000					
* 
* INITIALISE ALL BUFFERS
* 
	PERF	EZIBUF
	PERF	ZGREA	RELEASE EXCL. ACCES 
**
* RESET ALL SWITCHES*
**
	CLEAR	SBOPRCLS	OPERATOR CLOSE SWITCH 
	CLEAR	SBCANCEL 
	CLEAR	SBCHEQUE			
	MOVE	SWCCY,=W'0'	CURRENCY SWITCH		
	CLEAR	SBNOBOOK			
	CLEAR	SBRVS  	REVERSAL SWITCH		
	CLEAR	SBCARD			
	CLEAR	SBFLDEMP 
	MOVE	FCFIELD,=C' '	CLEAR INPUT FIELD 
**
* ACCEPT A FUNCTION KEY*
**
BE004 
	PERF	XDMSG,=W'30'	ENTER FUNCTION 
BE006 
	PERF	XAKBIN,=W'10' 
	MOVE	NWKTBIX,SPBINW2	SAVE FUNCTION KEY INDEX		 
	CBE	NWKTBIX,KWCANCEL,BE000	CANCEL KEY PRESSED
* KEYLOCK TURN, POWER OFF OR UNDEFINED KEY
	CBNG	NWKTBIX,=W'0',BE006	KEYLOCK TURN OR POWER OFF 
	CBL	NWKTBIX,=W'12',BE100	  NON PREFIX KEY		
**
* PREFIX KEY, SET CORRESPONDING SWITCHES*
* HOWEVER, THE INPUT FIELD MUST BE EMPTY
**
	CBE	SPBINW1,=W'0',BE008	INPUT FIELD IS EMPTY 
	PERF	XEERR,=W'10',KW1	'UNSERVICEABLE REQUEST'
	B	BE000	RESTART INPUT
BE008 
	SUB	SPBINW2,=W'11'	ADJUST INDEX		
	IB	SPBINW2,BE010,BE010,BE010,	  CURRENCY 1,2 OR 3	C
		BE020,BE030,BE040,BE050			
	B	BE006
BE010					
* 
* CURRENCY KEY 1,2 OR 3*
* 
	MOVE	SWCCY,SPBINW2	CURRENCY NUMBER		
	B	BE006	ACCEPT NEXT FUNCTION KEY		
BE020					
	SET	SBCHEQUE			
	B	BE006	ACCEPT NEXT FUNCTION KEY		
BE030					
	SET	SBNOBOOK			
	B	BE006	ACCEPT NEXT FUNCTION KEY		
BE040					
	SET  	SBRVS	REVERSAL		
	B	BE006	ACCEPT NEXT FUNCTION KEY		
BE050 
	SET	SBCARD			
	B	BE006	ACCEPT NEXT FUNCTION KEY		
**
* NON PREFIX KEY PRESSED*
**
BE100					
	COPY	FCFIELD,KW0,SPBINW1,SPINPUT,KW0	COPY NON EOI CHARACTERS 
	CBG	SPBINW1,=W'0',BE110	FIELD NOT EMPTY
	SET	SBFLDEMP	INDICATE FIELD EMPTY		
************************************************************************
* 
* CHECK FUNCTION-KEY COMBINATIONS 
* 
************************************************************************
BE110 
	PERF	CDCHKY
	TBT	SBCANCEL,BE990	ERROR DETECTED
************************************************************************
**
* CHECK HARDWARE AVAILABILITY AND KEYHOLE SETTING 
**
************************************************************************
	PERF	CFCHKH
	TBT	SBCANCEL,BE990 
************************************************************************
**
* GET ADDITIONAL INPUT*
**
************************************************************************
BE500					
	CBE	NWKTBIX,=W'1',BE600	'EOI'		
	CBE	NWKTBIX,=W'2',BE600	'LIST'		
	CBE	NWKTBIX,=W'3',BE600	'OPEN'		
	CBE	SWCCY,=W'0',BE550			
**
* CURRENCY IS ON*
**
	TBT	SBFLDEMP,BE520			
**
* CURRENCY IS ON AND THE FIELD IS NOT EMPTY*
*    INITIALISE A CURRENCY RECORD IN THE UWB*
**
	PERF	ECICCY	INITIALISE UWB		
	MOVE	CCCCYCDE,FCFIELD	INIT CURRENCY CODE		
	B	BE600	SELECT FUNCTION		
**
* CURRENCY IS ON AND FIELD IS EMPTY*
*    READ CURRENCY RECORD*
**
BE520					
	MOVE	CDCCYRNR,SWCCY	CURRENCY NUMBER		
	ADD	CDCCYRNR,=D'10'			
	MUL	CDCCYRNR,KDSHIFT	SHIFT TO GET RECORD NUMBER		
	PERF	ZCRDD,CDCCYRNR,NDLRN1,KW1 
	TBT	SBCANCEL,BE990 
	B	BE600	SELECT FUNCTION		
**
* CURRENCY IS OFF*
*    GET OPERATOR INPUT*
**
BE550					
	PERF	CEGACT	GET ACCOUNT NUMBER		
	TBT 	SBCANCEL,BE990	ERROR DETECTED OR CANCEL 		
* *
*  AT THIS POINT, WHEN THE FUNCTION SELECTED IS NOT 'CARD TRANSFER',*
*  'OPERATOR CLOSE' OR 'D-S (ALL ACCOUNT OPTION)' 
*  - THE REQUIRED ACCOUNT RECORD HAS BEEN READ INTO UWB UA1,*
*  - THE VARIABLE 'IDACTNR1' CONTAINS THE UNSHIFTED ACCOUNT NUMBER,*
*  - THE VARIABLE 'NDLRN1' CONTAINS THE LOGICAL RECORD NUMBER OF THE*
*    ACCOUNT RECORD,*
*  - THE BOOLEAN 'SBCHQACT' INDICATES WHETHER THE ACCOUNT*
*    READ IN IS A CHEQUE ACCOUNT OR NOT.*
* *
************************************************************************
**
* SELECT FUNCTION*
**
************************************************************************
BE600					
	TBF	SBOPRCLS,BE610			
	PERF	DQCOPR	OPERATOR CLOSE 
	B	BE900			
**
* CURRENCY SWITCH ?*
**
BE610					
	CBE	SWCCY,=W'0',BE700			
**
* CURRENCY IS ON*
**
	CBNE	NWKTBIX,=W'6',BE620	NOT 'UPDATE'		
	PERF	DAUCCY	CURRENCY UPDATE
	B	BE900			
BE620					
	CBNE	NWKTBIX,=W'7',BE630	NOT 'INQUIRY'		
	PERF	DOQCCY	CURRENCY INQUIRY 
	B	BE900			
BE630					
	CBE	NWKTBIX,=W'9',BE640	'IN' 
	CBNE	NWKTBIX,=W'10',BE700	NOT 'OUT'		
BE640 
	PERF	DPECCY	CURRENCY EXCHANGE
	B	BE900			
**
* BRANCH TO SEVERAL FUNCTIONS*
**
BE700					
	IB	NWKTBIX,BE710,BE720,BE730,BE740,BE750,		C 
		BE760,BE770,BE780,BE790,BE800,		C 
		BE810 
BE710	 				
	CBE	FCFIELD,=C'6371',BE712			
	PERF	DCVDU	DEMONSTRATE VIDEO 
	B	BE900			
BE712					
	PERF	DDTP71	DEMONSTRATE TP71		
	B	BE900			
BE720					
	PERF	DELACT	LIST ACCOUNT		
	B	BE900			
BE730					
	PERF	DFOACT	OPEN ACCOUNT		
	B	BE900			
BE740					
	PERF	DGCACT	CLOSE ACCOUNT		
	B	BE900			
BE750					
	PERF	DHBACT	BLOCK/DEBLOCK ACCOUNT		
	B	BE900			
BE760					
	PERF	DJUACT	UPDATE ACCOUNT		
	B	BE900			
BE770					
	PERF	DIQACT	INQUIRY ACCOUNT		
	B	BE900			
BE780					
	PERF	DKDSTM	DAILY STATEMENT		
	B	BE900			
BE790					
	PERF	DLDEP	DEPOSIT		
	B	BE900			
BE800					
	PERF	DMWDR	WITHDRAWAL		
	B	BE900			
BE810					
	PERF	DNTRF	TRANSFER		
**
* NORMAL EXIT FROM FUNCTION MODULE*
**
BE900					
	CBE	NWKTBIX,=W'1',BE910	NOT FOR DEMO-FUNCTIONS 
* 
* PRINT LINE TYPE 3: CLOSING OF FUNCTION
* 
	PERF	PAJRN,=W'3' 
* 
* CHECK STATUS
* 
BE910 
	CBE	YDSTATUS,=D'3',BE999	SYSTEM HAS BEEN CLOSED
	CBNE	ODSTATUS,=D'2',BE999	OPERATOR CLOSE HAS SUCCEEDED		
**
* RE-EXECUTE FUNCTION CHOISE
**
BE990					
	B	BE000			
**
* RETURN TO CALLING MODULE*
**
BE999					
	RET				
	PEND				
* 
* 
	END

Full view