separate (Compilation_Unit.Produce_Metrics)
procedure Begin_End_Block
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --========================================
    -- Begin_End_Block ::=
    --     "BEGIN"
    --     Sequence_Of_Statements
    --     [ Exception_Handler ]
    --     "END"
    --========================================

    Current_Token : Token_Package.Token;  -- token being examined

begin
    -- Begin_End_Block

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Begin_Token) then
        raise Syntax_Error;
    end if;

    Sequence_Of_Statements
       (Current_Compilation_Unit => Current_Compilation_Unit,
        Program_Unit => Program_Unit,
        Halstead => Halstead,
        Loc => Loc,
        Mccabe => Mccabe);

    if Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) =
       Token_Package.Exception_Token then

        Exception_Handler (Current_Compilation_Unit => Current_Compilation_Unit,
                           Program_Unit => Program_Unit,
                           Halstead => Halstead,
                           Loc => Loc,
                           Mccabe => Mccabe);
    end if;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.End_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead BEGIN_END operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Begin_End_Halstead));

end Begin_End_Block;