DataMuseum.dk

top - metrics - download

    Length: 3840 (0xf00)
    Types: TextFile
    Names: »stdmcltxt«, »stdmcltxt   «

└─⟦9ccaf6601⟧ Bits:30008165 Bånd med SW8000 kildetekst/release værktøjer
    └─⟦39138f30b⟧ 
        └─⟦this⟧ »stdmcltxt   « 
└─⟦9ccaf6601⟧ Bits:30008165 Bånd med SW8000 kildetekst/release værktøjer
    └─⟦39138f30b⟧ 
        └─⟦f2bd3e7b2⟧ »filebintas  « 
            └─⟦f4c94b1e2⟧ 
                └─⟦this⟧ »stdmcltxt« 

TextFile

-- hgo/ep  89.09.01  rel. 2.1   RC8000/RC9000
--
-- Eksempel på mcl program til brug ved udviklingsopgaver
--
at 0 0 erase -- Slet skærmen
let n=<>     -- Fjern blanke efter brugernavn i U
let a=<>     -- Dette gøres kun af hensyn til udskrift !!!
while a!=< > and u!=<> do
  let n=<&n&a>
  let a=u(1 1)
  let u=u(2 12)
endwhile  
if a!=< > then let n=<&n&a> endif
let u=n
while <>=<> do
-- Udskriv menu'en
menu 25 3 <   --- Vælg venligst et af følgende punkter ---  > 
text <>
text<>
point <Eget job under s>
  at 43 write <VENT>
  attention <s> r  -- Send attention til s via sessions-terminal
    send <job &u ^j> -- Besvar input fra s
    get 13 a    -- Hent svar fra s
    while a=<> do
      send <^j>
      get 13 a
    endwhile
    select a of -- Test det
      case <ready>
        at 0 0 erase write <Job &u startet> nl
        direct a
      case <process exist>
        at 0 0 erase write <Job &u eksisterer i forvejen>
        loop 
      otherwise
        let r=a
        let a=<s>
    endselect
  endattention
  at 0 0 erase
  write <Job &u stoppet med resultat &r (retur parameter= &a)> nl
text <>
point <Job under s>
  at 37 read <med navn > 11 r 
  let n=<>  
  let a=<>  
  while a!=< > and r!=<> do
    let n=<&n&a>
    let a=r(1 1)
    let r=r(2 12)
  endwhile  
  if n!=<> then
    convert n   -- konverter navn til små bogstaver
    attention <s> r
      send <job &n ^j>
      get 20 a    -- læs svar fra s
      while a=<> do
        send <^j>
        get 20 a
      endwhile
      if a=<ready> then
        at 0 0 erase write <Job &n startet> nl
        direct a
      else  
        let r=a
        let a=<s>
      endif 
    endattention
    at 0 0 erase
    write <Job &n stoppet med resultat &r (retur parameter= &a)> nl
  endif     
text <>
point <Attention til proces>
  at 46 read <med navn > 11 r 
  let n=<>  
  let a=<>  
  while a!=< > and r!=<> do 
    let n=<&n&a>
    let a=r(1 1)
    let r=r(2 12)
  endwhile  
  if n!=<> then
    convert n
    attention n r
      at 0 0 erase write <to &n > nl
      direct a
    endattention
    at 0 0 erase
    if r!=<ok> then
      write <Fejl: &r> nl
    endif
  endif     
text <>
point <S kommunikation>
    attention <s> r
      at 0 0 erase write <to s> nl
      direct a
    endattention
    at 0 0 erase
    if r!=<ok> then
      write <S retur = &r, Stop retur = &a> nl
    endif
text <>
point <Operatør kommunikation>
    attention <tas> r  -- send attention til tas selv
      at 0 0 erase
      direct a
    endattention
    at 0 0 erase
    if r!=<ok> then
      write <Operatør ikke klar> nl -- ikke flere ledige 
    endif
text <>
point <MCL program udførelse>
  at 48 read <navn > 11 r 
  let n=<>
  let a=<>
  while a!=< > and r!=<> do
    let n=<&n&a>
    let a=r(1 1)
    let r=r(2 12)
  endwhile
  if n!=<> then
    convert n
    execute n r  -- start nyt mcl-program
    if r=<unknown> or r=<resources> then
      at 0 0 erase 
      write<Kan ikke starte &n  (&r)>
    else
      at 0 0 erase write <Retur = &r> nl
    endif
    output off
    echo off
  endif
text <    (eget MCL program)> 
---- tekst hørende til forrige point !!
text <>
point <Log ud (afmeld)>
    at 0 0 erase
    exit <Afsluttet>
text <>
text <>
text <                           std menu 89.09.01 rel. 2.1>
endmenu
endwhile
-- MCL eksempel slut
▶EOF◀