DataMuseum.dk

top - metrics - download

    Length: 3621 (0xe25)
    Types: TextFile
    Names: »MY_MAIN.TXT«

└─⟦6a1b9f2c5⟧ Bits:30005310/disk3.imd Open Access II v2.10 (dansk)
    └─⟦this⟧ »MY_MAIN.TXT« 

TextFile

      
      
      !=============================================================ø
      !my_main:  This is the main program -- it consists mostly of  ø
      !          definitions and the application's user interface.  ø
      !          This program, and the procedures which make it up, ø
      !          have been modified from those developed in the     ø 
      !          tutorial, along the lines suggested in the last    ø
      !          section; also, an additional command, and its      ø
      !          procedure, has been added.                         ø
      !=============================================================ø
      

!========================== Initialization =================================
WINDOW dataW = SIZE 79 BY 24 AT 1,1 FRAMED    !data window definition
WINDOW dataTP = TOP 1 IN dataW MODE TITLE     !Top subpane definition
WINDOW dataBP = BOTTOM 1 in dataW MODE PROMPT !Bottom pane definition 
WINDOW menuW = SIZE 60 BY 3 AT 10,10 FRAMED   !Menu window definition
WINDOW menuTP = TOP 1 IN menuW MODE TITLE     !Top subpane definition
WINDOW menuBP = BOTTOM 1 in menuW MODE PROMPT !Bottom pane definition 
         
VIEW data = FROM cust    !define the view 
USE data DISPLAY cust    !use it

option = 1   !defines option (for main menu) 
message = '' !defines message (for verify procedure) 
!===========================================================================


! BEGIN APPLICATION USER INTERFACE 

SCREEN dataW  !Draws data window
   PUT IN dataBP '<do>  <undo> ' FILLED       !Prompt line.
   PUT IN dataW      !Put anything else in the main pane of this window.

    
   WHILE option > 0  !Keep putting up menu until quit or <undo> is selected.
      PUT IN dataTP 'CUSTOMER TRACKING SYSTEM' FILLED         !Title. 

      !---------- Main Menu appears; data window now inactive -------------- 
      SCREEN menuW
         PUT IN menuTP 'CUSTOMER MAIN MENU' FILLED               !Title. 
         PUT IN menuBP '<do>  <undo>' FILLED              !Prompt line.
          
         PUT IN menuW AT 1,1
         MENU                           
            : LIST : option = 1 
            : ENTER : option = 2
            : MODIFY : option = 3 
            : DELETE : option = 4 
            : SUMMARIZE_ORDERS : option = 5
            : QUIT :     option = 0        !skips IF statement & exits loop.
            : K_UNDO :   option = 0        !skips IF statement & exits loop.
            END MENU 
         END SCREEN  !Puts away menuW 
      !-------------------- data window is active again--------------------- 
      

      !::::::::::: Adjust data window's title & call procedure ::::::::::::::
      IF option = 1  !Does the option after the menu is deactivated.
         PUT IN dataTP AT 1,1 'LIST RECORDS' FILLED 
         PUT IN dataW 
         DO my_list
      ELSE IF option = 2
         PUT IN dataTP AT 1,1 'ENTER A NEW RECORD' FILLED  
         PUT IN dataW 
         DO my_ent
      ELSE IF option = 3 
         PUT IN dataTP AT 1,1 'MODIFY AN EXISTING RECORD' FILLED 
         PUT IN dataW 
         DO my_mod 
      ELSE IF option = 4 
         PUT IN dataTP AT 1,1 'DELETE A RECORD' FILLED 
         PUT IN dataW 
         DO my_del 
      ELSE IF option = 5 
         PUT IN dataTP AT 1,1 'SUMMARY OF PRODUCTS ON ORDER' FILLED 
         PUT IN dataW DO CLEAR SCREEN 
         DO my_rep 
         END IF
         !::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
         
      END WHILE
   END SCREEN  !Deactivates dataW 
USE data END