separate (Compilation_Unit.Produce_Metrics)
procedure Procedure_Specification
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine;
              Unit_Name : out Program_Unit_Name;
              Formal_Parameters_Count : out Natural) is

    --=====================================================
    -- process a specification part and update statitistics
    --
    -- Procedure_Specification ::=
    --   "PROCEDURE" <IDENTIFIER> [ Formal_Part ]
    --=====================================================

    Current_Token : Token_Package.Token;

begin
    -- Procedure_Specification

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Procedure_Token) then
        raise Syntax_Error;
    end if;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Class_Of (Current_Token),
             Token_Package.Identifier) then
        raise Syntax_Error;
    end if;

    -- get program unit name
    Unit_Name := String_To_Name (Token_Package.Value_Of (Current_Token));

    -- increment Halstead operand count
    Halstead.Store_Operand (Halstead_Operand.Definition
                               (Token_Package.Value_Of
                                   (This_Token => Current_Token)));

    if Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) =
       Token_Package.Left_Parenthesis_Token then

        Formal_Part (Current_Compilation_Unit => Current_Compilation_Unit,
                     Program_Unit => Program_Unit,
                     Halstead => Halstead,
                     Loc => Loc,
                     Mccabe => Mccabe,
                     Formal_Parameters_Count => Formal_Parameters_Count);
    else
        Formal_Parameters_Count := 0; -- parameterless procedure unit
    end if;

end Procedure_Specification;