separate (Compilation_Unit.Produce_Metrics)
procedure Return_Statement
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --===============================================================
    -- RETURN_Statement ::= "RETURN" [ Expression ] ";"
    --===============================================================

    Current_Token : Token_Package.Token;

begin
    -- RETURN_Statement

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Return_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead RETURN operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Return_Halstead));

    if "/=" (Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)),
             Token_Package.Semicolon_Token) then

        -- until ";" is found
        Expression (Current_Compilation_Unit => Current_Compilation_Unit,
                    Program_Unit => Program_Unit,
                    Halstead => Halstead,
                    Loc => Loc,
                    Mccabe => Mccabe,
                    Terminate_Tokens =>
                       Set_Of_Tokens'(1 => Token_Package.Semicolon_Token));
    end if;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Semicolon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead SEMICOLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Semicolon_Halstead));

end Return_Statement;