DataMuseum.dk

Presents historical artifacts from the history of:

Philips Data Systems

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about Philips Data Systems

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - metrics - download

⟦f85045457⟧ 

    Length: 4806 (0x12c6)
    Notes: pts_type(SC)
    Names: »TABORT.SC«

Derivation

└─⟦efe3a1cfc⟧ Bits:30009667 Philips computer tape "600113"
    └─⟦this⟧ »TOSSWORK/TABORT.SC«

PTS(SC)

	IDENT TABORT 	REL 8.2 78-09-15  870105040820 

* 
************************************************* 
* 
*   PHILIPS TERMINAL SYSTEM PTS 
* 
*   TABORT = ABORT I/O REQUEST
* 
* 
* 
* 
* 
* 
************************************************* 
* 
* 
*   THIS MODULE IS CALLED BY THE LKM HANDLER WITH THE FOLLOWING 
*   PARAMETERS:-
* 
*   A5 = TTAB-ADDRESS OF CALLING PROGRAM
* 
*   A8 = ECB-ADDRESS OF I/O REQUEST TO BE ABORTED 
* 
*   A PENDING I/O REQUEST IS ABORTED. 
*   THE ABORT REQUEST MUST BE DONE FROM THE SAME TASK 
*   THAT MADE THE I/O REQUEST. THUS I/O WITH WAIT CAN 
*   NOT BE ABORTED. 
	EJECT


	ENTRY	TABORT 


	EXTRN	FNDDWT	FIND DWT-ADDRESS
	EXTRN	DWTST	DWT STATUS 
	EXTRN	DWTTAB	TTAB-ADDRESS IN DWT 
	EXTRN	DWTWAT	WAIT ACTIVATE INDICATOR IN DWT
	EXTRN	TABIO	ABORT I/O AND ACTIVATE 
	EXTRN	TENDIO	END I/O 
	EXTRN	LKMQDI	QUEUE JOB AND DISPATCH
	EXTRN	LKMRQE	LKM REQUEST ERROR 
	EXTRN	ITABRT	ABORT INTERTASK REQUEST 
	EXTRN	FREBLK	FREE ONE BLOCK


DWTECH	EQU	/22	ECHO DEVICE DWT
* 
*  CONDITIONAL ASSEMBLY 
* 
*  BY SETTING X:A=0 NO ACTIVATION (IF ANY) WILL TAKE PLACE
*  IF X:A=1 I/O REQUEST WITH ACTIVATION WILL BE ABORTED AND 
*  THE ACTIVATION WILL BE PERFORMED WITH A7=1 TO INDICATE 
*  REQUEST HAS BEEN ABORTED 
CREDIT	EQU	0
	EJECT

* 
*	ABORT I/O REQUEST 
* 

TABORT	LDR*	A3,A8 
	RF(N)	TABOER	REQUEST ALREADY COMPLETED 

	CF	A15,FNDDWT	LOOK FOR DWT ADDRESS 
	LDR	A8,A6
	RF(Z)	TABOER	DWT UNKNOWN 

	CW	A5,DWTTAB,A6
	RF(NE)	TABOER	ILLEGAL TASK 

	LD	A7,DWTST,A6 
	RF(N)	TABOER	DEVICE NOT BUSY 

	SLC	A7,2 
	RF(NN)	TABO20	NOT ECHO REQUEST 
	LD	A6,DWTECH,A6	GET ECHO DWT 
	CF	A15,TENDIO	ABORT ECHO DEVICE
	LDR	A6,A8	RESTORE DWT
TABO20	EQU	*
	CF	A15,ITABRT	ABORT IF INTERTASK REQUEST 
	IFT	CREDIT=1 
	LDKL	A1,/C000	RETURN CODE
	CF	A15,TABIO	ABORT AND ACTIVATE IF REQUESTED 
	XIF
	IFF	CREDIT=1 
	LD	A4,DWTWAT,A6
	RF(Z)	TABO30	I/O NOT WAIT
	CF	A15,FREBLK	I/O AND ACTIVATE FREE DISP BLK 
	CM	DWTWAT,A6	SET NOT WAIT
TABO30	EQU	*
	LDKL	A1,/C000	RETURN CODE
	CF	A15,TENDIO	ABORT
	XIF
	ABL	LKMQDI	QUEUE TASK AND GO TO DISPATCHER 

TABOER	ABL	LKMRQE	GO AND INDICATE LKM ERROR 


	END

Full view