separate (Compilation_Unit.Produce_Metrics)
procedure Floating_Point_Constraint
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --===================================================
    -- Floating_Point_Constraint ::=
    --   "DIGITS" Expression [ Range_Constraint ]
    --===================================================

    Current_Token : Token_Package.Token;

begin
    -- Floating_Point_Constraint

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Digits_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead DIGITS operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Digits_Halstead));

    -- until ";", "RANGE", or ":=" is found
    Expression
       (Current_Compilation_Unit => Current_Compilation_Unit,
        Program_Unit => Program_Unit,
        Halstead => Halstead,
        Loc => Loc,
        Mccabe => Mccabe,
        Terminate_Tokens =>
           Set_Of_Tokens'
              (Token_Package.Semicolon_Token,
               Token_Package.Assignment_Token, Token_Package.Range_Token));

    if Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) =
       Token_Package.Range_Token then

        Range_Constraint (Current_Compilation_Unit => Current_Compilation_Unit,
                          Program_Unit => Program_Unit,
                          Halstead => Halstead,
                          Loc => Loc,
                          Mccabe => Mccabe);
    end if;

end Floating_Point_Constraint;