separate (Compilation_Unit.Produce_Metrics)
procedure Type_Declaration
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --================================================
    -- Formal_Part is Discriminant_Part
    -- Type_Declaration ::=
    --   "TYPE" <IDENTIFIER> [ Formal_Part ]
    --      [ "IS" Type_Definition ] ";"
    --================================================

    Dummy_Count : Natural;
    Current_Token : Token_Package.Token;

begin
    -- Type_Declaration

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Type_Token) then
        raise Syntax_Error;
    end if;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Class_Of (Current_Token),
             Token_Package.Identifier) then
        raise Syntax_Error;
    end if;

    -- increment Halstead operand count
    Halstead.Store_Operand (Halstead_Operand.Definition
                               (Token_Package.Value_Of
                                   (This_Token => Current_Token)));

    if Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) =
       Token_Package.Left_Parenthesis_Token then

        Formal_Part (Current_Compilation_Unit => Current_Compilation_Unit,
                     Program_Unit => Program_Unit,
                     Halstead => Halstead,
                     Loc => Loc,
                     Mccabe => Mccabe,
                     Formal_Parameters_Count => Dummy_Count);

    end if;

    if Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) =
       Token_Package.Is_Token then

        Get_Next_Token (Out_Token => Current_Token,
                        From => Current_Compilation_Unit,
                        Current_Loc => Loc);

        -- increment Halstead TYPE_IS operator count
        Halstead.Store_Operator ((Kind => Halstead_Operator.Type_Is_Halstead));

        Type_Definition (Current_Compilation_Unit => Current_Compilation_Unit,
                         Program_Unit => Program_Unit,
                         Halstead => Halstead,
                         Loc => Loc,
                         Mccabe => Mccabe);

    else

        -- increment Halstead TYPE operator count
        Halstead.Store_Operator ((Kind => Halstead_Operator.Type_Halstead));

    end if;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Semicolon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead SEMICOLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Semicolon_Halstead));

end Type_Declaration;