separate (Compilation_Unit.Produce_Metrics)
procedure Generic_Specification
             (Current_Compilation_Unit : in out Ada_Compilation_Unit;
              Program_Unit : in Program_Unit_State_Machine;
              Halstead : in Halstead_State_Machine;
              Loc : in Loc_State_Machine;
              Mccabe : in Mccabe_State_Machine) is

    --==============================================================
    -- Progam unit name is GENERIC_UNIT
    -- Generic_Specification ::=
    --     "GENERIC"
    --     { Generic_Parameter_Declaration }
    --     Generic_Subprogram_Or_Package_Specification
    --==============================================================

    Current_Token : Token_Package.Token;
    No_More_Declarations : Boolean := False;

begin
    -- Generic_Specification

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    if "/=" (Token_Package.Value_Of (Current_Token),
             Token_Package.Generic_Token) then
        raise Syntax_Error;
    end if;

    -- increment Halstead GENERIC operator count
    Halstead.Store_Operator ((Kind => Halstead_Operator.Generic_Halstead));

    Process_Declarative_Items:
        loop

            case Token_Package.Value_Of
                    (Peek (From => Current_Compilation_Unit)) is

                when Token_Package.Procedure_Token |
                     Token_Package.Function_Token |
                     Token_Package.Package_Token =>

                    No_More_Declarations := True;

                when others =>

                    Generic_Parameter_Declaration
                       (Current_Compilation_Unit => Current_Compilation_Unit,
                        Program_Unit => Program_Unit,
                        Halstead => Halstead,
                        Loc => Loc,
                        Mccabe => Mccabe);

            end case;

            exit Process_Declarative_Items when No_More_Declarations;

        end loop Process_Declarative_Items;

    Generic_Subprogram_Or_Package_Specification
       (Current_Compilation_Unit => Current_Compilation_Unit,
        Program_Unit => Program_Unit,
        Halstead => Halstead,
        Loc => Loc,
        Mccabe => Mccabe);

end Generic_Specification;