separate (Compilation_Unit.Produce_Metrics)
procedure Function_Specification
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine;
              Unit_Name : out Program_Unit_Name;
              Formal_Parameters_Count : out Natural) is

    --===========================================================
    -- Function_Specification ::=
    --   "FUNCTION" Designator [ Formal_Part ] "RETURN" Name
    --===========================================================

    Current_Token : Token_Package.Token;
    Dummy_Name_Kind : Name_Kind;

begin
    -- Function_Specification

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Function_Token) then
        raise Syntax_Error;
    end if;

    Designator (Current_Compilation_Unit => Current_Compilation_Unit,
                Program_Unit => Program_Unit,
                Halstead => Halstead,
                Loc => Loc,
                Mccabe => Mccabe,
                Unit_Name => Unit_Name);

    if Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) =
       Token_Package.Left_Parenthesis_Token then

        Formal_Part (Current_Compilation_Unit => Current_Compilation_Unit,
                     Program_Unit => Program_Unit,
                     Halstead => Halstead,
                     Loc => Loc,
                     Mccabe => Mccabe,
                     Formal_Parameters_Count => Formal_Parameters_Count);

    else

        Formal_Parameters_Count := 0;

    end if;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Return_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead RETURN operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Return_Halstead));

    Name (Current_Compilation_Unit => Current_Compilation_Unit,
          Program_Unit => Program_Unit,
          Halstead => Halstead,
          Loc => Loc,
          Mccabe => Mccabe,
          Out_Name_Kind => Dummy_Name_Kind);

end Function_Specification;