DataMuseum.dk

top - metrics - download

    Length: 10240 (0x2800)
    Types: TextFile
    Names: »ADP00«

└─⟦a137c8bca⟧ Bits:30001766 PL FAERD ASCII NR 9
    └─⟦this⟧ »/ADP00« 

TextFile

; PL RØRT VED VADR0 18.12.83

	.TITL DP000
	.NREL
	.RDXO 16
	.RDX 10
	.TXTM 1
	.TXTN 1
	.NOLOC 1
PGD:	1B0+1B15
	PGD0
	0
	PCD-PGD
	.TXT @DP000@
PGD0:«ff»
BUFF:	.+0
	.-1
	BUF0
	10
	PCD
	0
	0
	0
	0
	0
BUF0:	.+0
	.-1
	BUF1
	10
	PCD
	0
	0
	0
	0
	0
BUF1:	.+0
	.-1
	0
	10
	PCD
	0
	0
	0
	0
	0«ff»
LZO:	.TXT @LPT<0><0>@
	Z
	0
	1
	65535
	END
	1
	1
	0
	LZO0
	47
	0
	0
	LZO1*2
	LZO1*2
	LZO0
	80
	0
	.BLK ZAUX
LZO0:	0
	0
	0
	0
	LZO0
	0
	LZO1*2
LZO1:	.BLK 40«ff»
BEG0:	LZO
BEG:	LDA 0,.3
	LDA 2,BEG0
	OPEN
	LDA 2,CUR
	OFF«ff»
LDA 0,.512
	DOAS 0,52
	SKPBZ 52
	JMP .-1
	LDA 0,.1
	DOAS 0,52
SKPBZ 52
	JMP .-1
	LDA 0,.64
	STA 0,ADR,2
LOOP:	DIB 0,52
	MOV 0,1
	DIB 0,52
	MOVS 1,1
	ADDS 1,0	; PL /FØR ADD
	STA 0,DATA,2
	OHXW
	OSP
	OSP
	OSP
	DISA
	OLN
	DSZ ADR,2
	JMP LOOP
	JMP ENDC
END0:	.+1
	1B8
	0
	0
	0
	0
END1:	.+1
	.TXT @S<0><0><0><0>@
END3:	LZO
ENDC:	LDA 2,END3
	LDA 1,.12
	OUTEN
	LDA 1,.1
	CLOSE
END:	LDA 1,END0
	LDA 2,END1
	SENDM
	LDA 2,CUR
	STOPP
	JMP END«ff»
DISS0:	0
DISS:	STA 3,DISS0
	LDA 0,DATA,2
	MOVZL 0,0,SZC
	DALUI
	MOVL 0,0
	MOVL 0,0
	MOVL 0,0
	LDA 1,.3
	AND 1,0,SNR
	DJJID
	SEQ 0,1
	DLDST
	DIOIN
DISSE:	JMP @ DISS0«ff»
ALUI0:	.+1
	.TXT @COM<0>NEG<0>MOV<0>INC<0>ADC<0>SUB<0>ADD<0>AND@
ALUI1:	.+1*2
	.TXT @ ZOC@
ALUI2:	.+1*2
	.TXT @ LRS@
ALUI3:	.+1
	.TXT @   <0>SKP<0>SZC<0>SNC<0>SZR<0>SNR<0>SEZ<0>SBN@
ALUI:	LDA 0,DATA,2
	MOVS 0,0
	LDA 1,.7
	AND 1,0
	MOVZL 0,0
	LDA 1,ALUI0
	ADD 1,0
	OTXT
	LDA 0,DATA,2
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0,SNR
	JMP ALUI4
	LDA 1,ALUI1
	ADD 0,1
	GETBY
	OCHR
ALUI4:	LDA 0,DATA,2
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0,SNR
	JMP ALUI5
	LDA 1,ALUI2
	ADD 0,1
	GETBY
	OCHR
ALUI5:	OSP
	LDA 0,DATA,2
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 3,.32
	LDA 1,.3
	MOVR 0,0,SNC
	JMP ALUI6
	ADD 1,3
	MOV 3,0
	OCHR
	OSP
ALUI6:	LDA 0,DATA,2
	MOVS 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0
	LDA 1,.48
	ADD 1,0
	OCHR
	OKOM
	LDA 0,DATA,2
	MOVS 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0
	LDA 1,.48
	ADD 1,0
	OCHR
	LDA 0,DATA,2
	LDA 1,.7
	AND 1,0,SNR
	EDISS
	OKOM
	LDA 1,ALUI3
	MOVZL 0,0
	ADD 1,0
	OTXT
	EDISS«ff»
LDST0:	.
	0
	.TXT @LDA<0>STA@
LDST:	LDA 0,DATA,2
	MOVS 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0
	MOVZL 0,0
	LDA 1,LDST0
	ADD 1,0
	OTXT
	OSP
	LDA 0,DATA,2
	MOVS 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0,SNC
	JMP LDST1
	LDA 0,.64
	OCHR
	OSP
LDST1:	LDA 0,DATA,2
	MOVS 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0
	LDA 1,.48
	ADD 1,0
	OCHR
	OKOM
LDST6:	LDA 0,DATA,2
	MOVS 0,0
	MOVL 0,0,SNC
	JMP LDST2
	LDA 0,LDST3
	OCHR
	LDA 1,.255
	LDA 0,DATA,2
	AND 1,0
	INC 1,1
	SUB 0,1
	MOV 1,0
	OHXB
	JMP LDST4
LDST3:	45
LDST2:	LDA 0,DATA,2
	LDA 1,.255
	AND 1,0
	OHXB
LDST4:	OKOM
	LDA 0,DATA,2
	MOVS 0,0
	LDA 1,.3
	AND 1,0
	LDA 1,.48
	ADD 1,0
	OCHR
	EDISS
«ff»
JJID0:	.+1
	.TXT @JMP<0>JSR<0>ISZ<0>DSZ@
JJID:	LDA 0,DATA,2
	MOVS 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0
	MOVZL 0,0
	LDA 1,JJID0
	ADD 1,0
	OTXT
	OSP
	LDA 0,DATA,2
	MOVS 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0,SNC
	JMP JJID1
	LDA 0,.64
	OCHR
	OSP
JJID1:	LDA 0,DATA,2
	MOVS 0,0
	MOVL 0,0,SNC
	JMP JJID2
	LDA 0,JJID3
	OCHR
	LDA 1,.255
	LDA 0,DATA,2
	AND 1,0
	INC 1,1
	SUB 0,1
	MOV 1,0
	OHXB
	JMP JJID4
JJID3:	45
JJID2:	LDA 0,DATA,2
	LDA 1,.255
	AND 1,0
	OHXB
JJID4:	OKOM
	LDA 0,DATA,2
	MOVS 0,0
	LDA 1,.3
	AND 1,0
	LDA 1,.48
	ADD 1,0
	OCHR
	EDISS
«ff»
IOIN0:	.+1
	.TXT @NIO<0>DIA<0>DIB<0>DIC<0>DOA<0>DOB<0>DOC<0>SKP@
IOIN1:	.+1*2
	.TXT @ SCP@
IOIN2:	.+1
	.TXT @BNBZDNDZ@
IOIN:	LDA 0,DATA,2
	MOVS 0,0
	LDA 1,.7
	AND 1,0
	MOVZL 0,0
	LDA 1,IOIN0
	ADD 1,0
	OTXT
	LDA 0,DATA,2
	MOVS 0,0
	LDA 1,.7
	AND 1,0
	SNE 1,0
	JMP IOIN3
	LDA 0,DATA,2
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0,SNR
	JMP IOIN4
	LDA 1,IOIN1
	ADD 0,1
	GETBY
	OCHR
	JMP IOIN4
IOIN3:	LDA 0,DATA,2
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0
	LDA 1,IOIN2
	ADD 1,0
	MOV 0,3
	LDA 0,0,3
	MOV 0,1
	MOVS 0,0
	OCHR
	MOV 1,0
	OCHR
	OSP
	JMP IOIN5
IOIN4:	OSP
	LDA 0,DATA,2
	MOVS 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0
	LDA 1,.48
	ADD 1,0
	OCHR
	OKOM
IOIN5:	LDA 0,DATA,2
	LDA 1,.63
	AND 1,0
	LDA 1,IOIN6
	MOVZL 0,3
	ADDZ 3,0
	ADD 1,0
	ONAM
	EDISS
IOIN6:	.+1
	.TXT @000  <0>EXMEM<0>002  <0>003  <0>004  <0>ASL  <0>006  <0>007  @
	.TXT @TTI  <0>TTO  <0>PTR  <0>PTP  <0>RTC  <0>PLT  <0>CDR  <0>LPT  @  
	.TXT @DSC  <0>SPC  <0>SPC1 <0>PTR1 <0>TMX10<0>TMX11<0>TMX0 <0>TMX1 @
	.TXT @MT   <0>PTP1 <0>OCPOB<0>OCPIB<0>OCPKI<0>DISP <0>OCPAL<0>LPS  @
	.TXT @REC  <0>XMT  <0>REC1 <0>XMT1 <0>MT1  <0>CLP  <0>FPAR <0>FPAX @
	.TXT @TTI1 <0>TTO1 <0>AMX  <0>AMX1 <0>HLCR <0>HLCX <0>CDR1 <0>LPT1 @
	.TXT @SMX  <0>FDD  <0>CRP  <0>CLP1 <0>FDD1 <0>053  <0>054  <0>LPS1 @
	.TXT @DST  <0>DOT  <0>CNT  <0>DKP  <0>FPAR2<0>FPAX2<0>062  <0>CPU  @«ff»
PLN0:	0
PLN1:	0
PLN:	STA 3,PLN0
	STA 0,PLN1
	LDA 0,.10
	OCHR
	LDA 0,.13
	OCHR
	LDA 0,PLN1
	DSZ LINE,2
	JMP @ PLN0
	OFF
	JMP @ PLN0«ff»
PFF0:	0
PFF1:	0
PFF2:	0
PFF3:	.+1
	.TXT @<27>=<12><27>3<0>@
PFF5:	.+1
	.TXT @DISCETTE PRINT REV.01.01  <0>@
PFF6:	.+1*2
	.TXT @     <0>@
PFF7:	.+1
	.TXT @<27>4<10><13><10><10><0>@
PFF:	STA 0,PFF0
	STA 1,PFF1
	STA 3,PFF2
	LDA 0,PFF3
	OTXT
	LDA 1,.64
	STA 1,LINE,2
	LDA 0,PFF5
	OTXT
	ISZ PAGE,2
	LDA 0,PAGE,2
	LDA 1,PFF6
	BINDE
	LDA 0,PFF6
	MOVZR 0,0
	INC 0,0
	OTXT
	LDA 0,PFF7
	OTXT
	LDA 1,PFF1
	LDA 0,PFF0
	JMP @ PFF2«ff»
PTXT0:	0
PTXT1:	0
PTXT2:	0
PTXT:	MOVZL 0,0
	STA 0,PTXT0
	STA 1,PTXT1
	STA 3,PTXT2
PTXT3:	LDA 1,PTXT0
	GETBY
	MOV 0,0,SNR
	JMP PTXT4
	OCHR
	ISZ PTXT0
	JMP PTXT3
PTXT4:	LDA 1,PTXT1
	JMP @ PTXT2«ff»
PNAM0:	0
PNAM1:	0
PNAM2:	0
PNAM3:	0
PNAM:	STA 1,PNAM0
	STA 3,PNAM1
	LDA 1,.5
	STA 1,PNAM2
	MOVZL 0,0
	STA 0,PNAM3
PNAM4:	LDA 1,PNAM3
	GETBY
	OASC
	ISZ PNAM3
	DSZ PNAM2
	JMP PNAM4
	LDA 1,PNAM0
	JMP @ PNAM1«ff»
PASC0:	0
PASC1:	0
PASC:	STA 1,PASC0
	STA 3,PASC1
	LDA 1,.127
	AND 1,0
	SNE 1,0
	LDA 0,.32
	LDA 1,.32
	SL 1,0
	LDA 0,.32
	OCHR
	LDA 1,PASC0
	JMP @ PASC1«ff»
PSP0:	0
PSP1:	0
PSP2:	0
PSP:	STA 0,PSP0
	STA 1,PSP1
	STA 3,PSP2
	LDA 0,.32
	OCHR
	LDA 1,PSP1
	LDA 0,PSP0
	JMP @ PSP2«ff»
PKOM0:	0
PKOM1:	0
PKOM2:	0
PKOM3:	44
PKOM:	STA 0,PKOM0
	STA 1,PKOM1
	STA 3,PKOM2
	LDA 0,PKOM3
	OCHR
	LDA 0,PKOM0
	LDA 1,PKOM1
	JMP @ PKOM2«ff»
PHXD0:	0
PHXD1:	0
PHXD2:	.+1*2
	.TXT @0123456789ABCDEF@
PHXD:	STA 1,PHXD0
	STA 3,PHXD1
	LDA 1,.15
	AND 1,0
	LDA 1,PHXD2
	ADD 0,1
	GETBY
	OCHR
	LDA 1,PHXD0
	JMP @ PHXD1«ff»
PHXB0:	0
PHXB1:	0
PHXB2:	0
PHXB:	STA 1,PHXB0
	STA 3,PHXB1
	STA 0,PHXB2
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	OHXD
	LDA 0,PHXB2
	OHXD
	LDA 1,PHXB0
	JMP @ PHXB1«ff»
PHXW0:	0
PHXW1:	0
PHXW2:	0
PHXW:	STA 0,PHXW0
	STA 1,PHXW1
	STA 3,PHXW2
	MOVS 0,0
	OHXB
	LDA 0,PHXW0
	OHXB
	LDA 1,PHXW1
	LDA 0,PHXW0
	JMP @ PHXW2«ff»
PCHR0:	LZO
PCHR1:	0
PCHR2:	0
PCHR:	STA 3,PCHR2
	STA 1,PCHR1
	LDA 2,PCHR0
	MOV 0,1
	OUTEN
	LDA 2,CUR
	LDA 1,PCHR1
	JMP @ PCHR2«ff»
	0
	0
	PFF
	0
	DISSE
	LDST
	IOIN
	JJID
	ALUI
	DISS
	0
	0
	0
	0
	40
	PTXT
	PNAM
	0
	0
	PLN
	0
	0
	0
	0
	0
	0
	0
	0
	0
	END
	ENDC
	0
	0
	PASC
	0
	PHXW
	PHXB
	PHXD
	PKOM
	PSP
	PCHR«ff»
.DUSR	OCHR	=JSR @ -1,2
.DUSR	OSP	=JSR @ -2,2
.DUSR	OKOM	=JSR @ -3,2
.DUSR	OHXD	=JSR @ -4,2
.DUSR	OHXB	=JSR @ -5,2
.DUSR	OHXW	=JSR @ -6,2
.DUSR	OREL	=JSR @ -7,2
.DUSR	OASC	=JSR @ -8,2
.DUSR	IWD	=JSR @ -9,2
.DUSR	IREL	=JSR @ -10,2
.DUSR	TERMC	=JMP @ -11,2
.DUSR	TERM	=JMP @ -12,2
.DUSR	REL0	=-13
.DUSR	REL1	=-14
.DUSR	REL2	=-15
.DUSR	AREL	=-16
.DUSR	DREL	=-17
.DUSR	ADR	=-18
.DUSR	DATA	=-19
.DUSR	BLCK	=-20
.DUSR	CNT	=-21
.DUSR	OLN	=JSR @ -22,2
.DUSR	ORAD	=JSR @ -23,2
.DUSR	OLAB	=JSR @ -24,2
.DUSR	ONAM	=JSR @ -25,2
.DUSR	OTXT	=JSR @ -26,2
.DUSR	.40	=-27
.DUSR	GNBLC	=JMP @ -28,2
.DUSR	GBLC7	=JMP @ -29,2
.DUSR	GBLC2	=JMP @ -30,2
.DUSR	GUBLC	=JMP @ -31,2
.DUSR 	DISA 	=JSR @ -32,2
.DUSR	DALUI	=JMP @ -33,2
.DUSR	DJJID	=JMP @ -34,2
.DUSR	DIOIN	=JMP @ -35,2
.DUSR	DLDST	=JMP @ -36,2
.DUSR	EDISS	=JMP @ -37,2
.DUSR	GBLC6	=JMP @ -38,2
.DUSR	OFF	=JSR @ -39,2
.DUSR	LINE	=-40
.DUSR	PAGE	=-41«ff»
PCD:	.+0
	.-1
	0
	0
	.TXT @DP000@
	.+0
	.-1
	BUFF
	PGD
	0
	0
	42
	END
	0	
	0
	0
	0
	BEG*2
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	.END PCD
«ff»
«nul»