separate (Compilation_Unit.Produce_Metrics)
procedure Selective_Wait_Alternative
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --======================================
    -- Selective_Wait_Alternative ::=
    --      Accept_Alternative
    --    | Delay_Alternative
    --    | "TERMINATE" ";"
    --======================================

    Current_Token : Token_Package.Token;

begin
    -- Selective_Wait_Alternative

    case Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) is

        when Token_Package.Accept_Token =>
            Accept_Alternative
               (Current_Compilation_Unit => Current_Compilation_Unit,
                Program_Unit => Program_Unit,
                Halstead => Halstead,
                Loc => Loc,
                Mccabe => Mccabe);

        when Token_Package.Delay_Token =>
            Delay_Alternative
               (Current_Compilation_Unit => Current_Compilation_Unit,
                Program_Unit => Program_Unit,
                Halstead => Halstead,
                Loc => Loc,
                Mccabe => Mccabe);

        when Token_Package.Terminate_Token =>
            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            -- increment Halstead TERMINATE operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.Terminate_Halstead));

            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            if "/=" (Token_Package.Value_Of (Current_Token),
                     Token_Package.Semicolon_Token) then
                raise Syntax_Error;
            end if;

            -- increment Halstead SEMICOLON operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.Semicolon_Halstead));

        when others =>
            raise Syntax_Error;

    end case;

end Selective_Wait_Alternative;