|
DataMuseum.dkPresents historical artifacts from the history of: RegneCentralen RC3600/RC7000 |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about RegneCentralen RC3600/RC7000 Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - metrics - download
Length: 7680 (0x1e00)
Types: TextFile
Names: »B29«
└─⟦6dbcc9c03⟧ Bits:30000463 DOMUS disk image
└─⟦this⟧ »/B29«
0010 REM FIL-NAVN "HANGMAN"
0020 PRINT CHR(12)
0030 DIM BJ$(1)
0040 PRINT TAB(26); "HANGMAN"
0050 PRINT
0060 PRINT "MASKINEN VÆLGER ET ORD SOM DEN GEMMER."
0070 PRINT "DU FÅR KUN AT VIDE HVOR MANGE BOGSTAVER DER INDGÅR I ORDET"
0080 PRINT "HVIS DU GÆTTER RIGTIG FORTÆLLER MASKINEN DIG"
0090 PRINT "HVOR I ORDET BOGSTAVET INDGÅR."
0100 PRINT "EFTER HVER FEJLSLAGEN FORSØG HÆNGER MASKINEN DIG EN LILLE SMULE."
0110 PRINT "DU HAR 10 FORSØG INDEN DU ER HÆNGT H E L T."
0120 PRINT
0130 PRINT "SAMTLIGE ORD ER STAVET MED STORT."
0140 PRINT
0150 PRINT "NÅR/HVIS DU GÆTTER ET BOGSTAV RIGTIG FÅR DU MULIGHED"
0160 PRINT "FOR AT GÆTTE HELE ORDET. HVIS DU FEJLER HER, TÆLLER"
0170 PRINT "DET IKKE MED I REGNSKABET."
0180 PRINT
0190 INPUT "NÅR DU HAR LÆST DETTE TAST RETURN",BJ$
0200 DIM ORD$(20),P$(144,1),D$(20,1),N$(26,1),U(50),H$(3,4)
0210 DIM BOGS$(1),L$(26),G$(1),B$(20),W$(3),T$(3),TOM$(1)
0220 TOM$(1 : 1)=" "
0230 NN=50; C=1
0240 PRINT CHR(12)
0250 FOR I=1 TO 20
0260 D$(I)="-"
0270 NEXT I
0280 M=0
0290 FOR I=1 TO 26
0300 N$(I)=""
0310 NEXT I
0320 FOR I=1 TO 144
0330 P$(I)=" "
0340 NEXT I
0350 FOR I=1 TO 144 STEP 12
0360 P$(I)="X"
0370 NEXT I
0380 FOR I=2 TO 7
0390 P$(I)="X"
0400 NEXT I
0410 P$(19)="X"
0420 IF C<NN THEN GO TO 0450
0430 PRINT "DU HAR GÆTTET ALLE ORDERNE"
0440 GO TO 2240
0450 RANDOMIZE 3
0460 Q=INT(NN*RND(0))+1
0470 IF U(Q)=1 THEN GO TO 0450
0480 U(Q)=1; C=C+1; T1=0
0490 PRINT CHR(6); CHR(125); CHR(103);
0500 PRINT "JEG GØR LIGE KLAR"
0510 RR=1
0520 PRINT CHR(6); CHR(96); CHR(99);
0530 EXEC SAMELINE
0540 FOR I=RR TO RR+11
0550 PRINT P$(I);
0560 NEXT I
0570 RR=RR+12
0580 IF RR<>145 THEN
0590 PRINT
0600 GO TO 0540
0610 ENDIF
0620 RESTORE
0630 FOR I=1 TO Q
0640 READ ORD$
0650 NEXT I
0660 ANTAL=0
0670 FOR I=1 TO 20
0680 BOGS$(1 : 1)=ORD$(I : 1)
0690 IF BOGS$=" " THEN EXIT
0700 L$(I : 1)=BOGS$(1 : 1)
0710 ANTAL=ANTAL+1
0720 NEXT I
0730 D$(ANTAL+1)=" "
0740 PRINT CHR(6); CHR(96); CHR(111);
0750 PRINT "HER ER DE BOGSTAVER DU HAR VALGT:"
0760 FOR I=1 TO 26
0770 PRINT N$(I);
0780 IF N$(I+1)="" THEN EXIT
0790 PRINT ",";
0800 NEXT I
0810 PRINT CHR(6); CHR(96); CHR(113);
0820 FOR I=1 TO ANTAL
0830 PRINT D$(I);
0840 NEXT I
0850 PRINT
0860 PRINT
0870 PRINT " "
0880 EXEC SAMELINE
0890 INPUT "HVAD ER DIT GÆT: ",G$(1 : 1)
0900 EXEC UPPERCASE(G$)
0910 Z=0; Q=3
0920 FOR I=1 TO 26
0930 IF N$(I)="" THEN
0940 Q=2
0950 ELSE
0960 IF G$=N$(I) THEN
0970 PRINT CHR(6); CHR(125); CHR(103);
0980 PRINT "DU HAR GÆTTET DETTE BOGSTAV FØR"
0990 Q=1
1000 ENDIF
1010 ENDIF
1020 IF Q<>3 THEN EXIT
1030 NEXT I
1040 IF Q=3 THEN GO TO 1070
1050 IF Q=2 THEN GO TO 1090
1060 IF Q=1 THEN GO TO 0740
1070 PRINT "PROGRAM FEJL -- START FORFRA"
1080 GO TO 2240
1090 N$(I)=G$(1 : 1)
1100 T1=T1+1
1110 FOR I=1 TO ANTAL
1120 IF L$(I : 1)=G$(1 : 1) THEN
1130 D$(I)=G$
1140 Z=Z+1
1150 ENDIF
1160 NEXT I
1170 PRINT CHR(6); CHR(96); CHR(96);
1180 PRINT " "
1190 PRINT " "
1200 IF Z=0 THEN GO TO 1530
1210 GO TO 1220
1220 FOR I=1 TO ANTAL+1
1230 IF D$(I)="-" THEN
1240 EXIT
1250 ELSE
1260 IF D$(I)=" " THEN
1270 GO TO 1500
1280 ENDIF
1290 ENDIF
1300 NEXT I
1310 PRINT CHR(6); CHR(125); CHR(103);
1320 PRINT " "
1330 PRINT CHR(6); CHR(96); CHR(113);
1340 FOR I=1 TO ANTAL
1350 PRINT D$(I);
1360 NEXT I
1370 PRINT
1380 PRINT
1390 INPUT "HVAD ER DIT GÆT PÅ HELE ORDET : ",B$
1400 EXEC UPPERCASE(B$)
1410 IF B$+TOM$=ORD$ THEN GO TO 1450
1420 PRINT CHR(6); CHR(125); CHR(103);
1430 PRINT "FORKERT. PRØV ET ANDET BOGSTAV"
1440 GO TO 0740
1450 PRINT "KORREKT !!! DET TOG DIG"; T1; "GÆT"
1460 INPUT "ØNSKER DU ET ANDET ORD(JA/NEJ)",W$
1470 IF W$="JA" OR W$="JA" THEN GO TO 0240
1480 PRINT "DET HAR VÆRET MORSOMT ! - FARVEL FOR NU -"
1490 GO TO 2240
1500 PRINT "DU FANDT ORDET----- ";
1510 PRINT ORD$
1520 GO TO 1460
1530 M=M+1
1540 PRINT
1550 PRINT CHR(6); CHR(96); CHR(96);
1560 PRINT "BEKLAGER DETTE BOGSTAV INDGÅR IKKE I ORDET"
1570 ON M GO TO 1580,1600,1620,1640,1660,1680,1700,1720,1740,1760
1580 PRINT "FØRST TEGNER VI HOVEDET"
1590 GO TO 1770
1600 PRINT "NU TEGNER VI KROPPEN"
1610 GO TO 1770
1620 PRINT "DET NÆSTE VI TEGNER ER EN ARM"
1630 GO TO 1770
1640 PRINT "NU ER DET TID FOR DEN ANDEN ARM"
1650 GO TO 1770
1660 PRINT "LAD OS NU TEGNE DET HØJRE BEN"
1670 GO TO 1770
1680 PRINT "DENNE GANG TEGNER VI DET VENSTRE BEN"
1690 GO TO 1770
1700 PRINT "NU SÆTTER VI DEN ENE HÅND PÅ"
1710 GO TO 1770
1720 PRINT "DET NÆSTE ER DEN ANDEN HÅND"
1730 GO TO 1770
1740 PRINT "NU TEGNER VI DEN ENE FOD"
1750 GO TO 1770
1760 PRINT "HER ER DEN ANDEN FOD -- DU ER HÆNGT --"
1770 ON M GO TO 1780,1810,1830,1850,1870,1890,1910,1930,1950,1970
1780 P$(30)="-"; P$(31)="-"; P$(32)="-"; P$(41)="("; P$(42)="."
1790 P$(44)="."; P$(45)=")"; P$(54)="-"; P$(55)="-"; P$(56)="-"
1800 GO TO 1980
1810 P$(67)="X"; P$(79)="X"; P$(91)="X"; P$(103)="X"
1820 GO TO 1980
1830 P$(39)="'"; P$(52)="'"; P$(65)="'"; P$(78)="'"
1840 GO TO 1980
1850 P$(47)="'"; P$(58)="'"; P$(69)="'"; P$(80)="'"
1860 GO TO 1980
1870 P$(114)="'"; P$(125)="'"
1880 GO TO 1980
1890 P$(116)="'"; P$(129)="'"
1900 GO TO 1980
1910 P$(27)="O"
1920 GO TO 1980
1930 P$(35)="O"
1940 GO TO 1980
1950 P$(136)="O"; P$(137)="O"
1960 GO TO 1980
1970 P$(141)="O"; P$(142)="O"
1980 R=0; RR=0
1990 FOR I=1 TO 3
2000 H$(I)=P$(I+R)+P$(I+1+R)+P$(I+2+R)+P$(I+3+R)
2010 R=R+3
2020 NEXT I
2030 PRINT H$(1)+H$(2)+H$(3)
2040 RR=RR+12; R=RR
2050 IF R<>144 THEN GO TO 1990
2060 PRINT CHR(6); CHR(125); CHR(103);
2070 PRINT " "
2080 IF M<>10 THEN GO TO 0740
2090 PRINT CHR(6); CHR(96); CHR(115);
2100 PRINT "BEKLAGER - DU TABTE - ORDET VAR ---"; ORD$; "---"
2110 PRINT "DET SVIPSEDE DENNE GANG GJORDE DET IKKE"
2120 GO TO 1460
2130 INPUT "TAST JA ELLER NEJ",T$
2140 IF T$="JA" OR T$="JA" THEN GO TO 0250
2150 DATA "FIN ","GIK ","SOL ","SNE ","LYS ","BIL ","TUD "
2160 DATA "FISK ","SLUT ","GRÆS ","PIBE ","KÆLK ","SNUE ","TABE "
2170 DATA "LAMPE ","HÆNGT ","RC700 ","GALGE ","BOMBE ","FLINT ","LIKØR "
2180 DATA "BLOMST ","SENNEP ","GARAGE ","POTENS ","GRATIS ","INDMAD "
2190 DATA "TELEFON ","RYGEOST ","TRAKTAT ","VIKLERS","XYLOFON ","YNDLING "
2200 DATA "SKÆRSILD ","ØRKESLØS ","VÆRTSHUS ","VILDMAND ","SVÆRVÆGT "
2210 DATA "FOTOGRAFI ","SENSATION ","ÆGTESTAND ","UNDERSKÅL ","TRÆDEPUDE "
2220 DATA "VIDTLØFTIG ","UNDERMÅLER ","TRYKKABINER ","INDKASSERE "
2230 DATA "TRANSMISSION ","ELEKTRICITET ","VIOLINBYGGER "
2240 STOP
2250 PROC SAMELINE
2260 PRINT CHR(13); CHR(26); CHR(11);
2270 ENDPROC
2280 PROC UPPERCASE(E)
2290 FOR TÆL=1 TO LEN(E$)
2300 IF E$(TÆL : 1)<=CHR(125) AND E$(TÆL : 1)=>CHR(97) THEN
2310 E$(TÆL : 1)=CHR(ORD(E$(TÆL : 1))-32)
2320 ENDIF
2330 NEXT TÆL
2340 ENDPROC UPPERCASE
2350 REM //----------------------------------------------//
«eof»