DataMuseum.dk

top - metrics - download

    Length: 1536 (0x600)
    Types: TextFile
    Names: »tsymdet«

└─⟦00964e8f7⟧ Bits:30007478 RC8000 Dump tape fra HCØ.
    └─⟦b2ec5d50f⟧ 
        └─⟦09b4e9619⟧ »thcømat« 
            └─⟦this⟧ 

TextFile

\f


message symdet

symdet=algol message.no
symdet                           rene moss  JSR/11-10-73
external
boolean procedure symdet(n,a,d1,d2);
value n; integer n,d2; real d1; array a;
begin
  integer i,i1,j,k,db,ti,tj;
  real x,y,z,da;
  da:=1; db:=ti:=0;
  for i:=1 step 1 until n do 
  begin
    i1:=i-1;
    tj:=0;
    for j:=1 step 1 until i1 do 
    begin
      x:=a(ti+j);
      for k:=j-1 step -1 until 1 do x:= x-a(ti+k)*a(tj+k);
      a(ti+j):=x;
      tj:=tj+j 
    end;
    x:=a(ti+i);
    for k:=i-1 step -1 until 1 do 
    begin
      y:=a(ti+k);
      z:=a(ti+k):=y*a(k*(k+1)/2);
      x:=x-y*z 
    end;
    da:=da*x;
    if x=0 then 
    begin
      db:=0;
      symdet:=false;
      goto S 
    end;
    j:=da extract 12;
    da:=(da shift (-12)) shift 12;
    if j>2048 or j=2048 then j:=j-4096;
    db:=db +j;
    ti:=ti+i;
    a(ti):=1/x
  end;
  symdet:=true;
S:
  d1:=da;
  d2:=db
end symdet
; end
▶EOF◀