separate (Compilation_Unit.Produce_Metrics)
procedure Abort_Statement
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --===========================================================
    -- ABORT_Statement ::= "ABORT" Name { "," Name } ";"
    --===========================================================

    Dummy_Name_Kind : Name_Kind;
    Current_Token : Token_Package.Token;
    No_More_Names : Boolean := False;

begin
    -- ABORT_Statement

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Abort_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead ABORT operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Abort_Halstead));

    Process_Names:
        loop

            Name (Current_Compilation_Unit => Current_Compilation_Unit,
                  Program_Unit => Program_Unit,
                  Halstead => Halstead,
                  Loc => Loc,
                  Mccabe => Mccabe,
                  Out_Name_Kind => Dummy_Name_Kind);

            -- if ";" is found, then set No_More_Names to TRUE
            Get_Next_Token (Out_Token => Current_Token,
                            From => Current_Compilation_Unit,
                            Current_Loc => Loc);

            case Token_Package.Value_Of (Current_Token) is

                when Token_Package.Comma_Token =>

                    -- increment Halstead COMMA operator count
                    Halstead.Store_Operator
                       ((Kind => Halstead_Operator.Comma_Halstead));

                when others =>
                    No_More_Names := True;

            end case;

            exit Process_Names when No_More_Names;

        end loop Process_Names;

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Semicolon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead SEMICOLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Semicolon_Halstead));

end Abort_Statement;