|
DataMuseum.dkPresents historical artifacts from the history of: RC4000/8000/9000 |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about RC4000/8000/9000 Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - metrics - download
Length: 2304 (0x900)
Types: TextFile
Names: »tdisplay«
└─⟦667bb35d6⟧ Bits:30007480 RC8000 Dump tape fra HCØ.
└─⟦4334b4c0b⟧
└─⟦this⟧ »tdisplay«
begin
integer i,parent,lgd;
zone process (1,1,stderror);
integer array ia (1:2),process_ia(1:51);
boolean første;
array fpname (1:2);
array field af;
long array field laf;
real runtime, start_time, wait_time, time;
af:=laf:=0;
i:=system(4,1,fpname);
if i = 0 then movestring(fpname,1,<:sos:>);
open(process,0,fpname,0) ;
parent:=monitor(4,process,i,ia);
if parent=0 then write(out,<:<10>:>,fpname.laf,<: ukendt:>) else
begin
system(5)move_core:(78,ia);
lgd:=(ia(2)-ia(1))/2;
begin
integer array int_name_tabel (1:lgd);
system(5)move_core:(ia(1),int_name_tabel);
første:=true;
for i:=1 step 1 until lgd do
begin
system(5)move_core:(int_name_tabel(i)+2,process_ia);
if process_ia(25)=parent then
begin
if første then
write(out,<:<10>display af :>,fpname.laf,
<: den :>,<<dd dd dd>,systime(5,0,time),
<: kl.:>,<<dd.dd>,time/10000,
false add 10,1,false add 32,44,<:claim::>,
<:<10>navn start rørt cpu size buf area:>);
første:=false;
runtime:=process_ia.laf(14)/10000;
time:=process_ia.laf(15)/10000;
systime(4,time,start_time);
time:=process_ia.laf(16)/10000;
systime(4,time,wait_time);
outtext(out,-12,process_ia.af,1);
write(out,<< zd.dd>,start_time/10000,
wait_time/10000,
<<dddddd.d>,runtime,
<< dddddd>,process_ia(12)-process_ia(11),
<< ddd>,process_ia(13) shift (-12),
process_ia(13) extract 12);
end =parent;
end i;
if første then write(out,<:<10>:>,fpname.laf,<: har ingen børn:>);
end lgd;
write(out,false add 10,2);
end parent<>0;
trapmode:= 1 shift 10;
end ;
▶EOF◀