|
DataMuseum.dkPresents historical artifacts from the history of: RC4000/8000/9000 |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about RC4000/8000/9000 Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - metrics - download
Length: 6144 (0x1800)
Types: TextFile
Names: »bittxt«
└─⟦621cfb9a2⟧ Bits:30002817 RC8000 Dump tape fra HCØ. Detaljer om "HC8000" projekt.
└─⟦0364f57e3⟧
└─⟦this⟧ »bittxt«
└─⟦00964e8f7⟧ Bits:30007478 RC8000 Dump tape fra HCØ.
└─⟦b2ec5d50f⟧
└─⟦this⟧ »bittxt«
s. a4, b1, c2, d2 ;begin integer w0,w1,w2,bit,maske; comment
w. ; boolean mog0; comment
p. <:fpnames:> ; comment
k = h55 ; bit:= 25; comment
0 ; maske:= 0; comment
0 ; mog0:= false; comment
al w0 0 ; w0:= 0; comment
; comment
a0: jl. w3 h25.-2 ;igen: fpproc(25)inchar:(0,in,w2); comment
sn w2 0 ; if w2=0 then goto igen; comment
jl. a0. ; comment
sn w2 32 ; if w2=32 then goto igen; comment
jl. a0. ; comment
sn w2 25 ; if w2=25 then goto EM; comment
jl. b0. ; comment
sn w2 10 ; if w2=10 then goto NL; comment
jl. b1. ; comment
rl. w1 d0. ; w1:= bit; comment
al w1 x1 -1 ; w1:= w1-1; comment
sh w1 0 ; if w1<=0 then goto fejl; comment
jl. c0. ; comment
rs. w1 d0. ; bit:= w1; comment
al w1 0 ; w1:= 0; comment
sn w2 109 ; if w2=109 then goto enere; comment
jl. a1. ; comment
sn w2 48 ; if w2=48 then goto nuller; comment
jl. a2. ; comment
sn w2 49 ; if w2=49 then goto en; comment
jl. a3. ; comment
sn w2 46 ; if w2=46 then goto nul; comment
jl. a4. ; comment
; comment
c0: jl. w3 h25.-2 ;fejl: fpproc(25)inchar:(0,in,w2); comment
sn w2 10 ; if w2=10 then goto NL1; comment
jl. c1. ; comment
se w2 25 ; if w2<>25 then goto fejl; comment
jl. c0. ; comment
al w2 10 ; fpproc(26)outchar:(0,out,10); comment
jl. w3 h26.-2 ; comment
c1: al w2 63 ;NL1: fpproc(26)outchar:(0,out,63); comment
jl. w3 h26.-2 ; comment
al w2 10 ; fpproc(26)outchar:(0,out,10); comment
jl. w3 h33.-2 ; comment
al w2 1 ; fpproc(7)endprogram:(0,0,1); comment
jl. h7. ; comment
; comment
b0: al w2 10 ;EM: fpproc(26)outchar:(0,out,10); comment
jl. w3 h26.-2 ; comment
b1: jl. w3 h32.-2 ;NL: fpproc(32,w0,out,-8257528); comment
1<23+32<12+8 ; comment
al w2 10 ; fpproc(26)outchar:(0,out,10); comment
jl. w3 h33.-2 ; comment
al w2 0 ; fpproc(7)endprogram:(0,0,0); comment
jl. h7. ; comment
; comment
a1: al w1 -1 ;enere:w1:= -1; comment
a2: rl. w2 d1. ;nuller: ;comment
se w2 0 ; if mog0 then goto fejl; comment
jl. c0. ; comment
ls. w0 ( d0.) ; w0:= w0 shift bit; comment
am. ( d0.) ; comment
ls w1 -24 ; w1:= w1 shift(bit-24); comment
lo w0 2 ; w0:= logor(w0,w1); comment
al w2 -1 ; w2:= -1; comment
rs. w2 d1. ; mog0:= true; comment
am. ( d0.) ; comment
ls w2 -1 ; w2:= w2 shift(bit-1); comment
rs. w2 d2. ; maske:= w2; comment
jl. a0. ; goto igen; comment
; comment
a3: al w1 1 ;en: w1:= 1; comment
a4: rl w2 0 ;nul: w2:= w0; comment
la. w2 d2. ; w2:= logand(w2,maske); comment
ls w0 1 ; w0:= w0 shift 1; comment
lo w0 2 ; w0:= logor(w0,w1); comment
al w1 -1 ; w1:= -1; comment
lx. w1 d2. ; w1:= exor(w1,maske); comment
la w0 2 ; w0:= logand(w0,w1); comment
lo w0 4 ; w0:= logor(w0,w2); comment
jl. a0. ; goto igen ;comment
; comment
d0: 25 ; comment
d1: 0 ; comment
d2: 0 ; comment
e. e. ;end
▶EOF◀