DataMuseum.dk

top - metrics - download

    Length: 2551 (0x9f7)
    Types: TextFile
    Names: »AP_MAIN.TXT«

└─⟦6a1b9f2c5⟧ Bits:30005310/disk3.imd Open Access II v2.10 (dansk)
    └─⟦this⟧ »AP_MAIN.TXT« 

TextFile

!========================== Initialization =================================
WINDOW dataW = SIZE 79 BY 18 AT 1,1 FRAMED    !data window definition
WINDOW dataTP = TOP 1 IN dataW MODE TITLE     !Top subpane definition
WINDOW dataBP = BOTTOM 1 in dataW MODE PROMPT !Bottom pane definition 
WINDOW menuW = SIZE 50 BY 3 AT 15,10 FRAMED   !Menu window definition
WINDOW menuTP = TOP 1 IN menuW MODE TITLE     !Top subpane definition
WINDOW menuBP = BOTTOM 1 in menuW MODE PROMPT !Bottom pane definition 
         
VIEW data = FROM cust    !define the view 

option = 1   !defines option (for main menu) 
message = '' !defines message (for verify procedure) 
!===========================================================================


! BEGIN MAIN PROGRAM: APPLICATION

SCREEN dataW  !Draws data window
   PUT IN dataBP '<do>  <undo> ' FILLED       !Prompt line.
   PUT IN dataW      !Put anything else in the main pane of this window.

    
   WHILE option > 0  !Keep putting up menu until quit or <undo> is selected.
      PUT IN dataTP 'CUSTOMER TRACKING SYSTEM' FILLED         !Title. 

      !--- The Main Menu Window appears; now the data window is inactive ---- 
      SCREEN menuW
         PUT IN menuTP 'CUSTOMER MAIN MENU' FILLED               !Title. 
         PUT IN menuBP '<do>  <undo>' FILLED              !Prompt line.
          
         PUT IN menuW AT 1,1
         MENU                           
            : LIST : option = 1 
            : ENTER : option = 2
            : MODIFY : option = 3 
            : DELETE : option = 4 
            : QUIT :     option = 0        !skips IF statement & exits loop.
            : K_UNDO :   option = 0        !skips IF statement & exits loop.
            END MENU 
         END SCREEN  !Puts away menuW 
      !---- Main Menu disappears; now the data window is active again--------   
         
      IF option = 1  !Does the option after the menu is deactivated. 
         PUT IN dataTP AT 1,1 'LIST RECORDS' FILLED 
         PUT IN dataW 
         DO AP_LIST
      ELSE IF option = 2
         PUT IN dataTP AT 1,1 'ENTER A NEW RECORD' FILLED  
         PUT IN dataW 
         DO AP_ENT
      ELSE IF option = 3 
         PUT IN dataTP AT 1,1 'MODIFY AN EXISTING RECORD' FILLED 
         PUT IN dataW 
         DO AP_MOD 
      ELSE IF option = 4 
         PUT IN dataTP AT 1,1 'DELETE A RECORD' FILLED 
         PUT IN dataW 
         DO AP_DEL 
         END IF
         
      END WHILE
   END SCREEN  !Deactivates dataW