DataMuseum.dk

top - metrics - download

    Length: 3072 (0xc00)
    Types: TextFile
    Names: »instermtxt«

└─⟦aa55fa693⟧ Bits:30007479 SW8110/1 TAS/SOS/PRIMO Rel 2.3
    └─⟦78f95c038⟧ 
        └─⟦06821cd16⟧ 
            └─⟦this⟧ »instermtxt« 

TextFile

-- @(#)instermtxt	1.3  (RC International)  10/1/90
-- ep 90.10.01 release 2.3   RC8000/RC9000
--
-- MCL program til installation af ny terminal
-- Programmet startes ved tilmelding som bruger 'newterm'
-- Dette kan kun gøres fra terminaler der ikke er kendt af Tas
-- og som derfor benyttes som default terminal.
--
output off
echo off
if u!=<newterm> then    -- Test om det er bruger 'newterm'
  exit <Illegal bruger af installerings program>
endif
while <>=<> do
  nl nl nl
  write <*** Installering af ny terminal, rel. 2.3 (90.10.01) ***>
  nl
  write <------ Vælg terminaltype -----> nl nl
  write <1  Hard copy terminal> nl
  write <2  Ansi på 3600 frontend> nl
  write <3  Ansi på CSP> nl
  write <4  RC822 (RC851) emulator på 3600 frontend> nl
  write <5  RC822 (RC851) emulator på CSP> nl
  write <6  > nl
  write <7  > nl
  write <8  RC45  ansi på 3600 frontend> nl
  write <9  RC45  ansi på CSP> nl
  write <10 RC822 på 3600 frontend> nl
  write <11 RC822 på CSP> nl
  write <12 > nl
  write <13 > nl
  read <Indtast nummeret på terminalens type: > a
  nl
  read <Indtast gruppenummer for terminal (1 til 95): > b
  if b=<  > or b=<> then
    loop
  endif
  nl
  read <Bypass af terminal ? (j/n) > h
  nl
  read <Indtast evt. beskrivelse af terminal: > c
  attention <s> r   -- Send attention til s
  send <new instermproc base 0 0 buf 10 area 10 size 100000 prog fp run>
  get 20 q           -- Læs svar fra s
  while q=<> do
    send <^j>
    get 20 q
  endwhile
  if q=<ready> then -- Hvis svar lig 'ready' så
    send <do z3.hn.y3.42.in.fp w3.hn.x3.2.in.2.in.z3, ^j>
    send <   x1.104.le.12 send message wait answer, ^j>
    send <   z0.x1.4.in.2 write y0.name.8  ^j>
    get 40 p
    while p(1 1)!=<+> do
      let p=p(2 40)
    endwhile
    let p=p(5 11)
    write <Indsætter terminal &p > nl
    send <settascat ^j>   -- Kald programmet settascat
    send <terminal &p^j>  -- Angiv terminalnavn
    send <termtype &a^j>  -- Angiv terminaltype
    send <termgroup &b^j> -- Angiv terminal gruppe
    if h=<j> then send <bypass> endif
    send <freetext &c^j>  -- Angiv evt. supplerende tekst
    send <end ^j>         -- Opdatering slut 
    nl
    get 80 c              -- Hent svar fra settascat
    write c               -- Udskriv dette
    send<do x3.s x1.2.le.12 send message^J>         -- FINIS til fp
    get 1 w               -- Vent på fp afslutning
  endif
endattention  -- Nedlæg sessions-terminal
if q!=<ready> then -- Test resultat af attention m.m
  nl
  write<Fejl, kan ikke starte s-proces til brug for installation; &r,&q> nl
  read <Tast 'return' > r
endif
if r!=<ok> and r!=<cmcl> then -- Test resultat af insert
  nl
  write<Fejl, Opdateringer er ikke afsluttet korrekt; &r,&q> nl
  read <Tast 'return' > r
endif
exit <Terminal: &p Installering afsluttet> -- Afslut program
endwhile
▶EOF◀