DataMuseum.dk

top - metrics - download

    Length: 3072 (0xc00)
    Types: TextFile
    Names: »primomcltxt«, »primomcltxt «

└─⟦9ccaf6601⟧ Bits:30008165 Bånd med SW8000 kildetekst/release værktøjer
    └─⟦39138f30b⟧ 
        └─⟦this⟧ »primomcltxt « 
└─⟦9ccaf6601⟧ Bits:30008165 Bånd med SW8000 kildetekst/release værktøjer
    └─⟦39138f30b⟧ 
        └─⟦f2bd3e7b2⟧ »filebintas  « 
            └─⟦f4c94b1e2⟧ 
                └─⟦this⟧ »primomcltxt« 

TextFile

-- ep 89.09.01  release 2.1   RC8000/RC9000
--
echo on
let d = <>
let o = <display ^j>

while <>=<> do
at 0 0 erase

menu 15 4 <--- vælg device --->
  text <>

  -- for device specificering se venligst i: 
  -- Primo Users Guide/Reference Manual/Installation Guide
  -- RCSL 31-D688   page 47 and 48

  point <1 system printer - printer ->
    let d = <printer>

  point <2 angiv: process ell. device.hostno.hostid>
    at 0 20
    erase read <printer ? >  d

  --  Valg af ny printer kan indsættes i menuen med følgende point
  --  printeren er tilsluttet hostid  5711 med subhost devno 21
  --  point <3 remote printer - ^printer.21.5711
  --  let d = <@printer.21.5711>


  point <q returner>
    exit <signoff>
  text <>
  text <>
  text <>
  text <>
  text <>
  text <>
  text <>
  text <>
  text <>
  text <>
  text <>
  text <>
  text <>
  text <                                  primo menu 89.09.01  rel 2.1>

endmenu

  while d != <> do

    menu 10 4 <--- vælg kommando --->
    text <>

      point <a gentag kommando>
        let f = o
      point <b stop device - før kill,repeat,skip,suspend og route>
        let f = <stop &d ^j>
      point <c start device>
        let f = <start &d ^j>
      point <d display>
        let f = <display ^j>
      point <e request>
        let f = <request &d ^j>
      point <f kill af transport - husk stop>
        let f = <kill &d ^j>
      point <g repeat - søg sider tilbage - husk stop>
        at 0 23
        read <gentag antal sider ? >  e
        let f = <repeat &d &e^j>
      point <h skip - søg sider frem - husk stop>
        at 0 23
        read <skip antal sider ? >  e
        let f = <skip &d &e^j>
      point <i suspend - stil udskrift i bero - husk stop>
        let f = <suspend &d ^j>
      point <j route - send udskrift til anden printer - husk stop og suspend>
        at 0 23
        read <route til ? >  e
        let f = <route &d &e^j>
      point <k select - vælg papir type/prioritet>
        at 0 23
        read <specification ? > e
        let f = <select &d &e^j>
        text <         - papir type : group.queue>
        text <         - prioritet  : first/ last/ next/ previous/ suspend>
      point <l drain - stop printer når transport er færdig>
        let f = <drain &d ^j>
      point <m vælg en anden printer>
        let d = <>
        loop
      point <n definer egen kommando>
        at 0 23
        read <kommando ? >  e
        let f = <&e ^j>
      point <q returner>
        exit <signoff>
    endmenu

    if f != <> then
      at 0 0 erase
      attention <primo> r
        send f
        direct p
      endattention
      if r!=<ok> then
        select r of
        case <unknown>
          write <Primo er ikke startet>
        case <timeout>
          write <Primo svarer ikke>
        case <resource>
          write <Midlertidigt ingen adgang til primo>
        otherwise
          write <Forbindelse til primo afbrudt !>
        endselect
      endif
    endif

    let o = f
    let f = <>
  

  endwhile


endwhile
▶EOF◀