separate (Compilation_Unit.Produce_Metrics)
procedure Basic_Loop_Statement
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --====================================================
    -- Basic_LOOP_Statement ::=
    --   "LOOP"
    --   Sequence_Of_Statements
    --   "END" "LOOP" [ <IDENTIFIER> ] ";"
    --====================================================

    Current_Token : Token_Package.Token;

begin
    -- Basic_Loop_Statement

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Loop_Token) then
        raise Syntax_Error;
    end if;

    Sequence_Of_Statements
       (Current_Compilation_Unit => Current_Compilation_Unit,
        Program_Unit => Program_Unit,
        Halstead => Halstead,
        Loc => Loc,
        Mccabe => Mccabe);

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.End_Token) then
        raise Syntax_Error;
    end if;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Loop_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead LOOP_END_LOOP operator count
    Halstead.Store_Operator ((Kind =>
                                 Halstead_Operator.Loop_End_Loop_Halstead));

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if Token_Package.Class_Of (Current_Token) = Token_Package.Identifier then

        -- increment Halstead operand count
        Halstead.Store_Operand (Halstead_Operand.Definition
                                   (Token_Package.Value_Of
                                       (This_Token => Current_Token)));

        Get_Next_Token (Out_Token => Current_Token,
                        From => Current_Compilation_Unit,
                        Current_Loc => Loc);
    end if;

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Semicolon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead SEMICOLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Semicolon_Halstead));

end Basic_Loop_Statement;