DataMuseum.dk

Presents historical artifacts from the history of:

Philips Data Systems

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about Philips Data Systems

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - metrics - download

⟦d911e98fb⟧ 

    Length: 10660 (0x29a4)
    Notes: pts_type(SC)
    Names: »CDCHKY.SC«

Derivation

└─⟦f350e1b7a⟧ Bits:30009678 Philips computer tape "600219"
    └─⟦this⟧ »PTSDEMO/CDCHKY.SC«

PTS(SC)

         IDENT    CDCHKY                CHECK FUNCTIONKEY-COMBINATION 
	DDUM	DEMODD
	PDIV 
	EXPROC	XEERR 
	ENTRY	CDCHKY 
************************************************************************
* 
* CHECK THE VALIDITY OF FUNCTION KEY COMBINATIONS 
* 
************************************************************************
CDCHKY	PROC 
CD000 
************************************************************************
**
* CHECKS ON CURRENCY*
**
************************************************************************
CD110					
	CBNE	KDCHECKS(NWKTBIX,KW1),=D'1',CD112			 
	CBNE	SWCCY,=W'0',CD990	ERROR		
	B 	CD120	NEXT CHECK		
**
* SPECIFIC CURRENCY CHECKS*
**
CD112					
	CBNE	KDCHECKS(NWKTBIX,KW1),=D'2',CD120	  NO SPECIFIC CHECK 
	CBE	SWCCY,=W'0',CD115			
**
* CURRENCY IS ON*
**
	TBT	SBCHEQUE,CD990			
	TBT	SBNOBOOK,CD990			
	TBT	SBCARD,CD990			
	TBT	SBRVS,CD990	ERRORS		
	B	CD120	NEXT CHECK		
**
* CURRENCY IS OFF*
**
CD115					
	TBF	SBFLDEMP,CD990	FIELD NOT EMPTY		
************************************************************************
**
* CHECKS ON CHEQUE*
**
************************************************************************
CD120					
	CBNE	KDCHECKS(NWKTBIX,KW2),=D'1',CD122			 
	TBT	SBCHEQUE,CD990	ERROR		
	B	CD130	NEXT CHECK		
**
* SPECIFIC CHEQUE CHECKS*
**
CD122					
	CBNE	KDCHECKS(NWKTBIX,KW2),=D'2',CD130	  NO SPECIFIC CHECK 
	TBF	SBCHEQUE,CD130	 ONLY IF CHEQUE IS ON		
**
* CHEQUE IS ON*
**
	TBT	SBRVS,CD990	'REVERSAL' MUST BE OFF		
	TBT	SBNOBOOK,CD990	'NOBOOK' MUST BE OFF		
	TBT	SBZEK,CD990	'ZEKOSA' MUST BE OFF 
	TBT	SBCARD,CD990	'CARD' MUST BE OFF
	TBF	SBFLDEMP,CD990	FIELD MUST BE EMPTY 
************************************************************************
**
* CHECKS ON NOBOOK*
**
************************************************************************
CD130 
	CBNE	KDCHECKS(NWKTBIX,KW3),=D'1',CD132			 
	TBT	SBNOBOOK,CD990	ERROR		
	B	CD140	NEXT CHECK		
**
* SPECIFIC NOBOOK CHECKS*
**
CD132					
	CBNE	KDCHECKS(NWKTBIX,KW3),=D'2',CD140			 
	TBF	SBNOBOOK,CD140	OK, NEXT CHECK		
	TBT	SBZEK,CD990	'ZEKOSA' MUST BE OFF 
	TBT	SBCARD,CD990	'CARD' MUST BE OFF		
	TBF	SBFLDEMP,CD990	FIELD MUST BE EMPTY 
************************************************************************
**
* CHECKS ON REVERSAL*
**
************************************************************************
CD140					
	CBNE	KDCHECKS(NWKTBIX,KW4),=D'1',CD142			 
	TBT	SBRVS,CD990	ERROR		
	B	CD150	NEXT CHECK		
CD142					
************************************************************************
**
* CHECKS ON CARD*
**
************************************************************************
CD150					
	CBNE	KDCHECKS(NWKTBIX,KW5),=D'1',CD152			 
	TBT	SBCARD,CD990	ERROR		
	B	CD160	NEXT CHECK		
**
* SPECIFIC CARD CHECKS*
**
CD152					
	CBNE	KDCHECKS(NWKTBIX,KW5),=D'2',CD154			 
	TBF	SBCARD,CD160	OK, NEXT CHECK		
	TBT	SBNOBOOK,CD990	'NOBOOK' MUST BE OFF		
	TBT	SBCHEQUE,CD990	'CHEQUE' MUST BE OFF		
	TBF	SBFLDEMP,CD990	FIELD MUST BE EMPTY 
CD154 
	CBNE	KDCHECKS(NWKTBIX,KW5),=D'3',CD160 
	TBF	SBCARD,CD160 
	TBF	SBCHEQUE,CD990 
************************************************************************
**
* CHECKS ON THE INPUT-FIELD*
**
************************************************************************
CD160					
	CBNE	KDCHECKS(NWKTBIX,KW6),=D'1',CD170			 
	TBF	SBFLDEMP,CD990	FIELD NOT EMPTY, ERROR		
************************************************************************
* 
*  CHECKS ON ZEKOSA FUNCTION REQUEST
* 
************************************************************************* 
CD170 

	MOVE	WW1,='7'
	CBNE	KDCHECKS(NWKTBIX,WW1),=D'1',CD172 
	TBT	SBZEK,CD990	ERROR, ZEKOSA ALREADY ON 
	B	CD999
************************************************************************
* 
*  SPECIFIC ZEKOSA CHECKS 
* 
************************************************************************* 
CD172 
	CBNE	KDCHECKS(NWKTBIX,WW1),=D'2',CD174 
	TBF	SBZEK,CD999	OK, NEXT CHECK 
	TBT	SBCARD,CD990	'CARD' OFF
	TBT	SBNOBOOK,CD990	'NOBOOK' OFF
	TBT	SBCHEQUE,CD990	'CHEQUE' OFF
	TBF	SBFLDEMP,CD990	FIELD MUST BE EMPTY 
CD174 
	CBNE	KDCHECKS(NWKTBIX,WW1),=D'3',CD999 
	TBF	SBZEK,CD999	OK, FINISHED 
	TBT	SBCARD,CD990 
	TBT	SBCHEQUE,CD990 
	B	CD999	OK TOO, FINISHED 
CD990 
	PERF	XEERR,=W'10',KW1	UNSERVICEABLE REQUEST
CD999 
	RET
	PEND 
* 
* 
	END

Full view