separate (Compilation_Unit.Produce_Metrics)
procedure With_Clause (Current_Compilation_Unit : in out Ada_Compilation_Unit;
                       Program_Unit : in Program_Unit_State_Machine;
                       Halstead : in Halstead_State_Machine;
                       Loc : in Loc_State_Machine;
                       Mccabe : in Mccabe_State_Machine) is


    --===============================================
    -- process the with clause and update statistics
    --
    -- WITH counts as one LOC data daclaration
    -- With_Clause ::= "WITH" ID_List ";"
    --===============================================

    Dummy_Count : Natural; -- don't care how many IDENTIFIERs are
    -- in the ID_List
    Current_Token : Token_Package.Token;

begin
    -- With_Clause

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);
    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.With_Token) then
        raise Syntax_Error;
    end if;
    -- increment LOC data declaration count
    Loc.Change_Data_Declarations_Count;

    -- increment Halstead WITH operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.With_Halstead));

    Id_List (Current_Compilation_Unit => Current_Compilation_Unit,
             Program_Unit => Program_Unit,
             Halstead => Halstead,
             Loc => Loc,
             Mccabe => Mccabe,
             Number_Of_Identifiers => Dummy_Count);

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);
    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Semicolon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead SEMICOLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Semicolon_Halstead));

end With_Clause;