DataMuseum.dk

top - metrics - download

    Length: 3072 (0xc00)
    Types: TextFile
    Names: »operamcltxt«, »operamcltxt «

└─⟦9ccaf6601⟧ Bits:30008165 Bånd med SW8000 kildetekst/release værktøjer
    └─⟦39138f30b⟧ 
        └─⟦this⟧ »operamcltxt « 
└─⟦9ccaf6601⟧ Bits:30008165 Bånd med SW8000 kildetekst/release værktøjer
    └─⟦39138f30b⟧ 
        └─⟦f2bd3e7b2⟧ »filebintas  « 
            └─⟦f4c94b1e2⟧ 
                └─⟦this⟧ »operamcltxt« 

TextFile

-- ep 89.09.01 release 2.1     RC8000/RC9000
--
-- Standard MCL program til brug for operatør
-- og udvikling.
--
at 0 0 erase -- Slet skærmen

while <>=<> do
-- Udskriv menu'en
menu 25 1 <------ Standard operatør og udviklings menu ------> 
text <>
point <Job under s>
  at 37 read <med navn > 11 r 
  let n=<>  
  let a=<>  
  while a!=< > and r!=<> do
    let n=<&n&a>
    let a=r(1 1)
    let r=r(2 12)
  endwhile  
  if a!=< > then let n=<&n&a> endif
  if n!=<> then
    convert n
    attention <s> r
      send <job &n ^j>
      get 13 a
      while a=<> do
        send <^j>
        get 13 a
      endwhile
      if a=<ready> then
        at 0 0 erase write <Job &n startet> nl
        direct a
      else  
        let r=a
        let a=<s>
      endif 
    endattention
    at 0 0 erase
    write <Job &n stoppet med resultat &r (retur parameter= &a)> nl
  endif     
text <>
point <Attention til proces>
  at 46 read <med navn > 11 r 
  let n=<>  
  let a=<>  
  while a!=< > and r!=<> do
    let n=<&n&a>
    let a=r(1 1)
    let r=r(2 12)
  endwhile  
  if n!=<> then
    convert n
    attention n r
      at 0 0 erase write <to &n > nl
      direct a
    endattention
    at 0 0 erase
    if r!=<ok> then
      write <Fejl: &r> nl
    endif
  endif     
text <>
point <S kommunikation>
    attention <s> r
      at 0 0 erase write <to s> nl
      direct a
    endattention
    at 0 0 erase
    if r!=<ok> then
      write <S retur = &r, Stop retur = &a> nl
    endif
text <>
point <Operatør kommunikation (Tas)>
    attention <tas> r
      at 0 0 erase
      direct a
    endattention
    at 0 0 erase
    if r!=<ok> then
      write <Operatør ikke klar> nl
    endif
text <>
point <MCL program udførelse>
  at 48 read <navn > 11 r 
  let n=<>
  let a=<>
  while a!=< > and r!=<> do
    let n=<&n&a>
    let a=r(1 1)
    let r=r(2 12)
  endwhile
  if n!=<> then
    convert n
    execute n r
    at 0 0 erase 
    if r=<unknown> or r=<resources> then
      write<Kan ikke starte &n  (&r)>
    else
      at 0 0 erase write <Retur = &r> nl
    endif
    output off
    echo off
  endif
text <    (eget MCL program)>
text <>
point <Primo >
  execute <primomcl> r
  if r=<unknown> or r=<resources> then
    at 0 0 erase 
    write<Kan ikke starte primo operatør menu (&r)>
  endif
  output off
  echo off
text <>
point <Bruger opdatering>
  let  v=<bruger>
  execute <upcatmcl> v
  at 0 0 write v
text <>
point <Frigiv terminal>
  let v=<terminal>
  execute <upcatmcl> v
  at 0 0 write v
text <>
point <Ekskluder terminal>
  let v=<fjern>
  execute <upcatmcl> v
  at 0 0 write v
text <>
point <Log ud (afmeld)>
    exit <Afsluttet>
text <                    operator menu 89.09.01 rel. 2.1>
endmenu
endwhile
▶EOF◀