DataMuseum.dk

Presents historical artifacts from the history of:

Philips Data Systems

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about Philips Data Systems

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - metrics - download

⟦d71af9946⟧ 

    Length: 11084 (0x2b4c)
    Notes: pts_type(SC)
    Names: »BCSTTO.SC«

Derivation

└─⟦35fda6e03⟧ Bits:30009701 Philips computer tape "BARCLAY"
    └─⟦this⟧ »DEMO6800/BCSTTO.SC« 
└─⟦e276fd206⟧ Bits:30009696 Philips computer tape "600413"
    └─⟦this⟧ »DEMO6800/BCSTTO.SC« 
└─⟦f350e1b7a⟧ Bits:30009678 Philips computer tape "600219"
    └─⟦this⟧ »PTSDEMO/BCSTTO.SC«

PTS(SC)

 IDENT BCSTTO START OPERATOR
	DDUM	DEMODD			
	PDIV				
	EXPROC	PAJRN 
	EXPROC	XBFMT			 
	EXPROC	XEERR 
	EXPROC	XAKBIN
	EXPROC	XCLAMP
	EXPROC	ZCRDD 
	EXPROC	ZGREA 
	EXPROC	ZDRWRD
	ENTRY	BCSTTO 
	ENTRY	CCSTTT 
	ENTRY	SPAP07 
	ENTRY	SPAP08 
	ENTRY	SPAP09 
************************************************************************
* 
*        START OPERATOR PROCEDURE*
* 
************************************************************************
BCSTTO	PROC				
BCOOO					
	MOVE	NDTRMLGG,YDSYSLGG	INITIALISE LANGUAGE 
	CBE	RDSTATUS,=D'2',BC100	TERMINAL ALREADY STARTED  		
	PERF	CCSTTT			
	TBT	SBCANCEL,BC999	IF CANCELED, RETURN 
BC100					
	SET	SBSTTO 
* 
* PRINT LINE TYPE 1: IDENTIFICATION 
* 
	PERF	PAJRN,=W'1' 
BC150 
	MOVE	IDNR2,=D'0'	INIT RETRY COUNT
	PERF	XBFMT,=W'21'	DISPLAY OPERATOR START SCREEN		
	MOVE	NDTRMLGG,ODOPRLGG	SET LANGUAGE
	TBT	SBCANCEL,BC900	IF CANCELED, RETURN		
	TBF	SBTRMBLK,BC400	TERMINAL BLOCKED?		
* 
* TERMINAL IS BLOCKED*
* 
	PERF	XCLAMP,KW5,KW1	LAMP 5 ON
	PERF	XEERR,=W'26',KW0	CALL SUPERVISOR
BC200 
	PERF	XAKBIN,=W'0'	ASK FOR ANSWER 
	TBF	SBKEY2,BC200	WAIT FOR KEY2		
**
* KEY2 ON*
**
	PERF	XCLAMP,KW3,KW0	ERROR LAMP OFF 
	PERF	XCLAMP,KW5,KW0	LAMP 5 OFF 
	CLEAR	SBTRMBLK 
	B	BC150
BC400					
	TBF	SBFT80,BC410	NO COMPACT TERMINAL 
	PERF	XBFMT,=W'69'
	B	BC420
BC410 
	PERF	XBFMT,=W'22'	DISPLAY OPERATOR BALANCES		
BC420 
	TBT	SBCANCEL,BC900	IF CANCELED, RETURN		
	MOVE	RDSTATUS,=D'3'	OPERATOR LOGGED ON (TWB)		
	MOVE	ODSTATUS,=D'2'	    "      "    "  (UWB)		
	MOVE	RDOPRNR,IDNR1	SAVE OPERATOR NUMBER IN TWB 
	MOVE	ODTRMNR,NDTRMNR	SAVE TERMINAL NUMBER IN UWB		 
	PERF	ZDRWRD,ODOPRRNR,NDLRN1	WRITE OPERATOR RECORD
	TBT	SBCANCEL,BC900 
	MOVE 	TDTRSCDE,=D'901'			
	ADD	YDLASSEQ,=D'1'			
	MOVE	TDTRSSEQ,YDLASSEQ			
**
* PRINT THE OPERATOR BALANCES*
* *
         MOVE    ICTEXT3,YCCCY(KW4)    SYSTEM CURRENCY
	MOVE	TDAMOUNT,ODCASH(KW1,KW4)	CASH BALANCE		 
	PERF	PAJRN,=W'7'			
* FOREIGN CURRENCIES*
	MOVE	IWINDEX1,KW0			
BC500					
	ADD	IWINDEX1,=W'1'			
         MOVE    ICTEXT3,YCCCY(IWINDEX1)
	MOVE	TDAMOUNT,ODCASH(KW1,IWINDEX1)			
	PERF	PAJRN,=W'7'			
	CBL	IWINDEX1,=W'3',BC500			
	B	BC990
* 
* CANCEL EXIT 
* 
BC900					
	MOVE	RDSTATUS,=D'2'	RESET STATUS 
	PERF	ZGREA	RELEASE EXCL. ACCES 
BC990 
	PERF	PAJRN,=W'3'	END OF FUNCTION 
BC999 
	CLEAR	SBSTTO 
	RET				
	PEND				
************************************************************************
**
* CHECK OPERATOR IDENTIFICATION IN OPERATOR START*
**
************************************************************************
SPAP08	PROC	XWRET 
	PBIN	XWRET 
S08000					 
	CBL	IDNR1,=D'10001',S08600	RANGE ERROR 
	CBG	IDNR1,=D'19999',S08600	RANGE ERROR 
	MOVE	ODOPRRNR,IDNR1	SAVE OPERATOR NUMBER 
	MUL	ODOPRRNR,KDSHIFT	GET RECORD NUMBER

Full view