separate (Compilation_Unit.Produce_Metrics)
procedure Id_Declaration
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --==================================================
    -- ID_Declaration ::=
    --   ID_List ":"
    --   $ number of IDENTIFIER is one $
    --   1. ID_Type_Declaration ";"
    --   2. ID_List_Type_Declaration ";"
    --==================================================

    Current_Token : Token_Package.Token;
    Number_Of_Identifiers : Positive;

begin
    -- ID_Declaration

    Id_List (Current_Compilation_Unit => Current_Compilation_Unit,
             Program_Unit => Program_Unit,
             Halstead => Halstead,
             Loc => Loc,
             Mccabe => Mccabe,
             Number_Of_Identifiers => Number_Of_Identifiers);

    -- change LOC data declaration count by Number_Of_IDENTIFIERs
    Loc.Change_Data_Declarations_Count
       (The_Amount_To_Change => Number_Of_Identifiers);

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Colon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead COLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Colon_Halstead));

    if Number_Of_Identifiers = 1 then

        Id_Type_Declaration
           (Current_Compilation_Unit => Current_Compilation_Unit,
            Program_Unit => Program_Unit,
            Halstead => Halstead,
            Loc => Loc,
            Mccabe => Mccabe);
    else

        Id_List_Type_Declaration
           (Current_Compilation_Unit => Current_Compilation_Unit,
            Program_Unit => Program_Unit,
            Halstead => Halstead,
            Loc => Loc,
            Mccabe => Mccabe);
    end if;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Semicolon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead SEMICOLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Semicolon_Halstead));

end Id_Declaration;