DataMuseum.dk

top - metrics - download

    Length: 3072 (0xc00)
    Types: TextFile
    Names: »kkbud«

└─⟦621cfb9a2⟧ Bits:30002817 RC8000 Dump tape fra HCØ.  Detaljer om "HC8000" projekt.
    └─⟦0364f57e3⟧ 
        └─⟦508e019d6⟧ »kkfiler« 
            └─⟦this⟧ 
└─⟦00964e8f7⟧ Bits:30007478 RC8000 Dump tape fra HCØ.
    └─⟦b2ec5d50f⟧ 
        └─⟦8748ba386⟧ »kkfiler« 
            └─⟦this⟧ 

TextFile

(u=algol
u)
begin
  integer i,j,k,b,antal,type,nr,inds,år,total;
  read(in,antal,år,inds);
  begin
    integer array m(1:antal+3,1:12);
    real array kn(1:antal+3,1:4),t(1:4);
    read(in,b); comment starts;
    m(antal+2,1):=b;
    kn(antal+2,1):=real(<:glsal:>);
    kn(antal+3,1):=real(<:nysal:>);
    kn(antal+1,1):=real(<:ialt:>);
    total:=0;

    for i:=1 step 1 until antal do
    begin
      j:=1;
      readstring(in,t,j);
      for j:=1 step 1 until 4 do kn(i,j):=t(j);
      read(in,type);
      if type=0 then
      begin
        read(in,b);
        for j:=1 step 1 until 12 do m(i,j):=b;
      end else if type=13 then
      begin
        for j:=1 step 1 until 12 do read(in,m(i,j));
      end else
      begin
        read(in,b);
        for j:=1 step 1 until 12 do m(i,j):=0;
        for j:=1 step 1 until type do
        begin
          read(in,nr);
          m(i,nr):=b;
        end;
      end;
    end;
    for j:=1 step 1 until 12 do
    begin
      m(antal+1,j):=0;
      for i:=1 step 1 until antal do
      m(antal+1,j):=m(antal+1,j)+m(i,j);
      m(antal+3,j):=m(antal+2,j)+inds-m(antal+1,j);
      if j<12 then m(antal+2,j+1):=m(antal+3,j);
    end;
    write(out,<:<12>:>,<<ddd>,år,false add 32,6);
    for j:=1 step 1 until 12 do
    write(out,<: :>,(case j of (<:jan:>,<:feb:>,<:mar:>,<:apr:>,<:maj:>,<:jun:>,<:jul:>,<:aug:>,<:sep:>,<:okt:>,<:nov:>,<:dec:>)),<:  :>);
    for i:=1 step 1 until antal+3 do
    begin
      outchar(out,10);
      for j:=1 step 1 until 4 do t(j):=kn(i,j);
      j:=1;
      k:=write(out,string t(increase(j)));
      write(out,false add 32,(8-k));
      for j:=1 step 1 until 12 do
      write(out,<<-bdddd>,m(i,j));
    end;
    for j:=1 step 1 until 12 do total:=total+m(antal+1,j);
    write(out,<:<10>Årsforbrug  :>,total);
    
  end;
end;
29 1982 13100
-5800
KD 2 4563 6 12
BRF 2 5333 3 9
R-HESS 2 7377 6 12
DJØF 2 7515 3 9
ING-PK 2 12674 6 12
AVIS 1 980 9
NESA 4 890 1 4 7 10
KTAS 4 450 3 6 9 12
Bilfor 4 348 3 6 9 12
TV-lic 2 500 4 10
Husfor 1 792 4
ul-for 1 160 10
an-for 1 700 10
FDM 1 300 2
Vægtafg 2 534 2 10
Falck 1 260 12
ej-skat 4 1105 2 5 8 11
gr-ejer 4 175 3 6 9 12
varme 13 830 830 830 830 0 0 830 830 830 830 830 830
vand 1 250 4
Børneh 0 642
RSLF 2 850 6 12
GL 13 500 500 500 500 500 0 0 400 400 400 400 400
SU1 4 2288 1 4 7 10
SU2 2 500 1 7
KBH1 0 750
KBH2 0 750
Billån 0 1040
al-kasse 4 300 3 6 9 12
▶EOF◀