DataMuseum.dk

top - metrics - download

    Length: 2304 (0x900)
    Types: TextFile
    Names: »swval«

└─⟦00964e8f7⟧ Bits:30007478 RC8000 Dump tape fra HCØ.
    └─⟦b2ec5d50f⟧ 
        └─⟦this⟧ »swval« 

TextFile

external procedure writeenvval(out,envval,owner);
integer array  envval;
zone  out;
string  owner;
begin
  comment  Proceduren udskriver de 6561 envval-værdier
          for ejeren, dvs. den interne spiller.
          For hver værdi vises de 8 omegnsfelter, omegnens
          midterfelt, samt totval , som er
          <trusselsværdi,strategisk værdi>;

  boolean field  bf,envno;
  integer  page,line,e,i,j,k,m;
  integer array  stone(-4:4);
  real  plname;

  plname:= real owner;
  for page:= 1 step 1 until 37 do
  begin
    write(out,<:<12>envval for :>,string plname,<: vægtblok = :>);
    for bf:= -1,-2,-3,-4,-5 do
    write(out,false add (envval.bf extract 12 +48),1,
    false add 32,1);
    write(out,<:   side :>,<<dd>,page,<:<10><10>:>);
    for i:= 1,2,3 do
    write(out,<: env ....X.... val     :>);
    write(out,<:<10>:>);
    for line:= 0 step 1 until 59 do
    begin
      write(out,<:<10>:>);
      for e:= (page-1)*180, e+60, e+60 do
      if e+line < 6561 then
      begin
        envno:= m:= e+line;
        write(out,<<dddd>,envno,<: :>);
        for i:= 1,2,3,4,5,6,7,8 do
        begin
          j:= case i of (2187,729,243,81,27,9,3,1);
          k:= case i of (-4,4,-3,3,-2,2,-1,1);
          stone(k):= m//j;
          m:= m-j*stone(k)
        end i;
        stone(0):= 3;
        for k:= -4 step 1 until 4 do
        write(out,
        false add (case stone(k)+1 of (46,120,111,88)),1);
        write(out,<<ddd>,envval.envno extract 11 shift (-7),<:,:>,
        <<dd>,envval.envno extract 7,<:   :>)
      end envno
    end line
  end page
end;
end
▶EOF◀