separate (Compilation_Unit.Produce_Metrics)
procedure Exit_Statement
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --==================================================================
    -- EXIT_Statement ::= "EXIT" [ Name ] [ "WHEN" Expression ]  ";"
    --==================================================================

    Current_Token : Token_Package.Token;
    Dummy_Name_Kind : Name_Kind;

begin
    -- EXIT_Statement

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Exit_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead EXIT operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Exit_Halstead));

    case Token_Package.Class_Of

            (Peek (From => Current_Compilation_Unit)) is

        when Token_Package.Identifier | Token_Package.Character_Literal |
             Token_Package.Standard_String_Literal |
             Token_Package.Alternate_String_Literal =>

            Name (Current_Compilation_Unit => Current_Compilation_Unit,
                  Program_Unit => Program_Unit,
                  Halstead => Halstead,
                  Loc => Loc,
                  Mccabe => Mccabe,
                  Out_Name_Kind => Dummy_Name_Kind);

        when others =>
            null;

    end case;

    if Token_Package.Value_Of (Peek (From => Current_Compilation_Unit)) =
       Token_Package.When_Token then

        Get_Next_Token (Out_Token => Current_Token,
                        From => Current_Compilation_Unit,
                        Current_Loc => Loc);

        -- increment Halstead WHEN operator count
        Halstead.Store_Operator ((Kind => Halstead_Operator.When_Halstead));

        -- increment McCabe PI
        Mccabe.Change_Pi;

        -- until ";" is found
        Expression (Current_Compilation_Unit => Current_Compilation_Unit,
                    Program_Unit => Program_Unit,
                    Halstead => Halstead,
                    Loc => Loc,
                    Mccabe => Mccabe,
                    Terminate_Tokens =>
                       Set_Of_Tokens'(1 => Token_Package.Semicolon_Token));

    end if;

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Semicolon_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead SEMICOLON operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Semicolon_Halstead));

end Exit_Statement;