DataMuseum.dk

top - metrics - download

    Length: 4608 (0x1200)
    Types: TextFile
    Names: »øv6«

└─⟦00964e8f7⟧ Bits:30007478 RC8000 Dump tape fra HCØ.
    └─⟦b2ec5d50f⟧ 
        └─⟦this⟧ »øv6« 

TextFile

program til algolkursus, udplotning af titrerdata.
29-04-1980 OJH/RM
begin
integer i,j,k,res;
real norm,equi,dvol,t,phmin,phmax,vmin,vmax;
boolean first, up;
array bs,bt(1:2);
phmin:=0; phmax:=12;
first:=true;
reads(<:plotter:>,bt);
j:=(if bt(1)= real(<:calin:> add 99) then 2 else 0);
i:=1; setplotname(string bt(increase(i)),j);
plotform(2,5,0);
REP:
reads(<:dataarea:>,bs);
stackcuri;
if  connectcuri(bs) <>0 then
begin
  unstackcuri;
  write(out,<:no connect:>);
  goto REP
end;
for i:=1 step 1 until 5 do
  for j:=j while readchar(in,k)<>8,j do outchar(out,k);
outend(10);
read(in,dvol,norm,equi,res);
begin
  array A(1:res);
  i:=read(in,A);
  unstackcuri;
  if i<res then write(out,<:only :>,<<d>,i,<: data < :>,res)
  else
  begin
    if first then
    begin
      vmin:=0; vmax:=res*dvol;
      if dvol<0 then begin vmin:=vmax; vmax:=0 end;
      plotautcoor(vmin,vmax,phmin,phmax);
      first:=false;
    end;
    up:=true; penup;
    for i:=1 step 1 until res do
    begin
      t:=A(i);
      if t>0 then
      begin
        plotmove(i*dvol,t);
        if up then begin up:=false; pendown end;
      end
      else
      if -,up then begin up:=true; penup end
    end for i;
    if -,up then penup;
    plotend;
    end dataplot;
  if readb(<:more:>) then goto REP
end end
algol6 kursus ex6n1txt osmotiske data ( v4n2 udvidet med plot)
29-04-1980 RM
begin
  integer n,i;
  real sx,sy,sxx,sxy,syy,q,a,b,sa,sb,RT,xmax,ymax;
  n:=readi(<:number of datapoints:>);
  begin
    real array X,Y(1:n);
    RT:=8.314'7*298;
    write(out,<:indlæs koncentration(g/ml),osmotisk-tryk/konc.():>);
    outend(10);
    for i:= 1 step 1 until n do read(in,X(i),Y(i));
    sx:= sy:= sxx:= sxy:= syy:= 0;
    for i:= 1 step 1 until n do
    begin
      sx:= sx+X(i);
      sy:= sy+Y(i);
      sxx:= sxx+X(i)*X(i);
      sxy:= sxy+X(i)*Y(i);
      syy:= syy+Y(i)*Y(i);
    end;
    sx:= sx/n; sy:= sy/n;
    sxx:= sxx-n*sx*sx;
    sxy:= sxy-n*sx*sy;
    syy:= syy-n*sy*sy;
    q:= syy-sxy*sxy/sxx;
    a:= sxy/sxx; sa:= sqrt(q/(n-2)/sxx);
    b:= -a*sx+sy; sb:= sqrt(q/(n-2)*(1/n+sx*sx/sxx));
    write(out,<:<10>middelfejl på Yi: :>,<<d.d'+d>,sqrt(q/(n-2)),
         <:<10>den fittede linie har<10>hældning:    :>,<<ddd.d'+d>,a,
         <: += :>,<<d.d'+d>,sa,<:<10>akseskæring: :>,<<ddd.d'+d>,b,
         <: +- :>,<<d.d'+d>,sb);
    write(out,<:<10><10>Molekylvægten: :>,<<dd ddd ddd>,RT/b,
         <: +- :>,RT/b/b*sb);
  setplotname(<:tek4006a:>,0);
  plotform(2,5,0);
  xmax:=X(n); ymax:=Y(1);
  for i:=2 step 1 until n do begin if Y(i)>ymax then ymax:=Y(i) end;
  plotautcoor(0,xmax,0,ymax);
  plotline(0,b,xmax,b+a*xmax);
  for i:=1 step 1 until n do plotpoint(X(i),Y(i),2);
end end
polynomiefit af kompressibilitets data.
oj 28-04-1980
begin
real t,y;
integer i,n,j;
array bs(1:2),C,S(0:3);
real procedure trykrmf(x);
  value x; real x;
  trykrmf:=C(0)+(C(1)+(C(2)+C(3)*x)*x)*x;
setplotname(<:houstona:>,0);
plotform(2,5,0);
plotautcoor(0,1100,.5,3.0);
for j:=1,j+1 while readb(<:more:>) do
begin
  reads(<:dataarea:>,bs);
  stackcuri;
  connectcuri(bs);
  read(in,n);
  begin
    real array p,pV(1:n);
    for i:=1 step 1 until n do read(in,p(i),pV(i));
    unstackcuri;
    polfit(n,1.0,p(n),pV(n),C,S,3);
    for i:=0 step 1 until 3 do
      write(out,<:<10>C(:>,<<d>,i,<:) = :>,
           <<-d.ddd'+ddd>,C(i),<: +-:>,<<-d.ddd'+ddd>,S(i));
    write(out,nl,3,<:tryk:>,sp,10,<:pV:>);
    for t:=100 step 10 until 200 do 
      write(out,nl,1,<<dddd>,t,sp,10,<<d.ddd>,trykrmf(t));
    plotgraph(y,C(0)+(C(1)+(C(2)+C(3)*y)*y)*y,0,1100,1.0);
    for i:=1 step 1 until n do plotpoint(p(i),pV(i),j);
    plotend;
  end array;
end j;
end
Bindingsgraden af ilt til hemoglobin plottet mod ilttrykket
jm 28-04-1980 
begin
real x,K1,K2,K3,K4,K;
real procedure gamma(x); 
   value x; real x;
   gamma:=(K1*x+2*K1*K2*x**2+3*K1*K2*K3*x**3+4*K1*K2*K3*K4*x**4)/
          (1+K1*x+K1*K2*x**2+K1*K2*K3*x**3+K1*K2*K3*K4*x**4)/4;
K1:=0.096;K2:=0.104;K3:=0.335;K4:=0.926;
setplotname(<:houstona:>,0);
plotform(2,5,0);
plotautcoor(0,200,0,1);
plotgraph(x,gamma(x),0,200,5.0);
K:=(K1*K2*K3*K4)**0.25;
K1:=4*K;K2:=3/2*K;K3:=2/3*K;K4:=0.25*K;
setmask(0.5,0.5,0.5);
plotgraph(x,gamma(x),0,200,5.0);
end
▶EOF◀