separate (Compilation_Unit.Produce_Metrics)
procedure Designator (Current_Compilation_Unit : in out Ada_Compilation_Unit;
                      Program_Unit : in Program_Unit_State_Machine;
                      Halstead : in Halstead_State_Machine;
                      Loc : in Loc_State_Machine;
                      Mccabe : in Mccabe_State_Machine;
                      Unit_Name : out Program_Unit_Name) is

    --=======================================
    -- Designator ::=
    --     <IDENTIFIER>
    --   | <STANDARD_STRING_LITERAL>
    --   | <ALTERNATE_STRING_LITERAL>
    --=======================================

    Current_Token : Token_Package.Token;

begin
    -- Designator

    Get_Next_Token (Out_Token => Current_Token,
                    From => Current_Compilation_Unit,
                    Current_Loc => Loc);

    case Token_Package.Class_Of (Current_Token) is

        when Token_Package.Identifier =>

            -- increment Halstead operand count
            Halstead.Store_Operand (Halstead_Operand.Definition
                                       (Token_Package.Value_Of
                                           (This_Token => Current_Token)));

            -- convert Token_Value to Program_Unit_Name
            Unit_Name := String_To_Name
                            (Token_Package.Value_Of (Current_Token));

        when Token_Package.Standard_String_Literal =>

            -- increment Halstead operand count
            Halstead.Store_Operand (Halstead_Operand.Definition
                                       (Token_Package.Value_Of
                                           (This_Token => Current_Token)));

            -- convert Token_Value to Program_Unit_Name
            Unit_Name := String_To_Name
                            (Token_Package.Value_Of (Current_Token));

            -- increment Halstead QUOTES operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.Quotes_Halstead));

        when Token_Package.Alternate_String_Literal =>

            -- increment Halstead operand count
            Halstead.Store_Operand (Halstead_Operand.Definition
                                       (Token_Package.Value_Of
                                           (This_Token => Current_Token)));

            -- convert Token_Value to Program_Unit_Name
            Unit_Name := String_To_Name
                            (Token_Package.Value_Of (Current_Token));

            -- increment Halstead PERCENTS operator count
            Halstead.Store_Operator ((Kind =>
                                         Halstead_Operator.Percents_Halstead));

        when others =>
            raise Syntax_Error;

    end case;

end Designator;