DataMuseum.dk

top - metrics - download

    Length: 2304 (0x900)
    Types: TextFile
    Names: »tsubmit«

└─⟦00964e8f7⟧ Bits:30007478 RC8000 Dump tape fra HCØ.
    └─⟦b2ec5d50f⟧ 
        └─⟦0b817e319⟧ »ctramos« 
            └─⟦this⟧ 

TextFile

submit=set 40
scope user submit
;global submit
submit=algol connect.no
81-10-29
Anders Lindgård
begin
integer i,res,c,char,exm;
array FP,IN,OUT,P,LP(1:3);
integer array field pda;
array field name;
integer array core(1:1);

procedure submit(job);
array job;
begin
integer i,res;
long array field f;
integer array M,A(1:8);
array field name;
f:=0;
M(1):=12 shift 12;
name:=2;
M.name(1):=real <:job:>;
name:=4;
M.name(1):=LP(1);
name:=8;
for i:=1,2 do M.name(i):=job(i);
res:=wait_answer(send_message(P,M),A);
if res <> 1 then
begin
  write(out,"nl",1,true,12,job.f,true,12,P.f,
        case res-1 of(<: rejected:>,
          <: unintelligible:>,
          <: does not exist:>));
end else
if A(1)=0 then
begin
  write(out,"nl",1,true,12,job.f,<< dddddd>,A(2) <*job number*>);
end else
begin
  write(out,"nl",1,true,12,job.f,<: error :>,A(1));
end;
end submit;

reflectcore(core);
readsfp(<:lp:>,LP,<::>);
pda:=owndescr;
pda:=core.pda(26); <*parent description*>
name:=pda+2;
for i:=1,2 do P(i):=core.name(i);
exm:='!';
initfp;
if fpinareas>0 then
begin
  for i:=1 step 1 until fpinareas do
  begin
    readinfp(IN,i);
    submit(IN);
  end;
end
else
begin
<*read from console*>
  write(out,"nl",1,<:submit begin.:>,"nl",if fpinareas=0 then 1 else 0);
  outendcur(0);
  connectlso;
  if -,readlsfp(OUT) then 
  begin
   generaten(OUT);
   res:=connectcuro(OUT);
   if res<>0 then unstackcuro;
  end;
  readchar(in,exm);
  for c:=readchar(in,char) while char<>25 and char<>exm do
  begin
    if char<>exm then outchar(out,char);
   end char;
 repeatchar(in);
 repeat readchar(in,char) until char=25 or char=10 ;
 i:=1;
 closeout;
 write(out,"nl",1,string OUT(increase(i)),<:=submit end.:>);
submit(OUT);
end console;
end;
lookup submit
mode list.no 15.no
▶EOF◀